TweetFollow Us on Twitter

Introduction to Scripting Microsoft Excel

Volume Number: 23 (2007)
Issue Number: 02
Column Tag: AppleScript Essentials

Introduction to Scripting Microsoft Excel

by Benjamin S. Waldie

With Office 2008 on the horizon, Microsoft has recently begun to push AppleScript as an alternative automation technology to Visual Basic macros in the Office applications. Moving forward, Visual Basic macros will not be supported in the release of Office 2008. Current AppleScript users are ahead of the curve. The Office applications have been AppleScriptable for quite some time, and AppleScript actually provides several advantages over Visual Basic. For one, AppleScripts can interact with multiple applications, including non-Microsoft applications, allowing even complex multi-application workflows to be automated.

Last month, we began discussing how to get started with scripting Microsoft Word. We explored various techniques for interacting with Word documents, as well as the content within those documents, all using AppleScript. This month, we're going to begin discussing another Office application, Microsoft Excel. Like Word, Excel contains a quite extensive AppleScript dictionary, allowing almost any task that can be performed manually to be automated using AppleScript.

Please note, all example code within this month's column was written and tested with Excel 2004 (version 11.x). If you are using another version of Excel, please be aware that the terminology may need to be adjusted in order to function properly. Let's get started.

Working with Workbooks

In Excel, the top-level class (beneath the application class) with which you will probably want to interact is a workbook. A workbook will contain one or more sheets, and those sheets will typically contain ranges of data. This data can be text, numbers, dates, and so forth. We will discuss each of these primary classes of Excel objects in this month's column, but we will begin with the workbook class.

Making a Workbook

Creating a workbook in Excel is similar to the process of creating a document in Word, or in many scriptable applications, for that matter. To do so, use the make command, as demonstrated below.

tell application "Microsoft Excel"
   make new workbook
end tell
--> workbook "Sheet1" of application "Microsoft Excel"

The make command's result will be a reference to the newly created workbook, which may be placed into an AppleScript variable, if desired, for future reference in your script.

Closing a Workbook

Closing a workbook is also very similar to closing a document in other scriptable applications. Use the close command, referencing the workbook you wish to close. Optionally, you may choose to specify whether the workbook should be saved during the close process, using the optional saving parameter. For example:

tell application "Microsoft Excel"
   close workbook 1 saving no
end tell

Opening a Workbook

To open a workbook, use the open command, followed by a reference to the workbook file you want to open. For example:

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
tell application "Microsoft Excel"
   open theWorkbookFile
end tell

One issue with the open command is that, unfortunately, it does not return a result. Therefore, if you want to perform further processing on the newly opened document, you will need to build a reference to it in another manner. One way to do this is to retrieve the workbook file's name, and then construct a reference to the workbook using that name, once it has been opened. This is demonstrated in the example code below.

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
set theWorkbookName to name of (info for theWorkbookFile)
tell application "Microsoft Excel"
   open theWorkbookFile
   set theWorkbook to workbook theWorkbookName
end tell
--> workbook "My Workbook.xls" of application "Microsoft Excel"

Another way that this can be achieved is by referencing the active workbook property of Excel's application class, once the workbook has been opened. This property references the currently active workbook, which should be the newly opened document.

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
set theWorkbookName to name of (info for theWorkbookFile)
tell application "Microsoft Excel"
   open theWorkbookFile
   set theWorkbook to active workbook
end tell
--> active workbook of application "Microsoft Excel"

When referencing the active workbook property, one thing to keep in mind is that, if another workbook is brought to the front, then your script may reference the incorrect workbook. Because of this, it is recommended to reference workbooks by name.

Saving a Workbook

To save an opened workbook to its existing path, use the save command, referencing the workbook to be saved. For example, the following code will save the currently active workbook to its current path.

tell application "Microsoft Excel"
   save active workbook
end tell

Excel also has a save workbook as command, which may be used to save a workbook into a new location, or in a different file format. The following example code makes use of this command, as well as some of its optional parameters, in order to save the currently active workbook to the desktop in comma separated format.

set theOutputPath to (path to desktop folder as string) & "My Saved Workbook.csv"
tell application "Microsoft Excel"
   tell active workbook
      save workbook as filename theOutputPath file format CSV file format
   end tell
end tell

Take some time to explore some of the other optional parameters for the save workbook as command, as well as some of the other available file formats, which can be found in Excel's AppleScript dictionary.

Working with Sheets

As previously mentioned, a workbook itself does not contain data in Excel. Rather, a workbook contains sheets, which contain the data. Most often, you will find yourself writing a script that will interact with a worksheet, a specific type of sheet in Excel. That's what we will be discussing here. Another type of sheet, which we will not discuss at this time, is a chart sheet.

Making a Worksheet

Like a workbook, a worksheet is created by using the make command. When using this command, be sure to specify a location for the new worksheet to be created, such as beginning, end, before worksheet 1, and so forth. For example, this code will create a new worksheet at the end of the existing worksheets within the currently active workbook.

tell application "Microsoft Excel"
   tell active workbook
      make new worksheet at end
   end tell
end tell
--> sheet "Sheet2" of active workbook of application "Microsoft Excel"

Selecting a Worksheet

At times, you may want to navigate to a specific worksheet in an Excel workbook. To do this, use the activate object command, and target the worksheet that you want to be displayed. For example:

tell application "Microsoft Excel"
   tell active workbook
      activate object worksheet "Sheet1"
   end tell
end tell

Working with Data

In an Excel worksheet, data is contained within cells, which are organized into rows and columns. Cells can be accessed by referencing the cell, row, column, or range class.

The Cell Class

To access a specific cell, use the cell class. For example, the following code references the first cell of a worksheet, found in column A, row 1.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      cell "A1"
   end tell
end tell
--> cell "A1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel" 

The Row Class

To access an entire row of cells, use the row class. For example, the following code references the first row of cells in a worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      row 1
   end tell
end tell
--> row "$1:$1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

The Column Class

To access an entire column of cells, use the column class. For example, the following code references the first column of cells in a worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      column 1
   end tell
end tell
--> column "$A:$A" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

The Range Class

Regardless of how you reference cells within a worksheet, you are really referencing what is known as a range. A range refers to either a single cell, or multiple cells within a worksheet, and the cell, row, and column classes all inherit the properties of the range class. There are numerous ways to directly reference a range. The following are some examples.

This code demonstrates how to reference a range that represents a single cell in a worksheet, in this case, the first cell in the first row, i.e. the intersection of column 1 and row 1.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      range "A1"
   end tell
end tell
--> cell "A1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

This next example demonstrates how to reference a range that represents multiple cells within a worksheet, in this case, cells 2 through 5 of the first two rows.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
       range "B1:F2"
   end tell
end tell
--> range "B1:F2" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

Again, there are numerous ways to reference a range of cells, and Excel is pretty flexible. For a chart that outlines different methods, take a look at the AppleScript Reference Guide for Excel, mentioned later in this column.

The Used Range

In some cases, you may not know specifically which range you want to reference. For example, you may just want to reference all of the data contained within a specified worksheet. To do this, you can reference the used range property of the worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      used range
   end tell
end tell
--> used range of active sheet of active workbook ¬
of application "Microsoft Excel"

Properties of Ranges

We have discussed numerous ways to reference ranges of cells in Excel. However, what can you do with a range once you have constructed a reference to it? Well, one thing you can do is access its properties. Ranges have numerous properties, but perhaps the two that you may find most useful are the value and formula properties.

By referencing the value property of a range, you can retrieve the value of a specified set of cells in a worksheet. For example, the following code retrieves the values of the used range in a specified worksheet. Notice that the value is returned as a list of lists. Each list represents a row, and each list item represents a cell.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      value of used range
   end tell
end tell
--> {{1.0, 2.0, 3.0}, {4.0, 5.0, 6.0}}

The formula property of a range returns a similar result. For example:

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      formula of used range
   end tell
end tell
--> {{"1", "2", "3"}, {"4", "5", "6"}}

Of course, these properties are not read-only properties. So, it is also possible to modify them, if desired. For example, the following code demonstrates how to set the value of a single cell.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      set value of cell "A1" to "A"
   end tell
end tell
Likewise, the following code will set the value of a range of cells.
tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      set value of range "A1:C2" to {{"a", "b", "c"}, {"d", "e", "f"}}
   end tell
end tell

Pulling Things Together

Now, let's take a brief look at some sample code that makes use of several of the topics that we have discussed throughout this month's column. The following example code will retrieve the names of any visible items on the desktop. It will then create a workbook, and insert the list of item names into the active worksheet.

— Retrieve a list of items on the desktop
set theFileNames to list folder (path to desktop) without invisibles
— Convert the list of items to a list of lists
repeat with a from 1 to length of theFileNames
   set item a of theFileNames to {item a of theFileNames}
end repeat
— Build a new workbook in Excel, and add the data to the current worksheet
tell application "Microsoft Excel"
   set theWorkbook to make new workbook
   tell active sheet of theWorkbook
      set value of range ("A1:A" & (length of theFileNames)) to theFileNames
   end tell
end tell

In Closing

It may seem like we've only scratched the surface of scripting Excel, and we have. As mentioned at the beginning of this month's column, Excel contains quite an extensive AppleScript dictionary, and there is a lot that you can do with it from a scripting perspective. However, using the techniques we have discussed in this month's column, you should be able to piece together a script that can construct a workbook, create a worksheet, retrieve data from a range of cells in a worksheet, and more.

For more information about scripting Excel, be sure to download the Excel AppleScript Reference Guide that I mentioned earlier. This can be found on the Mactopia website at http://www.microsoft.com/mac/. It is located in the Resources > Developer Center > AppleScript Resources for Office 2004 section.

Until next time, keep scripting!


Ben Waldie is the author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from http://www.spiderworks.com, as well as an AppleScript Training CD, available from http://www.vtc.com. Ben is also president of Automated Workflows, LLC, a company specializing in AppleScript and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit http://www.automatedworkflows.com, or email Ben at ben@automatedworkflows.com.

 
AAPL
$531.70
Apple Inc.
+0.53
MSFT
$39.99
Microsoft Corpora
+0.05
GOOG
$534.81
Google Inc.
+6.19

MacTech Search:
Community Search:

Software Updates via MacUpdate

TeamViewer 9.0.28116 - Establish remote...
TeamViewer gives you remote control of any computer or Mac over the Internet within seconds, or can be used for online meetings. Find out why more than 200 million users trust TeamViewer! Free for... Read more
Viber 4.1.0 - Send messages and make cal...
Viber lets you send free messages and make free calls to other Viber users, on any device and network, in any country! Viber syncs your contacts, messages and call history with your mobile device,... Read more
Apple iOS 7.1.1 - The latest version of...
The latest version of iOS can be downloaded through iTunes. Apple iOS 7 brings an all-new design and all-new features. Simplicity Simplicity is often equated with minimalism. Yet true simplicity is... Read more
1Password 4.3 - Powerful password manage...
1Password is a password manager that uniquely brings you both security and convenience. It is the only program that provides anti-phishing protection and goes beyond password management by adding Web... Read more
Lens Blur 1.3.0 - True out-of-focus boke...
Let Lens Blur transform your existing photo into true SLR-quality out-of-focus bokeh effect! Everyone needs a gorgeous personalized background for a social profile, blog, Web/UI design, presentation... Read more
VMware Fusion 6.0.3 - Run Windows apps a...
VMware Fusion allows you to create a Virtual Machine on your Mac and run Windows (including Windows 8.1) and Windows software on your Mac. Run your favorite Windows applications alongside Mac... Read more
Tweetbot 1.5.1 - Popular iOS twitter cli...
Tweetbot is a full-featured OS X Twitter client with a lot of personality. Whether it's the meticulously-crafted interface, sounds and animation, or features like multiple timelines and column views... Read more
Mac DVDRipper Pro 4.1.7 - Copy, backup,...
Mac DVDRipper Pro is the DVD backup solution that lets you protect your DVDs from scratches, save your batteries by reading your movies from your hard disk, manage your collection with just a few... Read more
PDFpenPro 6.2 - Advanced PDF toolkit for...
PDFpenPro allows users to edit PDF's easily. Add text, images and signatures. Fill out PDF forms. Merge or split PDF documents. Reorder and delete pages. Even correct text and edit graphics! Create... Read more
PDFpen 6.2 - Edit and annotate PDFs with...
PDFpen allows users to easily edit PDF's. Add text, images and signatures. Fill out PDF forms. Merge or split PDF documents. Reorder and delete pages. Even correct text and edit graphics! Features... Read more

Latest Forum Discussions

See All

Zeebox is Now Beamly TV – Still Offers t...
Zeebox is Now Beamly TV – Still Offers the Same Social Networking TV Fun, Plus a New Look Posted by Rob Rich on April 22nd, 2014 [ permalink ] | Read more »
Bandai Namco Unveils Upcoming Slate of M...
At their recent Global Gamers’ Day event, Bandai Namco was largely focused on their console and PC offerings for the upcoming year. However mobile still had a small presence, with some upcoming titles revealed by the company – though few were in a... | Read more »
The Story Behind Grammar Girl’s Grammar...
Learning is so much more rewarding when it’s also fun. That’s part of the reason why recent educational app, Grammar Pop HD, garnered such a positive review from us last week. The brainchild of Mignon Fogarty, otherwise known as Grammar Girl, we... | Read more »
Pinnacle Studio for iPhone Review
Pinnacle Studio for iPhone Review By Jennifer Allen on April 22nd, 2014 Our Rating: :: SIMPLY POWERFULiPhone App - Designed for the iPhone, compatible with the iPad Video editing while on the move has never been so convenient.   | Read more »
Taste Savant Review
Taste Savant Review By Jennifer Allen on April 22nd, 2014 Our Rating: :: TASTY RECOMMENDATIONSiPhone App - Designed for the iPhone, compatible with the iPad In need of some new restaurant recommendations? This app will be ideal,... | Read more »
Where’s My Water? Featuring XYY Adds Mor...
Where’s My Water? Featuring XYY Adds More Than Just Sheep to the Liquid Physics Puzzler Posted by Rob Rich on April 22nd, 2014 [ permalink ] | Read more »
FarmVille 2: Country Escape Review
FarmVille 2: Country Escape Review By Jennifer Allen on April 22nd, 2014 Our Rating: :: STEADY FARMINGUniversal App - Designed for iPhone and iPad FarmVille is bigger and brighter than ever before, but don’t expect it to sway you... | Read more »
Doctor Who: Legacy receives big update,...
Doctor Who: Legacy receives big update, adds Perk System and more Posted by Tre Lawrence on April 22nd, 2014 [ permalink ] Universal App - Designed for iPhone and iPad | Read more »
Strongarm Universal Mount Hardware Revie...
Made by: Viatek Price: $14.99 for 2 Hardware/iOS Integration Rating: 3.5 out of 5 stars Usability Rating: 4 out of 5 stars Reuse Value Rating: 3.75 out of 5 stars Build Quality Rating: 3.5 out of 5 stars Overall Rating: 3.69 out of 5 stars | Read more »
Boxer Review
Boxer Review By Campbell Bird on April 21st, 2014 Our Rating: :: KO YOUR INBOXUniversal App - Designed for iPhone and iPad Turn your inbox into a task list or tune it to your own needs with this highly customizable, user friendly... | Read more »

Price Scanner via MacPrices.net

Updated iPad Price Trackers
We’ve updated our iPad Price Tracker and our iPad mini Price Tracker with the latest information on prices and availability from Apple and other resellers. Using a mobile device? We’ve also updated... Read more
Everything You Wanted To Know And Probably Mo...
Macworld UK’s Lou Hattersley takes a look inside Apple’s A7 System On Chip (SoC) , noting that its processor module is much more powerful than other smartphone chipsets. He notes that the A7 was a... Read more
Mavericks Now Runs Half Of Internet Connected...
Computerworld’s Greg Keizer reports that half of all Macs that went online in March were running OS X Mavericks with Version 10.9 accounting for the largest adoption percentage of any individual OS X... Read more
WinZip Mac 3 Simplifies Cloud Sharing And Pri...
WinZip has announced WinZip Mac 3, a new file sharing app that makes it simple to manage, protect and share files across email and the cloud. With direct support for Dropbox and Google Drive,... Read more
2.5GHz Mac mini, Apple refurbished, available...
The Apple Store has Apple Certified Refurbished 2.5GHz Mac minis available for $509, $90 off MSRP. Apple’s one-year warranty is included, and shipping is free. Read more
13-inch MacBook Pro, Apple refurbished, avail...
The Apple Store continues to offer Apple Certified Refurbished 13″ 2.5GHz MacBook Pros (4GB RAM/500GB HD) for $999 which is $200 off MSRP. Apple’s one-year warranty is included, and shipping is free. Read more
15-inch MacBook Pros (refurbished) available...
The Apple Store has Apple Certified Refurbished October 2013 15″ Retina MacBook Pros available starting at $1699, with models up to $400 off MSRP. Apple’s one-year warranty is standard, and shipping... Read more
$100 off cellular iPad minis plus free $20 gi...
Best Buy is discounting cellular iPad minis with Retina Displays by $100 on their online store for a limited time. They’ll also throw in a free $20 Best Buy gift card. Choose free shipping or free... Read more
Updated Price Trackers
We’ve updated our Mac Price Trackers with the latest information on prices, bundles, and availability on systems from Apple’s authorized internet/catalog resellers: - 15″ MacBook Pros - 13″ MacBook... Read more
Apple refurbished MacBook Airs available for...
The Apple Store has Apple Certified Refurbished 2013 MacBook Airs available for up to $200 off the cost of new models. An Apple one-year warranty is included with each MacBook, and shipping is free... Read more

Jobs Board

*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
Position Opening at *Apple* - Apple (United...
…customers purchase our products, you're the one who helps them get more out of their new Apple technology. Your day in the Apple Store is filled with a range of Read more
*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
*Apple* Inc. Research Data Specialist - Appl...
…of Worldwide Market Research & Intelligence. The team is responsible for conducting Apple branded consumer market research. It is also responsible for analyzing data Read more
*Apple* Automotive Parts Department position...
Apple Automotive is one of the fastest growing dealer…and it shows. Consider making the switch to the Apple Automotive Group today! At Apple Automotive, we Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.