TweetFollow Us on Twitter

Introduction to Scripting Microsoft Excel

Volume Number: 23 (2007)
Issue Number: 02
Column Tag: AppleScript Essentials

Introduction to Scripting Microsoft Excel

by Benjamin S. Waldie

With Office 2008 on the horizon, Microsoft has recently begun to push AppleScript as an alternative automation technology to Visual Basic macros in the Office applications. Moving forward, Visual Basic macros will not be supported in the release of Office 2008. Current AppleScript users are ahead of the curve. The Office applications have been AppleScriptable for quite some time, and AppleScript actually provides several advantages over Visual Basic. For one, AppleScripts can interact with multiple applications, including non-Microsoft applications, allowing even complex multi-application workflows to be automated.

Last month, we began discussing how to get started with scripting Microsoft Word. We explored various techniques for interacting with Word documents, as well as the content within those documents, all using AppleScript. This month, we're going to begin discussing another Office application, Microsoft Excel. Like Word, Excel contains a quite extensive AppleScript dictionary, allowing almost any task that can be performed manually to be automated using AppleScript.

Please note, all example code within this month's column was written and tested with Excel 2004 (version 11.x). If you are using another version of Excel, please be aware that the terminology may need to be adjusted in order to function properly. Let's get started.

Working with Workbooks

In Excel, the top-level class (beneath the application class) with which you will probably want to interact is a workbook. A workbook will contain one or more sheets, and those sheets will typically contain ranges of data. This data can be text, numbers, dates, and so forth. We will discuss each of these primary classes of Excel objects in this month's column, but we will begin with the workbook class.

Making a Workbook

Creating a workbook in Excel is similar to the process of creating a document in Word, or in many scriptable applications, for that matter. To do so, use the make command, as demonstrated below.

tell application "Microsoft Excel"
   make new workbook
end tell
--> workbook "Sheet1" of application "Microsoft Excel"

The make command's result will be a reference to the newly created workbook, which may be placed into an AppleScript variable, if desired, for future reference in your script.

Closing a Workbook

Closing a workbook is also very similar to closing a document in other scriptable applications. Use the close command, referencing the workbook you wish to close. Optionally, you may choose to specify whether the workbook should be saved during the close process, using the optional saving parameter. For example:

tell application "Microsoft Excel"
   close workbook 1 saving no
end tell

Opening a Workbook

To open a workbook, use the open command, followed by a reference to the workbook file you want to open. For example:

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
tell application "Microsoft Excel"
   open theWorkbookFile
end tell

One issue with the open command is that, unfortunately, it does not return a result. Therefore, if you want to perform further processing on the newly opened document, you will need to build a reference to it in another manner. One way to do this is to retrieve the workbook file's name, and then construct a reference to the workbook using that name, once it has been opened. This is demonstrated in the example code below.

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
set theWorkbookName to name of (info for theWorkbookFile)
tell application "Microsoft Excel"
   open theWorkbookFile
   set theWorkbook to workbook theWorkbookName
end tell
--> workbook "My Workbook.xls" of application "Microsoft Excel"

Another way that this can be achieved is by referencing the active workbook property of Excel's application class, once the workbook has been opened. This property references the currently active workbook, which should be the newly opened document.

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
set theWorkbookName to name of (info for theWorkbookFile)
tell application "Microsoft Excel"
   open theWorkbookFile
   set theWorkbook to active workbook
end tell
--> active workbook of application "Microsoft Excel"

When referencing the active workbook property, one thing to keep in mind is that, if another workbook is brought to the front, then your script may reference the incorrect workbook. Because of this, it is recommended to reference workbooks by name.

Saving a Workbook

To save an opened workbook to its existing path, use the save command, referencing the workbook to be saved. For example, the following code will save the currently active workbook to its current path.

tell application "Microsoft Excel"
   save active workbook
end tell

Excel also has a save workbook as command, which may be used to save a workbook into a new location, or in a different file format. The following example code makes use of this command, as well as some of its optional parameters, in order to save the currently active workbook to the desktop in comma separated format.

set theOutputPath to (path to desktop folder as string) & "My Saved Workbook.csv"
tell application "Microsoft Excel"
   tell active workbook
      save workbook as filename theOutputPath file format CSV file format
   end tell
end tell

Take some time to explore some of the other optional parameters for the save workbook as command, as well as some of the other available file formats, which can be found in Excel's AppleScript dictionary.

Working with Sheets

As previously mentioned, a workbook itself does not contain data in Excel. Rather, a workbook contains sheets, which contain the data. Most often, you will find yourself writing a script that will interact with a worksheet, a specific type of sheet in Excel. That's what we will be discussing here. Another type of sheet, which we will not discuss at this time, is a chart sheet.

Making a Worksheet

Like a workbook, a worksheet is created by using the make command. When using this command, be sure to specify a location for the new worksheet to be created, such as beginning, end, before worksheet 1, and so forth. For example, this code will create a new worksheet at the end of the existing worksheets within the currently active workbook.

tell application "Microsoft Excel"
   tell active workbook
      make new worksheet at end
   end tell
end tell
--> sheet "Sheet2" of active workbook of application "Microsoft Excel"

Selecting a Worksheet

At times, you may want to navigate to a specific worksheet in an Excel workbook. To do this, use the activate object command, and target the worksheet that you want to be displayed. For example:

tell application "Microsoft Excel"
   tell active workbook
      activate object worksheet "Sheet1"
   end tell
end tell

Working with Data

In an Excel worksheet, data is contained within cells, which are organized into rows and columns. Cells can be accessed by referencing the cell, row, column, or range class.

The Cell Class

To access a specific cell, use the cell class. For example, the following code references the first cell of a worksheet, found in column A, row 1.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      cell "A1"
   end tell
end tell
--> cell "A1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel" 

The Row Class

To access an entire row of cells, use the row class. For example, the following code references the first row of cells in a worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      row 1
   end tell
end tell
--> row "$1:$1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

The Column Class

To access an entire column of cells, use the column class. For example, the following code references the first column of cells in a worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      column 1
   end tell
end tell
--> column "$A:$A" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

The Range Class

Regardless of how you reference cells within a worksheet, you are really referencing what is known as a range. A range refers to either a single cell, or multiple cells within a worksheet, and the cell, row, and column classes all inherit the properties of the range class. There are numerous ways to directly reference a range. The following are some examples.

This code demonstrates how to reference a range that represents a single cell in a worksheet, in this case, the first cell in the first row, i.e. the intersection of column 1 and row 1.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      range "A1"
   end tell
end tell
--> cell "A1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

This next example demonstrates how to reference a range that represents multiple cells within a worksheet, in this case, cells 2 through 5 of the first two rows.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
       range "B1:F2"
   end tell
end tell
--> range "B1:F2" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

Again, there are numerous ways to reference a range of cells, and Excel is pretty flexible. For a chart that outlines different methods, take a look at the AppleScript Reference Guide for Excel, mentioned later in this column.

The Used Range

In some cases, you may not know specifically which range you want to reference. For example, you may just want to reference all of the data contained within a specified worksheet. To do this, you can reference the used range property of the worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      used range
   end tell
end tell
--> used range of active sheet of active workbook ¬
of application "Microsoft Excel"

Properties of Ranges

We have discussed numerous ways to reference ranges of cells in Excel. However, what can you do with a range once you have constructed a reference to it? Well, one thing you can do is access its properties. Ranges have numerous properties, but perhaps the two that you may find most useful are the value and formula properties.

By referencing the value property of a range, you can retrieve the value of a specified set of cells in a worksheet. For example, the following code retrieves the values of the used range in a specified worksheet. Notice that the value is returned as a list of lists. Each list represents a row, and each list item represents a cell.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      value of used range
   end tell
end tell
--> {{1.0, 2.0, 3.0}, {4.0, 5.0, 6.0}}

The formula property of a range returns a similar result. For example:

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      formula of used range
   end tell
end tell
--> {{"1", "2", "3"}, {"4", "5", "6"}}

Of course, these properties are not read-only properties. So, it is also possible to modify them, if desired. For example, the following code demonstrates how to set the value of a single cell.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      set value of cell "A1" to "A"
   end tell
end tell
Likewise, the following code will set the value of a range of cells.
tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      set value of range "A1:C2" to {{"a", "b", "c"}, {"d", "e", "f"}}
   end tell
end tell

Pulling Things Together

Now, let's take a brief look at some sample code that makes use of several of the topics that we have discussed throughout this month's column. The following example code will retrieve the names of any visible items on the desktop. It will then create a workbook, and insert the list of item names into the active worksheet.

— Retrieve a list of items on the desktop
set theFileNames to list folder (path to desktop) without invisibles
— Convert the list of items to a list of lists
repeat with a from 1 to length of theFileNames
   set item a of theFileNames to {item a of theFileNames}
end repeat
— Build a new workbook in Excel, and add the data to the current worksheet
tell application "Microsoft Excel"
   set theWorkbook to make new workbook
   tell active sheet of theWorkbook
      set value of range ("A1:A" & (length of theFileNames)) to theFileNames
   end tell
end tell

In Closing

It may seem like we've only scratched the surface of scripting Excel, and we have. As mentioned at the beginning of this month's column, Excel contains quite an extensive AppleScript dictionary, and there is a lot that you can do with it from a scripting perspective. However, using the techniques we have discussed in this month's column, you should be able to piece together a script that can construct a workbook, create a worksheet, retrieve data from a range of cells in a worksheet, and more.

For more information about scripting Excel, be sure to download the Excel AppleScript Reference Guide that I mentioned earlier. This can be found on the Mactopia website at http://www.microsoft.com/mac/. It is located in the Resources > Developer Center > AppleScript Resources for Office 2004 section.

Until next time, keep scripting!


Ben Waldie is the author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from http://www.spiderworks.com, as well as an AppleScript Training CD, available from http://www.vtc.com. Ben is also president of Automated Workflows, LLC, a company specializing in AppleScript and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit http://www.automatedworkflows.com, or email Ben at ben@automatedworkflows.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Macs Fan Control 1.4.7.0 - Monitor and c...
Macs Fan Control allows you to monitor and control almost any aspect of your computer's fans, with support for controlling fan speed, temperature sensors pane, menu-bar icon, and autostart with... Read more
Boom 2 1.5.2 - $14.99
Boom 2 is a system-wide volume booster and equalizer app that is designed especially for OS X 10.10 Yosemite. It comes with a smart interface, self-calibrates itself according to your Mac, offers... Read more
MacFamilyTree 8.1.3 - Create and explore...
MacFamilyTree gives genealogy a facelift: modern, interactive, convenient and fast. Explore your family tree and your family history in a way generations of chroniclers before you would have loved.... Read more
WhiteCap 6.6 - Visual plug-in for iTunes...
WhiteCap is a sleek and sophisticated music visualizer and screensaver that features futuristic, wireframe mesh visuals with dynamic backgrounds and colors. WhiteCap contains thousands of visual... Read more
VOX 2.8.14 - Music player that supports...
VOX just sounds better! The beauty is in its simplicity, yet behind the minimal exterior lies a powerful music player with a ton of features and support for all audio formats you should ever need.... Read more
Paparazzi! 1.0b2 - Make user-defined siz...
Paparazzi! is a small utility for OS X that makes screenshots of webpages. This very simple tool takes screenshots of websites which do not fit on one screen. You specify the desired width, minimal... Read more
Carbon Copy Cloner 4.1.13 - Easy-to-use...
Carbon Copy Cloner backups are better than ordinary backups. Suppose the unthinkable happens while you're under deadline to finish a project: your Mac is unresponsive and all you hear is an ominous,... Read more
TrailRunner 3.8.832 - Route planning for...
TrailRunner is the perfect companion for runners, bikers, hikers, and all people wandering under the sky. Plan routes on a geographical map. Import GPS or workout recordings and journalize your... Read more
VueScan 9.5.65 - Scanner software with a...
VueScan is a scanning program that works with most high-quality flatbed and film scanners to produce scans that have excellent color fidelity and color balance. VueScan is easy to use, and has... Read more
Adobe Illustrator CC 2017 21.0.2 - Profe...
Illustrator CC 2017 is available as part of Adobe Creative Cloud for as little as $19.99/month (or $9.99/month if you're a previous Illustrator customer). Adobe Illustrator CC 2017 is the industry... Read more

Stickman Surfer rides in with the tide t...
Stickson is back and this time he's taken up yet another extreme sport - surfing. Stickman Surfer is out this Thursday on both iOS and Android, so if you've been following the other Stickman adventures, you might be interested in picking this one... | Read more »
Z-Exemplar (Games)
Z-Exemplar 1.4 Device: iOS Universal Category: Games Price: $3.99, Version: 1.4 (iTunes) Description: | Read more »
5 dastardly difficult roguelikes like th...
Edmund McMillen's popular roguelike creation The Binding of Isaac: Rebirth has finally crawled onto mobile devices. It's a grotesque dual-stick shooter that tosses you into an endless, procedurally generated basement as you, the pitiable Isaac,... | Read more »
Last week on PocketGamer
Welcome to a weekly feature looking back on the past seven days of coverage on our sister website, PocketGamer. It’s taken a while for 2017 to really get going, at least when it comes to the world of portable gaming. Thank goodness, then, for... | Read more »
ROME: Total War - Barbarian Invasion set...
To the delight of mobile strategy fans, Feral Interactive released ROME: Total War just a few months ago. Now the game's expansion, Barbarian Invasion is marching onto iPads as a standalone release. [Read more] | Read more »
Yuri (Games)
Yuri 1.0 Device: iOS iPhone Category: Games Price: $3.99, Version: 1.0 (iTunes) Description: It's night. Yuri opens his eyes. He wakes up in a strange forest.The small, courageous explorer rides on his bed on casters in this... | Read more »
Space schmup Xenoraid launches on the Ap...
10Tons Xenoraid is out today on the App Store, bringing some high-speed space action to your mobile gadgets just in time for the weekend. The company's last premium title, another sci-fi game titled Neon Chrome, did quite well for itself, so... | Read more »
Star Wars: Force Arena Beginner's G...
Star Wars: Force Arena joined the populous ranks of Star Wars games on mobile today. It's a two-lane MOBA starring many familiar faces from George Lucas's famed sci-fi franchise. As with most games of this nature, Force Arena can be a little obtuse... | Read more »
Mysterium: The Board Game (Games)
Mysterium: The Board Game 1.0 Device: iOS Universal Category: Games Price: $6.99, Version: 1.0 (iTunes) Description: The official adaptation of the famous board game Mysterium! | Read more »
Sonny (Games)
Sonny 1.0.4 Device: iOS Universal Category: Games Price: $2.99, Version: 1.0.4 (iTunes) Description: Reimagined for iOS, cult-hit RPG Sonny brings challenging turn-based combat that requires strategy and mastery of each new skill to... | Read more »

Price Scanner via MacPrices.net

New MacBooks And MacBook Pros WIth Kaby Lake...
Digitimes’ Joseph Tsai cites a Chinese-language Economic Daily News (EDN) report that unnamed market watchers are predicting Apple MacBook shipments to grow 10 percent in 2017, and projecting 15... Read more
New 2016 13-inch MacBook Pros on sale for up...
B&H Photo has the new 2016 13″ MacBook Pros in stock today and on sale for up to $150 off MSRP. Shipping is free, and B&H charges NY sales tax only: - 13″ 2.9GHz/512GB Touch Bar MacBook Pro... Read more
New 15-inch Touch Bar MacBook Pros in stock a...
B&H Photo has the new 2016 15″ Apple Touch Bar MacBook Pros in stock today and on sale for up to $150 off MSRP. Shipping is free, and B&H charges NY sales tax only: - 15″ 2.7GHz Touch Bar... Read more
Opera Announces Neon Concept Browser For Mac
Opera is inviting users to get a glimpse of what Opera for computers could become with its Opera Neon browser concept. Each Opera Neon feature is described as “an alternate reality” for the Opera... Read more
Tellini Releases TabView 3.0 Missing Tool fo...
Tellini has announced the release of TabView 3.0. TabView has been the first macOS viewer for PowerTab tablatures. PowerTab is a well-known and widely adopted tablature editor for Windows systems and... Read more
13-inch 1.6GHz/128GB MacBook Air on sale for...
Overstock.com has the 1.6GHz/128GB 13″ MacBook Air on sale for $130 off MSRP including free shipping: - 13″ 1.6GHz/128GB MacBook Air (MMGF2LL/A): $869.99 $130 off MSRP Their price is the lowest... Read more
12-inch 32GB Space Gray iPad Pro on sale for...
B&H Photo has 12″ Space Gray 32GB WiFi Apple iPad Pros on sale for $55 off MSRP including free shipping. B&H charges sales tax in NY only: - 12″ Space Gray 32GB WiFi iPad Pro: $744.44 $55 off... Read more
9-inch 32GB Space Gray iPad Pro on sale for $...
B&H Photo has the 9.7″ 32GB Space Gray Apple iPad Pro on sale for $549 for a limited time. Shipping is free, and B&H charges NY sales tax only. Read more
Apple iMacs on sale for up to $120 off MSRP,...
B&H Photo has 21″ and 27″ Apple iMacs on sale for up to $120 off MSRP, each including free shipping plus NY sales tax only: - 27″ 3.3GHz iMac 5K: $2199 $100 off MSRP - 27″ 3.2GHz/1TB Fusion iMac... Read more
Apple refurbished Apple TVs available for up...
Apple has Certified Refurbished 32GB and 64GB Apple TVs available for up to $30 off the cost of new models. Apple’s standard one-year warranty is included with each model, and shipping is free: -... Read more

Jobs Board

*Apple* Retail - Multiple Positions (Multi-L...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* & PC Desktop Support Technician...
Apple & PC Desktop Support Technician job in Stamford, CT We have immediate job openings for several Desktop Support Technicians with one of our most well-known Read more
*Apple* macOS Systems Integration Administra...
…most exceptional support available in the industry. SCI is seeking an Junior Apple macOS systems integration administrator that will be responsible for providing Read more
*Apple* Premier Retailer - Service Technicia...
DescriptionSimply Mac is the largest premier retailer for Apple products and solutions. At Simply Mac we are all Apple , all the time. Same products. Same prices. Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.