TweetFollow Us on Twitter

Using Repeat Loops in AppleScript

Volume Number: 20 (2004)
Issue Number: 12
Column Tag: Programming

AppleScript Essentials

by Benjamin S. Waldie

Should I Repeat Myself?

Using Repeat Loops in AppleScript

For the past couple of months, we have been talking about some basic Finder scripting. Now we are going to switch gears and get back to some basics of AppleScript. In this month's article, we will discuss the various types of repeat loops that you can use when you are scripting.

Why You Need Repeat Loops

Repeat loops are invaluable when writing AppleScript code, because you will frequently need to perform a single task more than once. While in some cases, you could simply write the same code over and over again in order to achieve the same result, in other instances, you cannot.

For example, let's say that you have a folder containing 10 files, and you want to rename all of them with a unique numeric extension from 1 to 10. You could write a repetitive AppleScript that would rename the files in this manner without a repeat loop. However, why would you want to do that? It would take a while to write, and it would be kind of a pain in the neck if you wanted to go back and change the code. For example, what if, after writing the code, you changed your mind and now you want the files to be named from 11 to 20? You would need to go back through all of your code and restructure it. Isn't one of the primary functions of AppleScript to automate things? So, why not automate your code?

In some cases, the only way to accomplish a task is to use a repeat loop. For example, let's say that you need a script that will rename files in a folder. However, the number of files in the folder may change each time the script is run. To do this, you would need to get a list of all of the files in the folder, and then use a repeat loop to go through and rename all of them.

As we continue, throughout this article, you will see how repeat loops can be extremely useful in all types of automated processes.

Types of Repeat Loops

There are several different types of repeat loops that can be used in AppleScript.

Repeat

In AppleScript, it is possible to loop indefinitely by using the repeat type of repeat loop, which is written as follows:

repeat
   -- DO SOMETHING
end repeat

Using the above example, the AppleScript code inside of the repeat loop will loop on forever. It will never stop unless an error occurs. You should take care when using this type of repeat loop, as you can sometimes box yourself into a corner with no way to get out. It is always good practice to provide some type of mechanism within your code in order to get yourself out of the repeat loop. This is typically done by using the exit repeat statement.

For example, let's say that you need to display a dialog prompting the user to enter a username. However, you want to make absolutely sure that the user types at least something into the dialog. This can be done with a combination of a repeat type of repeat loop and an exit repeat statement.

repeat
   display dialog "Please enter your username:" default answer ""
   set theUserName to text returned of result
   if theUserName <> "" then exit repeat
end repeat

As you can see in the example code above, the dialog will continue to be displayed until the user enters something into the prompt.

Repeat Times

Another type of repeat loop in AppleScript is the repeat times type of repeat loop, which is used to perform a loop for a specified number of times. For example, let's use the same scenario as above. However, instead of looping forever, let's say that you want to only give the user 3 chances to enter the username before an error will occur.

repeat 3 times
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
   if theUserName <> "" then exit repeat
end repeat
if theUserName = "" then display dialog "Invalid Entry!!!"

In the example code above, the user will only be prompted to enter the username a maximum of 3 times. If the user does not enter a username, then an error notification will be displayed.

Repeat While

The repeat while style of repeat loop is typically used to test for a specific scenario to occur. For example, we could use the repeat while type of repeat loop as another way to verify that a user enters something into our dialog example.

set theUserName to ""
repeat while theUserName = ""
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
end repeat

In the example above, the script will continue to loop until something is entered into the dialog. You could also use a repeat loop of this nature to loop until a file is detected in a certain folder. For example:

set theFilePath to (path to desktop as string) & "test.psd"
tell application "Finder"
   repeat while (file theFilePath exists) = false
   end repeat
end tell
display dialog "The Photoshop file has arrived!"

Repeat Until

The repeat until type of repeat loop is yet another type of repeat loop that is used to test for specific scenarios to occur. As you can see in the example code below, this type of repeat loop is very similar to the repeat while type of repeat loop.

set theUserName to ""
repeat until theUserName <> ""
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
end repeat

Reprat With

The repeat with type of repeat loop can actually be broken down another level, into two separate types of distinct repeat with loops.

The first type of repeat with loop will allow you to loop for a specified number of times, while dynamically incrementing an integer variable's count. This type of repeat with loop is formed as follows:

repeat with theIncrementValue from theStartingValue to theEndingValue
   -- DO SOMETHING
end repeat

In the code above, the variable theIncrementValue signifies the current increment of an integer value in the loop. The variable theStartingValue signifies an integer that should be used as the initial increment value, whereas the variable theEndingValue signifies an integer that should be used as the final increment value. When a repeat loop of this nature is executed, it will continue to loop, incrementing the variable theIncrementValue each time until it reaches the value of the theEndingValue.

Let's take a look at another example in order to help illustrate this process. In the following example, we are going to prompt the user to select a folder, and then loop a specified number of times, building a folder for each increment.

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 1 to 10
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

When executed, the code above will generate 10 folders, named from 1 to 10, in a user specified directory. You can see how using a repeat loop for this type of task can help to make your AppleScript code extremely efficient.

It is also possible to change the manner by which the increment in this type of repeat loop occurs. For example, you may not want to loop by 1's. Instead, you may want to loop by 2's. This can be done by adding an optional by parameter at the end of the initial repeat with statement. For example:

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 1 to 10 by 2
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

In the example above, the script increments by 2's rather than 1's. Therefore, instead of building 10 folders, the script will only build 5, and they will be named "1", "3", "5", "7", and "9".

When using this type of repeat with loop, it is not necessary to begin the loop with a starting increment of 1. For example, the following code will cause 10 folders to be created, named from 11 to 20.

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 11 to 20
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

It is also possible to cause the increment value to move in reverse, such as from 10 to 1. For example:

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 10 to 1 by -1
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

At the beginning of this section, I mentioned that there are actually two types of repeat with loops in AppleScript. The second type of repeat with loop is used to loop through a series of values in a list. It is formed as follows:

repeat with theCurrentValue in theListOfValues
   -- DO SOMETHING
end repeat

When using this type of repeat with loop, each time the code loops, the variable theCurrentValue will take on the value of the current item in the list variable theListOfValues. Let's take a look at this type of loop in action.

set theDestinationFolder to choose folder
set theListOfValues to {"apples", "oranges", "pears"}
tell application "Finder"
   repeat with theCurrentValue in theListOfValues
      make new folder at theDestinationFolder with properties {name:theCurrentValue}
   end repeat
end tell

In the example code above, the script will loop through the list variable theListOfValues, which, in this case, contains the names of three different types of fruit. Each time the code loops, the variable theCurrentValue will take on the current value from the variable theListOfValues. So, during the first loop, the variable theCurrentValue would take on a value of "apples", the second loop, it would take on a value of "oranges", and so forth.

In Closing

Hopefully, the various types of repeat loops specified in this article will be helpful to you as you begin writing more complex AppleScript code. By creating nested repeat loops of varying types, you can really create some complex and adventurous scripts.

If you are interested in learning more about repeat loops in AppleScript, I recommend checking out the AppleScript Language Guide, which can be found under AppleScript in the Developer Connection on Apple's web site - http://developer.apple.com/. You may also want to consider picking up a good introductory AppleScript book, such as Danny Goodman's AppleScript Handbook.

Until next time, keep scripting!


Benjamin Waldie is president of Automated Workflows, LLC, a firm specializing in AppleScript and workflow automation consulting. In addition to his role as a consultant, Benjamin is an evangelist of AppleScript, and can frequently be seen presenting at Macintosh User Groups, Seybold Seminars, and MacWorld. For additional information about Benjamin, please visit http://www.automatedworkflows.com , or email Benjamin at applescriptguru@mac.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

CleanMyMac 3.9.2 - $39.95
CleanMyMac makes space for the things you love. Sporting a range of ingenious new features, CleanMyMac lets you safely and intelligently scan and clean your entire system, delete large, unused files... Read more
CleanMyMac 3.9.2 - $39.95
CleanMyMac makes space for the things you love. Sporting a range of ingenious new features, CleanMyMac lets you safely and intelligently scan and clean your entire system, delete large, unused files... Read more
Printopia 3.0.4 - Share Mac printers wit...
Run Printopia on your Mac to share its printers to any capable iPhone, iPad, or iPod Touch. Printopia will also add virtual printers, allowing you to save print-outs to your Mac and send to apps.... Read more
Tinderbox 7.3.1 - Store and organize you...
Tinderbox is a personal content management assistant. It stores your notes, ideas, and plans. It can help you organize and understand them. And Tinderbox helps you share ideas through Web journals... Read more
ExpanDrive 6.1.6 - Access cloud storage...
ExpanDrive builds cloud storage in every application, acts just like a USB drive plugged into your Mac. With ExpanDrive, you can securely access any remote file server directly from the Finder or... Read more
Printopia 3.0.4 - Share Mac printers wit...
Run Printopia on your Mac to share its printers to any capable iPhone, iPad, or iPod Touch. Printopia will also add virtual printers, allowing you to save print-outs to your Mac and send to apps.... Read more
Tinderbox 7.3.1 - Store and organize you...
Tinderbox is a personal content management assistant. It stores your notes, ideas, and plans. It can help you organize and understand them. And Tinderbox helps you share ideas through Web journals... Read more
ExpanDrive 6.1.6 - Access cloud storage...
ExpanDrive builds cloud storage in every application, acts just like a USB drive plugged into your Mac. With ExpanDrive, you can securely access any remote file server directly from the Finder or... Read more
VOX 3.0.1 - Music player that supports m...
VOX just sounds better! The beauty is in its simplicity, yet behind the minimal exterior lies a powerful music player with a ton of features and support for all audio formats you should ever need.... Read more
Merlin Project 4.3.3 - $289.00
Merlin Project is the leading professional project management software for OS X. If you plan complex projects on your Mac, you won’t get far with a simple list of tasks. Good planning raises... Read more

Latest Forum Discussions

See All

The best Black Friday mobile game deals...
With Black Friday in full swing, more and more mobile games have been going on sale. Many of mobile's finest games are available at crazy discounts. If you haven't yet, check out part one of our Black Friday game discount roundup. Here are the... | Read more »
Animal Crossing: Pocket Camp mid-game gu...
By this point, you've probably hit or surpassed mid-way inAnimal Crossing: Pocket Camp.The game changes quite a bit as your focus slowly shifts from endlessly fulfilling requests for campsite buddies to improving your amenities. Here are a few tips... | Read more »
Mille Bornes (Games)
Mille Bornes 1.0 Device: iOS Universal Category: Games Price: $1.99, Version: 1.0 (iTunes) Description: | Read more »
Blob gets a new look in Give It Up! 3
Blob makes his triumphant return, as Yoozoo Games and Invictus Gaming have joined forces to create Give It Up! 3, the third in a series of delightful action-adventure games featuring our wobbly friend Blob. In this newest adventure, you’ll get to... | Read more »
148Apps' Ultimate Guide to Black Fr...
Black Friday is here, and there are a whole lot of discounts running right now for folks on the lookout for new mobile devices, accessories, and yes, even games. Here's a helpful rundown of what you'll find both in stores and online. Happy... | Read more »
The best Black Friday mobile game deals
Black Friday's upon us, and if you've happened to nab a fancy new phone during the week's big savings, you might be searching for some new games to fill up space on your new gadget. There are a lot of great games on sale right now for Black Friday... | Read more »
The best mobile games to play while your...
Thanksgiving is a time to reconnect with loved ones, eat lots of food, and all of that jazz, but once the festivities start to wind down, folks tend to head to the couch to watch whatever football is happening for Turkey Day. | Read more »
The best Black Friday deals for Apple ga...
Black Friday is hours away at this point, but many popular retailers are getting a jump on things with plenty of pre-Black Friday sales already available. Many of those early bird sales including some sharp discounts on the latest Apple phones... | Read more »
The Inner World 2 (Games)
The Inner World 2 1.0 Device: iOS Universal Category: Games Price: $4.99, Version: 1.0 (iTunes) Description: Solve mind-bending puzzles in a world full of mystery and save the family of the flute-noses! Their dynasty has been... | Read more »
warbot.io wants you for the robot wars
Fans of epic gundam-style battles will find a lot to love in warbot.io, the first game for up and coming developer Wondersquad. The game saw a lot of success when it first launched for browsers and Facebook, and now even more people are getting the... | Read more »

Price Scanner via MacPrices.net

Apple 9″ 32GB iPad for $80 off on Walmart onl...
Snag a 9.7″ 32GB WiFi iPad for $249 on Walmart’s online store as part of their Black Friday sale. That’s $80 off MSRP, and it’s the lowest price available for an iPad so far this season. Sale price... Read more
Apple Black Friday sale for 2017: $150 Apple...
BLACK FRIDAY Apple has posted their Black Friday deals for 2017. Receive a $150 Apple gift card with the purchase of select Macs and up to $100 with various iPads, iPhones, and Apple Watches. The... Read more
Black Friday 2017: Where to find the best dea...
B&H Photo has 15″ and 13″ MacBook Pros on sale for up to $200 off MSRP as part of the Black Friday and Holiday sale. Shipping is free, and B&H charges sales tax for NY & NJ residents only... Read more
Black Friday 2017: Where to find the best dea...
B&H Photo has 12″ MacBooks on sale for $150 off MSRP as part of the Black Friday and Holiday sale. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 12″ 1.2GHz... Read more
Black Friday 2017: Where to find the best dea...
B&H Photo has 10.5″ iPad Pros in stock today and on sale for up to $130 off MSRP. Each iPad includes free shipping, and B&H charges sales tax in NY & NJ only: – 10.5″ 64GB WiFi iPad Pro... Read more
Black Friday 2017: Where to find the best dea...
B&H Photo has 13″ MacBook Airs on sale for up to $150 off MSRP as part of the Black Friday and Holiday sale. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 13″... Read more
Black Friday 2017: Where to find the best dea...
B&H Photo has 27″ and 21″ iMacs on sale for up to $200 off MSRP as part of the Black Friday and Holiday sale. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 27... Read more
Black Friday 2017: Where to find the best dea...
B&H Photo has Mac minis on sale for $100 off MSRP as part of their Black Friday sale, each including free shipping plus NY & NJ sales tax only: – 1.4GHz Mac mini: $399 $100 off MSRP – 2.6GHz... Read more
Black Friday 2017: Find the best deals and lo...
Scan our exclusive price trackers for the latest Black Friday 2017 sales & deals and the lowest prices available on Apple Macs, iPads, and gear from Apple’s authorized resellers. We update the... Read more
Black Friday: 27″ 3.4GHz iMac for $1599, save...
Amazon has the 27″ 3.4GHz Apple iMac on sale for $1599.99 as part of their Black Friday sale. That’s $200 off MSRP, and shipping is free. Their price is currently the lowest price available for this... Read more

Jobs Board

Information Systems Engineer, *Apple* Retai...
# Information Systems Engineer, Apple Retail Engineering Job Number: 112895982 Santa Clara Valley, California, United States Posted: 02-Oct-2017 Weekly Hours: 40.00 Read more
Commerce Engineer, *Apple* Media Products (...
# Commerce Engineer, Apple Media Products (New York City) Job Number: 113028813 New York City, New York, United States Posted: 20-Sep-2017 Weekly Hours: 40.00 **Job Read more
Business Development Manager, *Apple* Pay -...
# Business Development Manager, Apple Pay Job Number: 112919084 Santa Clara Valley, California, United States Posted: 18-Aug-2017 Weekly Hours: 40.00 **Job Summary** Read more
Digital Marketing Media Planner, *Apple* Se...
# Digital Marketing Media Planner, Apple Services Job Number: 113080212 Culver City, California, United States Posted: 03-Oct-2017 Weekly Hours: **Job Summary** Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.