TweetFollow Us on Twitter

Real-time Driver
Volume Number:5
Issue Number:10
Column Tag:Assembly Lab

Related Info: Serial Drivers File Mgr (PBxxx) Event Manager
Time Manager

Real-Time Driver

By Jeff E. Mandel, MD MS, New Orleans, LA

A Real-Time Device Driver in MPW Asm

When working in the laboratory or in engineering, it is often necessary to use the Mac to control serial devices. Such devices are generally configured to respond to simple commands, and provide a simple response. An example would be the American Edwards AccuPro™ Volumetric Infusion Pump, which is a device for delivering intravenous infusions of drugs. This device contains an RS-232 interface, supports full duplex 2400 baud communication, and has a simple command language for setting and interrogating the device’s infusion rate, the limits for infused volume and infusion time, the volume already infused, and the status of the pump.

Programming the pump involves four steps; the command string is built in memory, a pointer to this string is placed in a parameter block for a _PBWrite, a _PBRead is used to obtain the pump’s response, and the returned string is decoded. While this may seem simple, one must remember that the serial communication takes a significant amount of time, and could take forever if the pump or the serial line fails. Additionally, the serial communications controller is capable of functioning with minimal CPU supervision, which transpires at interrupt level, and thus, it would be nice to use asynchronous device driver calls, to free the Mac to work on keeping the user interface going, while the serial controller handles the IO in the background.

The program I will describe for performing these tasks is a driver. Most Mac programmers are familiar with drivers from writing DAs, however, a device driver is somewhat of a different animal, particularly when one wishes it to be “real-time” without intervention from the foreground program. The device driver has several purposes:

1) To insulate the application from the peculiarities of the device, so that the device can be changed without requiring a change in the application. Additionally, the device could be simulated by a driver, so that debugging of application code can be done without having to have the physical device.

2) To insulate the application programmer from having to understand how serial communications, real-time IO, etc. work.

3) To permit all of the resources associated with the IO task to be grouped together, so that they can be installed and uninstalled easily.

In writing such a driver, it is important to recall several important factors:

1) Drivers cannot utilize application globals for their own storage.

2) Drivers are only notified of events that pertain to them when they own the frontmost window, and then only receive mouse, keyboard, update, and activate events.

3) Activities which occur at interrupt level (i.e. ioCompletion routines, Vertical retrace tasks, Time manager tasks, etc.) are extremely limited in what they can do, due to the uncertainty of the heap.

In order to write such a driver, several decisions were made:

1) The driver utilizes app1Evts to signal that it needed to regain control. Thus, the serial reads and writes utilize an ioCompletion routine which simply posts an app1Evt.

2) Serial driver calls have a time limit. When the serial call is queued (asynchronously), a Time manager task is primed. If the serial IO completed first, it stops the Time manager task from completing by setting the tmCount field to zero, and if the read or write did not complete within the specified time, the time manager task issues a _KillIO call on the relevant serial driver. This results in the ioCompletion routine being called, which notifies the driver. The time manager task is contained in a resource of type ‘TMMR’, which is loaded into the heap, locked, dereferenced, and the pointer placed in the tmAddr field of the time manager queue entry. The resource also contains a longword of private storage, which holds a pointer to a private parameter block (used for the KillIO call).

3) App1evts are posted with the parameter block pointer of the completed serial call as the message. The pump driver places the parameter block pointer of the pending pump driver in the ioMisc field of the serial call parameter block so the downstream routines can keep track of it. Alternatively, the downstream routines could get this pointer from the dCtlQHead field of the DCE.

4) App1Evts are passed to the driver by a GetNextEvent filter. This routine is called at the end of the _GetNextEvent trap, with A1 pointing to the EventRecord, and boolean result in both D0 and at 4(A7) (See Macintosh Technical Note #85). If the what field of the EventRecord equals app1Evt, the routine examines the message, and if it contains a negative word in the ioRefNum field of the parameter block pointed to by the message, it processes the event. If the event is processed, the filter sets the boolean result to False, so the the application knows not to deal with it. In either case, the routine exits by a JMP to the previous contents of the JGNEFilter global. This pointer is stored locally in our GNEFilter proc.

5) The GNEFilter is a separate resource (type = ‘GNEF’), which is loaded in the pump driver Open routine. The resource is patterned after the DRVR resource, in that it contains an offset to the code as its first word, and some local storage is provided between this word and the beginning of the code. The GNEFilter is loaded into the heap during the driver Open routine, using a _GetNamedResource call. This is done so that several drivers can share the GNEFilter, since only the first driver will load the resource into the heap. The GNEFilter keeps track of which resources have opened it by keeping their reference numbers in the local storage. Duplicate entries are avoided. The GNEFilter also keeps a parameter block pointer in its private storage for its private use.

6) When the GNEFilter processes an app1Evt with a negative ioRefNum, it accesses the parameter block pointer in the ioMisc field of the parameter block referenced in the message field of the event, and checks to see that the ioRefNum of this PB is in the list of cooperating drivers in the GNEFilter private storage. If it is, then we place the event pointer in the csParam field of the GNEFilter’s private parameter block, set the csCode to accEvent, and the ioRefNum to reference number of the ioMisc parameter block (this will be the ioRefNum of our driver; the ioRefNum of the parameter block passed in the message field will be one of the serial drivers). We then issue an immediate _Control call.

7) The Control routine supports four csCodes - accEvent, accRun, KillIO, and GoodBye. Goodbye simply JMPs to the Close routine. KillIO issues KillIO calls on the serial drivers and returns. AccRun asynchronously queues a Status call on the driver to inquire the pump status (thus, irrespective of what the application does, it will be notified of the pump status periodically). The accEvent csCode is generated by our GNEFilter, and is used to allow the driver to respond to serial IO completion at event level (that is, when the heap is consistent). The routine examines the low nibble of the ioTrap field of the parameter block pointed to by the event message. If the trap was _Write, the routine sets up the parameter block for single character reads on the serial input channel and queues an asynchronous _Read. If the trap was _Read, the routine examines the character read. If the character is a carriage return (ASCII 13), the accumulated input buffer is sent to be digested, if it is an asterisk (*), it is ignored (the McGaw pump generates these periodically to let us know it is pumping), and if it is any other character, it is appended to the input buffer. In the latter two cases, the routine queues another asynchronous _Read. In the first case, the routine posts an app2Evt with the message the pointer to the original parameter block used to queue the status call, and exits via JIODone.

8) The Status routine uses the three words in the csParam field of the parameter block to figure out what the application wants the driver to send to the pump. The Request field is used to look up a single character in a table (which is loaded from a resource of type ‘PDDF’). This character specifies which of the pump functions is to be interrogated or set, as specified in the Action field. The Info field contains the numeric value to be passed to the pump and/or returned to the application. The pump in general wants decimal integers, but in some cases wants a hex word, and the formatting information is specified in the table. Having constructed the string to be sent to the pump, the routine allocates a parameter block, places the string pointer in the ioBuffer field, the pointer to the driver Status parameter block in the ioMisc field, fills in the ioCompletion address, and queues an asynchronous _Write. Note that if the noQueueBit of the trap is set, the Status routine places the request at the head of the queue. It does this by checking the queue, and if there are zero or one queue entries, issuing the _Status call asynchronously, but if there are two or more queue entries, it slips the request after the current queue head by changing the qLink fields of the qHead PB and the PB in question.

9) The Open routine loads the GNEFilter and time manager task (as detailed above), opens the serial drivers and configures them for the pump, loads the pump request table, allocates the dCtlStorage handle, and sets up the driver globals there.

10) The Close routine removes the time manager task, closes the serial ports, removes the driver’s reference number from the GNEFilter private storage, and restores the previous GNEFilter if it is the last value there. It then deallocates all the pointers and handles it allocated and exits.

The application thus needs only do the following things to utilize the driver:

1) Open the driver

2) Allocate a pointer for the parameter block, setting the three words in the csParam field to pass the desired function, and queue the _Control call. The call should be made asynchronously. Immediate calls can be used to “jump the line”, that is, make sure the call is the next one to be taken from the queue.

3) The event loop should handle app2Evts by first processing the information in the ioResult and csParam fields, then disposing of the pointer.

4) If the pump driver is to function irrespective of what the application is doing, the application must frequently call _GetNextEvent with the event mask app1Evt mask set. In order to guarantee this you will need a FilterProc for ModalDialogs and Alerts which calls _GetNextEvent with the event mask set to app1Mask when the routine receives a null event, and a DragHook and MenuHook which calls _GetNextEvent with the event mask set to app1Mask. Additionally, any compute-intensive routines might include a call to the DragHook routine. The alternative is to keep track of driver calls and repost the ones that time out.

5) Call _SystemTask if you want periodic events.

6) Prior to closing the driver, you should do one of two things:

a) Issue a _KillIO call on the driver to flush the queue.

b) Wait until the queue empties itself. This can be done by waiting until the dCtlQHead field of the driver’s DCE is zero.

This is necessary because the _Close trap sits and waits for the driver to complete the pending request. The driver cannot complete the request, however, without the event loop, so we hang forever.

7) While the driver is set up to handle goodbye kisses to close the structures, it is much safer to close the driver explicitly, due to the serious adverse consequences of exiting without restoring the JGNEFilter pointer. The truly paranoid can load the GNEFilter into the system heap. The same caveat applies to the time manager queue entry (the pointer, not the routine) - if this is deallocated but not removed from the time manager queue, bad stuff will happen. I have not extensively worked on making the driver “safe as milk”, in general, during debugging, if it crashed, I rebooted. But then, I just got my Mac II.

8) The program is written in MPW assembler, and uses the structured programming macros. I have hacked up some of these to make them work properly for writing drivers. The only significant change is in DRVRExit, which checks the noQueueBit of the argument, and if it is clear, exits via the JIODone vector, otherwise, RTS.

The code for the driver, the GNEFilter, and the timer task, as well as the rez files and the shell commands to build the driver are presented below. Note that I actually build the driver as a desk accessory. This is done so that I can install it with the DA Mover. This is easier during development, but once the driver is debugged, it can be changed with the resource editor.

The sources have been hacked for the sake of brevity. All INCLUDES were deleted, many equates omitted, and code specific to the pump deleted as well. If you really want to assemble this, get the source disk.

 TITLE  ‘Pump driver’
ParamBlockSize equ 108
ActionOffsetequ  csParam
RequestOffset  equ csParam+2
InfoOffsetequ  csParam+4

EnabledFlagsequ  (1<<dStatEnable) \
+ (1<<dCtlEnable) + (1<<dNeedTime)

EventMask equ  1<<app1Evt

DStore  Record 0
WriteUnit DS.W   1
ReadUnitDS.W1
TimeCount DS.L   1
KillBlock DS.L   1
KillTaskDS.L1
IncomingLength DS.B1
IncomingString DS.B9
 Align  2
TableOffset equ  *
TableLenDS.W1
Table   DS.W5
 ENDR

IOStringRecord 0
OutgoingString DS.B8
ReadBufferDS.B   1
 Align  2
StringAllocation equ *
 ENDR

 DRVRStartDRVREntry
 
 DRVRBeginSave=A2-A4/D1-D2,\ with=(DStore,IOString,GNEGlobals);

 DC.B   EnabledFlags
 DC.B   0
 DC.W 7*60;  7 seconds
 DC.W EventMask
 DC.W 0 ; No menu

 DC.W DRVROpen
 DC.W DRVRPrime
 DC.W DRVRControl
 DC.W DRVRStatus
 DC.W DRVRClose

DRVRTitle
 DC.B ‘PumpDriver’
 ALIGN  2

DRVROpenDRVREnter
 MOVE.L A1,A2

*  Load the pump request table from the
*  resource fork

 Call _GetNamedResource:L (#’PDDF’:L,  #’Table’:A ),A4:L
 EXG  A0,A4
 _HLock
 _GetHandleSize
 If#  D0LT.L#0 Then.S
 MOVE.W #openErr,ioResult(A4)
 Return
 EndIf#
 EXG  A0,A4
 MOVE.L D0,D1
 MOVE.L A0,-(SP)

*  Get a new handle to put the Driver
*  globals and the pump request table into

 MOVE.L A1,-(SP)
 ADD.L  #TableOffset,D0
 _NewHandle ,clear
 _HLock
 MOVE.L A0,dCtlStorage(A2)
 MOVE.L (A0),A1
 MOVE.L A1,A3
 ADD.L  #TableOffset,A1
 MOVE.L (ResHandle),A0
 MOVE.L D1,D0
 _BlockMove
 Call _ReleaseResource ( ResHandle:L)
 MOVE.L (SP)+,A1

*  Open the serial drivers and set them up
*  for the pump  (I have ommitted the .AIN code
*  since it is identical
 
 MOVE.L #ParamBlockSize,D0
 _NewPtr ,clear
 LEA    #’.AOUT’,A2
 MOVE.L A2,ioNamePtr(A0)
 MOVE.B #fsWrPerm,ioPermssn(A0)
 _Open
 If# D0 NE.W #noErrThen.S
 MOVE.L (SP)+,A0
 MOVE.W #openErr,ioResult(A0)
 Return
 EndIf#
 MOVE.W ioRefNum(A0),
 WriteUnit(A3)

*  Set the output port for 2400 baud, 1
*  stop, no parity, eight bit communication

 MOVE.W #PortSetting,csParam(A0)
 MOVE.W #8,csCode(A0)
 _Control
 
 _DisposPtr

*  Set up a parameter block for the serial
*  IO timeout function. The pointer is
*  stored in the Driver private storage.
*  Insert task into the time manager queue
*  which performs the IO timeout function.

 MOVE.L #ParamBlockSize,D0
 _NewPtr ,clear
 MOVE.L A0,KillBlock(A3)
 MOVE.L #1500,TimeCount(A3)
 MOVE.L #tmQSize,D0
 _NewPtr
 MOVE.L A0,KillTask(A3)
 Call TimeOutInstall ( A0:L ,
 KillBlock(A3):L )

*  Install the GNEFilter

 Call _GetNamedResource:L ( #’GNEF’:L
 , #’GNEFilter’:A ),A2
 CMPA #0,A2
 If#  NEThen.S
 MOVE.L (A2),A2
 MOVE.W Drvr_num(A2),D1
 If#  D1 EQ.W  #0Then.S
 MOVE.W (A2),D0
 LEA  (A2,D0.W),A3
 MOVE.L JGNEFilter,-4(A3)
 MOVE.L A3,JGNEFilter
 MOVE.L #ParamBlockSize,D0
 _NewPtr ,clear
 MOVE.L A0,Control_Ptr(A2)
 EndIf#
 MOVE.W dCtlRefNum(A1),D2
 If# D1 LE #entry_slots Then.S
 For# D1 DownTo #1 Do.S
 If# Drvr_num(A2,D1.W*2) EQ.W
 D2 Then.S
 GoTo#.SDuplicateDrvr
 EndIf#
 EndF#
 ADD.W  #1,Drvr_num(A2)
 MOVE.W Drvr_num(A2),D1
 MOVE.W D2,
 Drvr_num(A2,D1.W*2)
 Else#.S
 
*  Get the Resource ID for the driver to
*  calculate the ID of owned Alert
*  (sub ID 0)

 LEA  DRVREntry,A0
 _RecoverHandle
 LINK A6,#-12
 Call _GetResInfo ( A0:L , (A6):A ,
 4(A6):A , 8(A6):L )
 MOVE.W (A6),D2
 UNLK A6
 MULU #32,D2
 ADD.W  #Owned,D2
 Call _CautionAlert:W ( D2:W ,
 0:L ),CC
 EndIf#
 EndIf#
DuplicateDrvr:
 MOVE.L (SP)+,A0
 MOVE.W #openErr,ioResult(A0)
 Return
 
DRVRClose DRVREnter
 MOVE.L A0,-(SP)
 MOVE.L dCtlStorage(A1),A2
 MOVE.L (A2),A3

 MOVE.L #ParamBlockSize,D0
 _NewPtr ,clear
 MOVE.W ReadUnit(A3),ioRefNum(A0)
 _Close
 MOVE.W WriteUnit(A3),    ioRefNum(A0)
 _Close
 _DisposPtr
 
 MOVE.L KillTask(A3),A0
 _RmvTime
 _DisposPtr
 MOVE.L KillBlock(A3),A0
 _DisposPtr
 
 Move.L A2,A0
 _DisposHandle
 
 MOVE.W dCtlRefNum(A1),D2
 Call _GetNamedResource:L (
 #’GNEF’:L , #’GNEFilter’:A ),A2
 CMPA #0,A2
 If#  NEThen.S
 MOVE.L (A2),A3
 MOVE.W Drvr_num(A3),D1
 If#  D1 GT.W  #1Then.S
 While# D2 NE.W
 Drvr_num(A3,D1.W*2) Do.S
 DBEQ.W D1,DuplicateClose
 EndW#
 If# D1 NE.W Drvr_num(A3) Then.S
 ADD.W  #1,D1
 For# D1To Drvr_num(A3)
 Do.S
 LEA  Drvr_num(A3,D1.W*2),
 A4
 MOVE.W (A4),-2(A4)
 EndF#
 EndIf#
 SUBQ.W #1,Drvr_num(A3)
 ElseIf#.SD1 EQ.W #1 Then.S
 If# D2 NE.W Drvrentries(A3)
 Then.S
 GoTo#.SDuplicateClose
 EndIf#
 MOVE.L GNE_Next(A3),
 JGNEFilter
 Call _ReleaseResource ( A2:L )
 EndIf#
 EndIf#
DuplicateClose:  
 MOVE.W #noErr,D0
 MOVE.L (SP)+,A0
 DRVRExit ioTrap(A0)
 
DRVRPrime DRVREnter
 MOVE.W noErr,D0
 Return

DRVRStatusDRVREnter

*  First, check to see if this is an
*  immediate call. If so, it “jumps the
*  line”, and will be the next call serviced
*  after the current one (if any) is
*  completed.

 MOVE.W ioTrap(A0),D1
 BTST #noQueueBit,D1
 If#  NEThen.S ;Immediate call
 LEA  dCtlQHead(A1),A2
 CMP.L  #0,(A2)
 If#  EQThen.S ;queue empty
 _Status ,async
 Return
 EndIf#

 MOVE.L (A2),D1
 CMP.L  4(A2),D1
 If# EQ Then.S ; only one entry
 _Status ,async
 Return
 EndIf#

* Fool the driver into thinking this is an
* asynchronous queue entry
 
 MOVE.W ioTrap(A0),D1
 BCLR   #noQueueBit,D1
 BSET   #asyncTrpBit,D1   MOVE.W D1,ioTrap(A0)
 MOVE.W #1,ioResult(A0)

*  Get parameter block of queue head, put
*  qLink of qHead in current parameter
*  block;and replace it with current
*  parameter block pointer

 MOVE.L (A2),A2
 MOVE.L (A2),(A0)
 MOVE.L A0,(A2)
 Return
 EndIf#
 
 MOVE.L A0,A2
 MOVE.L dCtlStorage(A1),A4
 MOVE.L (A4),A4

 MOVE.W TableLen(A4),D1
 MOVE.W RequestOffset(A2),D0
 If#  D0 GT.W D1 Then.S ;Not a valid
 ;pump call
 MOVE.W #statusErr,ioResult(A2)
 MOVE.L A2,D0
 MOVE.W #app2Evt,A0
 _PostEvent
 MOVE.L A2,A0
 MOVE.L #statusErr,D0
 DRVRExit ioTrap(A0)
 EndIf#

 MOVE.L #ParamBlockSize,D0
 _NewPtr ,clear

*  The next section of code places a pointer
*  to the needed string, and the number of
*  characters, into the parameter block. It
*  was ommitted from this listing. 

 MOVE.W WriteUnit(A4),
 ioRefNum(A0)
 LEA  SerialComplete,A3
 MOVE.L A3,ioCompletion(A0)
 _Write ,async

*  Set up the time manager task to KillIO
*  on the channel in TimeCount
*  milliseconds. KillBlock is a previously
*  allocated parameter block.

 MOVE.L KillBlock(A4),A0
 MOVE.L WriteUnit(A4),
 ioRefNum(A0)
 MOVE.L KillTask(A4),A0
 MOVE.L TimeCount(A4),D0
 _PrimeTime
 MOVE.L #noErr,D0
 Return
 
DRVRControl DRVREnter

 If#  csCode(A0) EQ.W#accEventThen
 MOVE.L csParam(A0),A2
 MOVE.L message(A2),A2
 MOVE.W ioTrap(A2),D2
 AND.W  #$00FF,D2
 MOVE.W ioResult(A2),D3

*  Check to see the serial call was not
*  aborted by KillIO. If so, inform the
*  application, dequeue the pump driver
*  call, and return

 If# D3 EQ.W #abortErr  Then.S
 MOVE.L ioMisc(A2),A0
 EXG  A0,A2
 _DisposPtr
 MOVE.W #TimeOut,ioResult(A2)
 ADD.W  D2,ioResult(A2)
 MOVE.L A2,D0
 MOVE.W #app2Evt,A0
 _PostEvent
 MOVE.L #TimeOut,D0
 MOVE.L A2,A0
 DRVRExit ioTrap(A0)
 EndIf#

*  The serial call did not time out, so
*  figure out if it was a READ or a WRITE
*  by examining the low nybble of the trap
*  field of the parameter block.

 If#  D2EQ.W#aRdCmdThen

*  READ - examine the character read. If it
*  is a ‘*’, we ignore it and queue another
*  read. If it is a carriage return, we call
*  RespondToRead to interpret the
*  completed pump response. Any other
*  character is incorporated into the string
*  being built at IncomingString and we
*  increment the IncomingLength byte,
*  then queue another READ. If we exceed
*  8 characters, we have a problem.

 MOVE.L ioBuffer(A2),A3
 MOVE.B (A3),D1
 MOVE.L dCtlStorage(A1),A4
 MOVE.L (A4),A4
 If#  D1EQ.B#13  Then.S
 MOVE.L KillTask(A4),A0
 CLR.L  tmCount(A0)
 MOVE.L ioMisc(A2),A3
 Call RespondToRead
 MOVE.L ioMisc(A2),A0
 EXG  A0,A2
 _DisposPtr
 MOVE.L A2,D0
 MOVE.W #app2Evt,A0
 _PostEvent
 CLR.B  IncomingLength(A4)
 CLR.L  IncomingString(A4)
 CLR.L  IncomingString+4(A4)
 CLR.L  D0
 MOVE.L A2,A0
 DRVRExit ioTrap(A0)
 ElseIf#.S D1 EQ.B #’*’ Then.S
 MOVE.L A2,A0
 _Read ,async
 Return
 Else#.S
 MOVE.B IncomingLength(A4),
 D0
 EXT.W  D0
 MOVE.B D1,
 IncomingString(A4,D0.W)
 ADD.W  #1,D0
 If#  D0 LE.W  #8 Then.S
 MOVE.B D0,
 IncomingLength(A4)
 Else#.S
 MOVE.L KillBlock,A0
 MOVE.W ReadUnit(A4),
 ioRefNum(A0)
 _KillIO
 MOVE.L ioMisc(A2),A0
 EXG  A0,A2
 _DisposPtr
 MOVE.L A2,D0
 MOVE.W #app2Evt,A0
 _PostEvent
 MOVE.L A2,A0
 MOVE.L
 #TooManyCharacters,D0
 DRVRExit ioTrap(A0)
 EndIf#
 MOVE.L A2,A0
 _Read ,async
 Return
 EndIf#
 ElseIf#.S D2  EQ.W #aWrCmd Then.S
 MOVE.L dCtlStorage(A1),A4
 MOVE.L (A4),A4
 MOVE.L KillBlock(A4),A0
 MOVE.W ReadUnit(A4),
 ioRefNum(A0)
 MOVE.L A2,A0
 MOVE.W ReadUnit(A4),
 ioRefNum(A0)
 MOVE.L #1,ioReqCount(A0)
 MOVE.L ioBuffer(A0),A2
 LEA  ReadBuffer(A2),A2
 MOVE.L A2,ioBuffer(A0)
 LEA  SerialComplete,A4
 MOVE.L A4,ioCompletion(A0)
 _Read ,async
 Return
 EndIf#
 ElseIf#.S csCode(A0) EQ.W #accRun
 Then.S
 MOVE.L A0,-(SP)
 MOVE.L #ParamBlockSize,D0
 _NewPtr ,clear
 MOVE.W dCtlRefNum(A1),
 ioRefNum(A0)
 MOVE.W #S_request,
 RequestOffset(A0)
 MOVE.W #Ask,ActionOffset(A0)
 CLR.L  ioCompletion(A0)
 _Status ,async
 MOVE.L (SP)+,A0
 ElseIf#.S csCode(A0) EQ.W #killCode
 Then.S
 MOVE.L #ParamBlockSize,D0
 MOVE.L dCtlStorage(A1),A2
 MOVE.L (A2),A2
 _NewPtr ,clear
 MOVE.W ReadUnit(A2),
 ioRefNum(A0)
 _KillIO
 MOVE.W WriteUnit(A2),
 ioRefNum(A0)
 _KillIO
 _DisposPtr
 Return
 ElseIf#.S csCode(A0) EQ.W #goodBye
 Then.S
 JMP  DRVRClose
 EndIf#

 MOVE.L #noErr,D0
 DRVRExit ioTrap(A0)
 ENDP
 END

The following is the GNEFilter Code:

 TITLE  ‘GNE filter’

StackFrameRECORD {A6Link},DECR
Result  DS.W1
RetAddr DS.L1
A6Link  DS.L1
LocalSize equ    *
 ENDR
 
 MAIN
 WITH EventRecord,StackFrame
 ,GNEGlobals

Entry   DC.WGNEFilter;Offset to
 ;GNE filter
 DCB.B  GNEGlobalSize,0
 
GNEFilter:

*  If the event is not an app1Evt, go to the
*  next event in the GNE filter chain,
*  which we previously stored in GNE_Next

 LEA    Entry,A0
 CMP.W  #app1Evt,what(A1)
 BNE.S  Out

*  We have an app1Evt. Check to see if the
*  ioRefnum is negative.

 LINK A6,#LocalSize
 MOVEM.LA2/D1-D2,-(SP)
 MOVE.L message(A1),A2
 MOVE.L ioMisc(A2),A2
 MOVE.W ioRefNum(A2),D1
 If#  GEThen.S
 GoTo#.SPreOut
 EndIf#

*  We have a negative ioRefnum. Check to
*  see if it is in the list of ioRefnums
*  we are cooperating with. If it is, pass
*  the event to the driver by setting
*  up a parameter block for an immediate
*  call to the control routine.

 MOVE.L Control_Ptr(A0),A2
 LEA    Drvr_num(A0),A0
 MOVE.W (A0)+,D2 
Loop:
 For# D2 DownTo #1 Do.S
 MOVE.W (A0)+,D0
 If#  D0EQ.WD1 Then.S
 MOVE.W D1,ioRefNum(A2)
 MOVE.W #accEvent,csCode(A2)
 MOVE.L A1,csParam(A2)
 MOVE.L A2,A0
 _Control ,immed
 CLR.W  D0
 MOVE.W D0,Result(A6)
 Leave#.S Loop
 EndIf#
 EndF#
PreOut:
 MOVEM.L(SP)+,A2/D1-D2
 UNLK A6
 LEA    Entry,A0
Out:    
 MOVE.L GNE_Next(A0),A0
 JMP    (A0)
 ENDP
 END

The following is the timeout task:

 TITLE  ‘Timeout for serial IO’

 Main
 
KillStore DC.L 0
 
KillRoutine:
 LEA    KillStore,A0
 MOVE.L (A0),A0
 _KillIO
 RTS
 ENDP
 END

The following contains the timeout routine installtation, and the serial ioCompletion routine

 TITLE  ‘Timeout for serial IO’

Export  ProcedureTimeOutInstall
 ( KillTask:L , KillPtr:L )
 Begin  Save=A0-A2 

 Call _GetNamedResource:L
 ( #’TMMR’:L , #’KillRoutine’:A ),A1
 CMPA #0,A1
 If#  NEThen.S
 MOVE.L (A1),A1
 MOVE.L KillTask(FP),A0
 MOVE.L KillPtr(FP),(A1)
 LEA    4(A1),A1
 MOVE.L A1,tmAddr(A0)
 _InsTime
 EndIf#
 Return
 
 ENDP
 
*  Serial Complete - This routine is the
*  ioCompletion routine for the
*  asynchronously serial IO calls from the
*  pump driver. On completion, the routine
*  posts an app1Evt with the message the
*  parameter block of the completed serial
*  call.

Export  ProcedureSerialComplete
 Begin  Save=A5  

 MOVE.L CurrentA5,A5
 MOVE.L A0,D0
 MOVE.W #app1Evt,A0
 _PostEvent
 Return
 ENDP   
 END

The following are the shell commands to build this as a desk accessory and install it with the DA mover.

Asm TimeOut.a
Asm KillRoutine.a
link  KillRoutine.a.o 
 -o PumpDriver -ra KillRoutine=16 
 -sn ‘Main=KillRoutine’ 
 -rt TMMR=-15296
Asm GNEFilter.a
link  GNEFilter.a.o 
 -o PumpDriver -sn ‘Main=GNEFilter’ 
 -ra GNEFilter=16 -rt GNEF=-15296
Asm Pdriver.a
link Pdriver.a.o TimeOut.a.o -t DFIL 
 -c DMOV -o PumpDriver -da 
 -sn ‘Main=PumpDriver’ -rt DRVR=34
“HD 40:System Folder:Font/DA Mover”  
 PumpDriver test_drvr

 
AAPL
$99.18
Apple Inc.
-1.57
MSFT
$45.90
Microsoft Corpora
-0.46
GOOG
$568.27
Google Inc.
-9.09

MacTech Search:
Community Search:

Software Updates via MacUpdate

Cocktail Family License (5 Macs) 7.6.1 -...
Cocktail is a general purpose utility for OS X that lets you clean, repair and optimize your Mac. It is a powerful digital toolset that helps hundreds of thousands of Mac users around the world get... Read more
Cocktail 8.0 Beta 2 - General maintenanc...
Cocktail is a general purpose utility for OS X that lets you clean, repair and optimize your Mac. It is a powerful digital toolset that helps hundreds of thousands of Mac users around the world get... Read more
QuickBooks 2015 16.0.0.1352 R1 - Financi...
QuickBooks 2015 helps you manage your business easily and efficiently. Organize your finances all in one place, track money going in and out of your business, and spot areas where you can save.... Read more
Mac DVDRipper Pro 5.0.1 - Copy, backup,...
Mac DVDRipper Pro is the DVD backup solution that lets you protect your DVDs from scratches, save your batteries by reading your movies from your hard disk, manage your collection with just a few... Read more
Apple OS X bash Update 1.0 - Fix for sec...
The OS X bash Update fixes a security flaw in the bash UNIX shell on OS X 10.9.5 (also on OS X 10.8 and 10.7 [see Related Links below]). OS X 10.9.5 or later Downloads for OS X 10.8 and OS X 10.7 in... Read more
SyncTwoFolders 2.0.5 - Syncs two user-sp...
SyncTwoFolders simply synchronizes two folders. It supports synchronization across mounted network drives and it is a possibility to run a simulation showing in a log what will be done. Please visit... Read more
FinderPop 2.5.7 - Classic Mac utility, n...
FinderPop is a Universal preference pane that extends OS X's contextual menus using a FinderPop Items folder much as the Apple Menu Items folder used to do for the Apple menu. It has other features... Read more
VueScan 9.4.45 - Scanner software with a...
VueScan is a scanning program that works with most high-quality flatbed and film scanners to produce scans that have excellent color fidelity and color balance. VueScan is easy to use, and has... Read more
LibreOffice 4.3.2.2 - Free Open Source o...
LibreOffice is an office suite (word processor, spreadsheet, presentations, drawing tool) compatible with other major office suites. The Document Foundation is coordinating development and... Read more
calibre 2.4 - Complete e-library managem...
Calibre is a complete e-book library manager. Organize your collection, convert your books to multiple formats, and sync with all of your devices. Let Calibre be your multi-tasking digital... Read more

Latest Forum Discussions

See All

iKeywi - Customizable 5-Row Keyboard (U...
iKeywi - Customizable 5-Row Keyboard 1.0 Device: iOS Universal Category: Utilities Price: $.99, Version: 1.0 (iTunes) Description: Want to add an extra row to your iPhone/iPad? One of the most popular keyboard extension in iOS... | Read more »
Manage Your Cloud – Wunderlist Now Suppo...
Manage Your Cloud – Wunderlist Now Supports Dropbox Posted by Jessica Fisher on October 1st, 2014 [ permalink ] Universal App - Designed for iPhone and iPad | Read more »
Nexticy Review
Nexticy Review By Jennifer Allen on October 1st, 2014 Our Rating: :: IDEAL FORM CREATIONiPad Only App - Designed for the iPad Nexticy allows you to make your own forms for research purposes or to organize your business better. It’s... | Read more »
Tiny Troopers: Alliance Marches onto the...
Tiny Troopers: Alliance Marches onto the App Store Tomorrow Posted by Jessica Fisher on October 1st, 2014 [ permalink ] Tiny Troopers: Alliance, by Kukouri, is a | Read more »
HeroCraft Introduces Unlimited Sequel to...
HeroCraft Introduces Unlimited Sequel to WW2: Sandbox. Strategy & Tactics Posted by Jessica Fisher on October 1st, 2014 [ permalink ] | Read more »
RGB Express Review
RGB Express Review By Jennifer Allen on October 1st, 2014 Our Rating: :: DELIGHTFUL PUZZLINGUniversal App - Designed for iPhone and iPad Guide trucks along their delivery routes in RGB Express, a testing but charming puzzle game... | Read more »
The Sagas of Fire*Wolf (Games)
The Sagas of Fire*Wolf 1.0 Device: iOS Universal Category: Games Price: $9.99, Version: 1.0 (iTunes) Description: | Read more »
BuggyFun Review
BuggyFun Review By Amy Solomon on October 1st, 2014 Our Rating: iPad Only App - Designed for the iPad BuggyFun allows children to create their own tracks for bugs to interact with for a unique open-ended experience.   | Read more »
Fold the Adventure Review
Fold the Adventure Review By Jennifer Allen on October 1st, 2014 Our Rating: :: AWKWARD FOLDSUniversal App - Designed for iPhone and iPad Fold pieces of paper to create platforms for a princely rabbit in this puzzle game; something... | Read more »
WW2: Sandbox. Strategy & Tactics (G...
WW2: Sandbox. Strategy & Tactics 1.0.0 Device: iOS Universal Category: Games Price: $9.99, Version: 1.0.0 (iTunes) Description: ***NOTE: Compatible with iPhone 4s and up, iPad 2 and up - may not work properly on earlier devices... | Read more »

Price Scanner via MacPrices.net

Amazon offers 13-inch MacBook Air for $899, $...
Amazon.com has the 13″ 1.4GHz 128GB MacBook Air on sale for $100 off MSRP including free shipping: - 13″ 1.4GHz 128GB MacBook Air: $899.99 Read more
Apple resting On Its iPhone Laurels? – The ‘B...
Apple calls its new iPhone 6 and 6 Plus “The Biggest Advancements in iPhone History,” but does reality live up to the hype? “Seldom have so many waited so breathlessly for so little,” tweeted veteran... Read more
Roundup of Apple Mac and iPad Education disco...
Purchase a new Mac or iPad at The Apple Store for Education and take up to $300 off MSRP. All teachers, students, and staff of any educational institution qualify for the discount. Shipping is free,... Read more
Apple Boycotts German Magazine Computer Bild...
Apple has revoked its PR accreditation of Germany’s Computer Bild, Europe’s best-selling PC magazine, in reaction to Bild’s posting of a “#Bentgate” YouTube video. Axel Telzerow, editor in chief of... Read more
iPhone 6 & iPhone 6 Plus Available in Chi...
Apple has announced that iPhone 6 and iPhone 6 Plus will be available in China beginning Friday, October 17 from the Apple Online Store (http://www.apple.com), Apple’s retail stores, and an expansive... Read more
MacBook Airs on sale for $100 off MSRP, start...
Best Buy has the new 2014 MacBook Airs on sale for $100 off MSRP on their online store. Choose free home shipping or free local store pickup (if available). Prices valid for online orders only, in-... Read more
Apple Releases OS X Mavericks bash Update 1.0...
Apple has released a patch update for OS X Mavericks users to address the recently-detected “Shellshock” security bug in BSD UNIX’s bash shell. Apple says only a few Mac users who had manually... Read more
Pivotal Payments Ready for Apple Pay – FlexPo...
Pivotal Payments, a provider of merchant services and global payment processing solutions, has announced its proprietary FlexPoint platform will support credit and debit transactions through Apple’s... Read more
iStabilizer Announces Tabarm — First Friction...
iStabilizer, a specialist in universal lightweight compact tripods, steady cams, dollies, mounts, and remotes for smartphones, tablets, and cameras, announced today the iStabilizer tabArm, the first... Read more
IStabilizer Flex Smartphone Tripod Wins Usa T...
iStabilizer, a specialist in universal lightweight compact tripods, steady cams, and other products for smartphones, tablets, and cameras, has announced today that its iStabilizer Flex smartphone... Read more

Jobs Board

*Apple* Retail - Multiple Positions (US) - A...
Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, you're also the Read more
*Apple* Retail - Multiple Positions (US) - A...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Senior Event Manager, *Apple* Retail Market...
…This senior level position is responsible for leading and imagining the Apple Retail Team's global event strategy. Delivering an overarching brand story; in-store, Read more
*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
Project Manager / Business Analyst, WW *Appl...
…a senior project manager / business analyst to work within our Worldwide Apple Fulfillment Operations and the Business Process Re-engineering team. This role will work Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.