TweetFollow Us on Twitter

Forth DA
Volume Number:3
Issue Number:2
Column Tag:Threaded Languages

Building Desk Accessories with Forth

By Jörg Langowski, MacTutor Editorial Board, Grenoble, France

A template desk accessory in Mach2

Any of our readers who has taken a close look at Mach2 code will have noticed that the output generated by the Forth compiler resembles very much that of 'classical' compiled languages like Pascal. Disassembly shows that much of the code is inline-generated machine code, and references to kernel routines are not too frequent.

This is one of the strong points of Mach2; retaining most of the ease of programming and debugging with a Forth interpreter, you can not only generate stand-alone applications, but also things that are much more dependent on interacting directly with the operating system such as VBLtasks that run independently of a runtime Forth kernel (see my article in V2#6 ); one could also imagine to create INIT resources, MDEFs or WDEFs and... desk accessories.

The problem with Forth code in general is that a 'stand-alone-application' generated by any Forth system available for the Macintosh contains - and is dependent on - at least part of the run time Forth kernel. Whether the kernel contains the interpreter (as in MacForth) or the task of interpreting is taken over by the CPU itself in subroutine threaded code such as Mach2 - the standard I/O routines, window handling, controls, menus etc. all come in a pre-written package that will form part of the stand-alone application. To write something like a desk accessory in Forth, this would imply that the runtime package had to be part of the DA. This is (a) not very practical because space-consuming and (b) not an available option in any Forth for the Macintosh that I'm aware of.

Nevertheless, Mach2 allows us to create a functioning desk accessory without too much effort and allows me to simultaneously illustrate some principles of DA programming to you at the same time.

DA strategy for implementation in Mach2

How would we proceed to build a desk accessory using Mach2? The DA is a DRVR resource. We would have to create this resource in memory first, then write it out to a resource file. There are resource manager routines that allow us to do this; AddResource will add a new resource to the current resource file, given a handle to a data structure in memory, and UpdateResFile saves these changes to the resource file. So all we have to do is to create a data structure of the format of a desk accessory, get a handle to it and call AddResource with the type DRVR to create the new driver, then update the resource file.

The general format of a desk accessory is known from Inside Macintosh. The first couple of bytes are a header containing flags that tell the system whether the DA needs to be called periodically, and what type of calls it can respond to; a delay setting that determines the time between periodic actions; and event mask that determines what events the desk accessory will respond to; a menu ID (negative) if the DA has a menu associated with it; and offsets to the Open, Prime, Control, Status and Close routines. These latter offsets are measured from the beginning of the desk accessory to the beginning of each of the routines. The last portion of the header is a string containing the driver name.

The remaining portion of the desk accessory may be executable code and can be written in Mach2 Forth if we make sure that references to kernel routines are avoided. Before we discuss the example (listing 1), however, let me briefly summarize what happens when a desk accessory is opened.

Fig. 1 Our simple DA, written in Forth!

Opening the desk accessory

When the DA (or any driver) is opened for the first time, a device control entry is created by the system, a data structure which contains information about the driver; it is described in Inside Macintosh (II-190). It will, for instance, contain the driver flags, the delay setting, the event mask and the menu ID from the desk accessory header. Also a window pointer to a window associated with the driver may be stored here or a handle to a memory block if the DA needs to store large amounts of data.

When a driver routine (open, control, close, status, prime) is called, a pointer the driver's device control entry is passed in register A1. The other parameter, passed in A0, is a pointer to the parameter block of the call. For desk accessories, this parameter block is important for Control calls since we'll be able to tell from the parameter block what has happened that the desk accessory has to respond to, such as menu selections, periodic actions, editing commands, etc.

Glue routines

Since the parameters to the driver routines are passed in registers, we'll have to write some assembler code to make them 'digestible' for Forth, which is stack-oriented. Also, we'll save A0-A1 and restore them after the call; as IM mentions, no other registers have to be saved. One important thing to remember is that we have to setup a Forth stack before using any actual Forth code; we make A6 point to a data block sufficiently large (100 bytes in the example, but you may easily change this to have more stack space).

The glue routines then in turn call the driver routines which have been written in Forth. The routines referenced in the DA header are the glue routines, of course. The final part of listing 1 contains the stack setup, the glue routines, and the part that initializes the desk accessory header and writes the driver code to a resource file.

The code written is contained between the 'markers' startDA and endDA. For adding the resource to the file, the word make-res is provided, which gets a handle to a data structure in memory and calls AddResource with the handle, the resource type (DRVR in our case) and a resource file ID as parameters.

init-DA will initialize the desk accessory's header. This includes setting the driver flags, the driver name, an event mask, the delay time between periodic actions, and calculating and storing the offsets between the start of the DA and the beginning of the 'glue' routines. Also, the ID of the DA's own menu is stored in the header; we'll come back to that later.

make-DA calls init-DA and then writes the newly created DRVR resource with ID=12 into the file "Mach2 DA.rsrc". This file can then be used by RMaker to create a Font-DA Mover compatible file that contains the DA and any resources owned by it.

DA-owned resources

Listing 2 shows the RMaker input file. It will include the DRVR code from "Mach2 DA.rsrc" and two more resources, a window template and a menu. Both these resources have an ID of -16000, which later indicates to the Font/DA Mover that they are 'owned' by the desk accessory whose ID is 12; they will therefore be moved together with the DA. If the DA's ID is changed during the move, their IDs will be changed accordingly so that they always correspond to that of the DA.

The format of the ID number of an owned resource is given in IM (I-109); I'll briefly review it here. The ID number is always negative and bits 15 and 14 are always 1. Bits 11-13 specify the owning resource type, and are zero for a DRVR. Bits 5-10 contain the ID number of the owning resource, which therefore must be between 0 and 63. Bits 0-4 may contain a number which identifies the individual resource. Therefore, the allowed number range for owned resources is between -16384 and -1.

If the DRVR resource has an ID=12, the IDs of the owned resources start with -16000 ( if bits 0-4 are zero) and go up to -15969 ( bits 0-4 = 31). Since -16000 is a simple number to remember, the DRVR is given an ID of 12 when it is created by the program. Both the MENU and WIND resources owned by the DRVR in the example will have IDs of -16000 (which correspond to 'local' IDs of 0).

Two Forth words are provided to easily convert local IDs to owned resource IDs. getDrvrID will calculate the driver ID from its reference number, which is kept in the device control entry; and ownResID will calculate the owned resource ID from the driver ID and the local resource ID.

The desk accessory

We can now take a look at the desk accessory's main code. The Open routine is called by the DAOpen glue routine. It will do nothing if the desk accessory's window is already open, which can be checked by looking at the dCtlWindow field in the device control entry. If the DA has not been opened yet, or has been opened and then closed again, it will create a new window from the WIND resource with local ID=0 and store its pointer in the device control entry; furthermore, it stores the driver reference number in the windowKind field of the window record. By this means, the desk manager will know that a window belongs to the DA, how to find it and to send the appropriate messages to the DA when the window is activated, deactivated, the mouse clicked in its content region or when it is closed.

Open will in addition calculate the ID of the MENU resource (local ID=0) that is owned by the DA. This number is also stored in the DA header, but you cannot reliably assume that it is correct. Font/DA Mover will change the DA's ID and the IDs of its own resources correctly, but it doesn't go into the DA header and sets the correct menu ID. However, some negative menu ID has to be present in the DA header in order to tell the desk manager that the DA has to respond to menu selections. The device control entry, however, has to contain the correct menu ID; otherwise the DA won't respond to its own menu.

Close will store zero in the dCtlWindow field so that a new Open will re-create the window; it deletes the DA's menu and disposes of the heap space occupied by window and menu, then it redraws the menu bar. Close is called automatically by the Desk Manager when the close box of the DA window is clicked, or Close is selected from the File menu of an application where the DA was called.

The Prime and DrStatus routines are not needed here, and will do nothing at all.

Sending messages to the DA

The heart of the desk accessory is the Ctl routine. This routine will receive a message from the desk manager to indicate which action should be taken - a very simple implementation of object-oriented behavior, in fact. I have written a shell routine that handles some of the actions of a desk accessory; all other actions simply do nothing, but since they are included in the case statement, you can very easily add your own routines.

The message code is contained in the csCode parameter, which is in the parameter block whose address was passed in A0 when Ctl was called. Ten messages are possible:

-1 : 'good bye kiss' that will be given just before an application exits to the finder;

64 : an event should be handled;

65 : take the periodic action that has to be performed by the DA. This message is sent every time the number of ticks in the drvrDelay field of the DA header has expired;

66 : The cursor shape should be checked and changed if appropriate. This message is sent each time SystemTask is called by the application, as long as the DA is active;

67 : A menu selection should be handled. csParam contains the menu ID and csParam+2 the menu item number;

68 : handle Undo command from the Edit menu;

70 : handle Cut command;

71 : handle Copy command;

72 : handle Paste command;

73 : handle Clear command.

The example implements handlers for the first five actions; no Edit menu selections are handled. The periodic action simply consists of a short beep once every second. (You might want to change this to save your sanity if you really want to do something useful with this desk accessory). The goodBye action is also a beep, but 50 ticks long. When the desk accessory is active and you close an application, it will sound almost as if the system reboots. Don't let yourself be bothered by this.

The accCursor message will call update-cursor, which checks whether the mouse is inside the DA window and changes the cursor to the standard NNW arrow, if necessary.

The menu and event handlers are a little more complicated. First, since both will output text to the DA window, we have to write some rudimentary output routines; the Mach2 output routines won't work without the kernel. tp will type a string in the current grafPort, and crd acts the same way as cr in the Forth kernel. I've also included some numeric output routines, which you might find convenient to use; they are not needed for the example, although I used them in debugging.

The event handler(s)

The DA's response to the accEvent message has to be subdivided according to the event that has happened. Therefore, we check the what field of the event record and set up another case statement that contains the handlers for each type of event. The behavior that we'll give to our DA window is that of a document window with zoom box and size box that responds to mouse down and key down events by displaying appropriate messages in the window. The DA's own menu should be displayed when the window is activated and removed when it is deactivated.

The activate handler, therefore, first checks whether the window is activated or deactivated, gets the menu from the resource file in the first case and attaches it to the menu bar, or deletes it in the latter case.

The update handler will clear the update region and redraw the grow icon. Key down events will clear the window and display a message in the first line.

Mouse down events cannot be handled as easily as with application windows. If you call findWindow when the mouse is clicked in a desk accessory window, the code returned is always 2 (= in system window), no matter what part of the system window was clicked. The drag region and close box are handled by the desk manager, so no problem there; but we have to check ourselves for clicks in the size or zoom box. This is especially annoying for the zoom box, because we also have to keep a record of the current zoom state of the window. With application windows, the window manager takes care of this task, changing the part code that is returned by FindWindow depending on whether we have to zoom in or out.

I defined the words ?inGrow and ?inZoom that return true when the mouse click (in local coordinates) was in the size box or in the zoom box of the active window. The zoom state has to be maintained by a flag. The mouse down event handler will check for size box and zoom box clicks and change the window accordingly. The region that comprises the grow icon - which is part of the content region - will have to be added to the update region after the window has been made smaller or before it is enlarged. The word invalsize has been defined for this purpose; for resizing with the size box, we just call it before and after the resizing since we don't know the new window size. For zooming, we call invalsize before zooming in and after zooming out.

If the mouse is clicked in the content region, the window responds simply by typing a message, followed by a new line.

This takes care of mouse down events; now menus are the last thing we have to include. If the accMenu message is received by the DA, the menu item number is extracted from the parameter block and a message displayed according to the item number. Add any of your own routines here if you like.

Getting the DA started

To add the desk accessory to your system file, just load the Forth program and type make-DA. This will create a file "Mach2 DA.rsrc" on the default disk. Then run RMaker with the input given in listing 2, which will give you a small briefcase called "Mach2 DA". It contains the DRVR, MENU and WIND resources and may be used as an input to the Font/DA Mover to install the desk accessory in the system file. Good luck (you don't really need it, though).

Using the template to write 'useful' DAs

In the unlikely case that you would want to beef up the DA example to do something really useful, you should be careful about a couple of things.

First, make sure that no Forth word you use in yout routines makes part of the Mach2 kernel. This can easily be checked by including the word in a simple definition and disassembling it. If you see a JSR to a jump table entry or a JSR xxx(A5) at the position of the word, you can't use it in a DA. JSRs are only legal if they point to routines that you defined yourself. The only Mach2 words you may use are those that directly compile 68000 code; fortunately, there are quite a few of them. Some others you have to redefine: the multiply and divide operators, for example.

Second, A6 stack space may become a problem if your routines get more complicated. This is easily taken care of, but equally easy to overlook.

Third, if you redefine any general purpose routines that create kernel-independent code and could be useful to others in writing their DAs, don't hesitate to drop me a line. Nothing is more frustrating than having to reinvent the wheel...

{1}
Listing 1: Desk Accessory written in Mach2
( Mach2 desk accessory with owned resources )
( J. Langowski / MacTutor Nov. 86 )

only forth also assembler also mac

HEX
44525652 CONSTANT "drvr

BINARY
0000110111101010 CONSTANT DAEmask

( *** System globals *** )
HEX
8FC CONSTANT JioDone 

DECIMAL
( windowrecord fields, starting with grafport )
16 CONSTANT portRect ( Grafport rectangle )

( fields of WindowPeek )
108 CONSTANT windowKind 
110 CONSTANT wVisible
111 CONSTANT wHiLited
112 CONSTANT goAwayFlag
113 CONSTANT spareFlag
130 CONSTANT dataHandle
140 CONSTANT controlList
152 CONSTANT refCon

( fields of device control entry )
 4 CONSTANT dCtlFlags
 6 CONSTANT dCtlQHdr
16 CONSTANT dCtlPosition
20 CONSTANT dCtlStorage
24 CONSTANT dCtlRefNum
26 CONSTANT dCtlCurTicks
30 CONSTANT dCtlWindow
34 CONSTANT dCtlDelay
36 CONSTANT dCtlEMask
38 CONSTANT dCtlMenu

( csCodes for Ctl calls )
-1 CONSTANT goodBye
64 CONSTANT accEvent
65 CONSTANT accRun
66 CONSTANT accCursor
67 CONSTANT accMenu
68 CONSTANT accUndo
70 CONSTANT accCut
71 CONSTANT accCopy
72 CONSTANT accPaste
73 CONSTANT accClear

( *** standard parameter block data structure *** )
0   CONSTANT  qLink( pointer to next queue entry )
4   CONSTANT  qType( queue type )
6   CONSTANT  ioTrap ( routine trap )
8   CONSTANT  ioCmdAddr ( routine address )
12  CONSTANT  ioCompletion( addr of completion routine )
16  CONSTANT  ioResult  ( result code returned here )
18  CONSTANT  ioNamePtr ( pointer to file name string)
22  CONSTANT  ioVRefNum ( volume reference number )
24  CONSTANT  ioRefNum
26  CONSTANT  csCode ( type of control call )
28  CONSTANT  csParam( control call parameters )

( *** eventrecord data structure *** )
0  CONSTANT what
2  CONSTANT message
6  CONSTANT when
10 CONSTANT where
14 CONSTANT modifiers

( *** event codes *** )
0  CONSTANT null-evt
1  CONSTANT mousedn-evt
2  CONSTANT mouseup-evt
3  CONSTANT keydn-evt
4  CONSTANT keyup-evt
5  CONSTANT autokey-evt
6  CONSTANT update-evt
7  CONSTANT disk-evt
8  CONSTANT activate-evt
10 CONSTANT network-evt
11 CONSTANT driver-evt

CODE shl ( data #bits )
 MOVE.L (A6)+,D0
 MOVE.L (A6),D1
 LSL.L  D0,D1
 MOVE.L D1,(A6)
 RTS
END-CODEMACH

CODE shr ( data #bits )
 MOVE.L (A6)+,D0
 MOVE.L (A6),D1
 LSR.L  D0,D1
 MOVE.L D1,(A6)
 RTS
END-CODEMACH

( *** start of desk accessory main code *** )

header testDA ( marker for writing to DRVR resource )
 header drvrFlags  2 allot
 header drvrdelay  2 allot
 header drvrEMask  2 allot 
 header drvrMenu   2 allot
 header drvrOpen   2 allot
 header drvrPrime  2 allot
 header drvrCtl  2 allot
 header drvrStatus 2 allot 
 header drvrClose  2 allot
 header drvrname  32 allot

( *** main desk accessory routines *** )
header oldPort 4 allot    ( for storage of old grafPtr )
header temprect 8 allot
header SizeRect 8 allot   ( grow size limits )
header mouseLoc 4 allot   ( mouse location )
header NewSize 4 allot    ( for SizeWindow )
header penLoc 4 allot( pen location )
header tempString 256 allot   ( for numeric conversion etc. )
header zoomState 4 allot  ( zoomed in or out )

: whereMouse ['] mouseLoc call getMouse ['] mouseLoc @ ;

: cl  ( WPtr -- ) portrect + call eraserect ;

: tp  call drawstring ;

: crd ['] penLoc call getpen
 10 ( horizontal boundary )
 ['] penLoc w@ 12 +
 call moveto
;

CODE NumToString
 MOVE.L (A6)+,A0
 MOVE.L (A6),D0
 MOVE.W #0,-(A7)
 _Pack7
 MOVE.L A0,(A6)
 RTS
END-CODE

CODE StringToNum
 MOVE.L (A6),A0
 MOVE.W #1,-(A7)
 _Pack7
 MOVE.L D0,(A6)
 RTS
END-CODE

CODE unpack
 MOVE.L (A6),D0
 CLR.L   D1
 MOVE.W D0,D1
 CLR.W  D0
 SWAP.W D0
 MOVE.L D0,(A6)
 MOVE.L D1,-(A6)
 RTS
END-CODE

CODE pack
 MOVE.L (A6)+,D1
 MOVE.L (A6),D0
 SWAP.W D0
 MOVE.W D1,D0
 MOVE.L D0,(A6)
 RTS
END-CODE

: .d ( num -- )  ['] tempstring NumToString  tp  ;
 
( *** event-handling routines *** )

: activate-handler { menuID DAWind event-rec | -- }
 event-rec modifiers + w@ 1 and
 IF ( window activated )
 menuID call getRMenu 0 call InsertMenu  
 call drawMenuBar
 ELSE ( window deactivated )
 menuID call deleteMenu
 menuID call getRMenu call DisposMenu
 call drawMenuBar
 THEN
;
 
: update-handler { DAWind event-rec | -- }
 ['] penLoc call GetPen
 DAWind CALL BeginUpdate
    DAWind cl
    DAWind CALL DrawGrowIcon
 DAWind CALL EndUpdate
 ['] penLoc 2+ w@ ['] penLoc w@ 
 call moveto ( restore pen position )
;

: ?inGrow { localPt WPtr | b r -- flag }
 WPtr portRect + 4 +
 dup w@ -> b 2+ w@ -> r
 ['] temprect r 14 - b 14 - r b call setrect
 localPt ['] tempRect call PtInRect 
;

: ?inZoom { localPt WPtr | r -- flag }
 WPtr portRect + 6 + w@ -> r
 ['] temprect r 20 -   -16   r 8 -   -4 call setrect
 localPt ['] tempRect call PtInRect 
;

: invalSize { gPort | b r -- }
 gPort 4 + w@ -> b
 gPort 6 + w@ -> r
 ['] temprect r 16 - 0 r b call setrect
 ['] temprect call invalrect
 ['] temprect 0 b 16 - r b call setrect
 ['] temprect call invalrect
;

: mousedn-handler { DAWind event-rec | whereM DAPort -- }
 DAWind portrect + -> DAPort
 event-rec where + @ -> whereM
 whereM ['] mouseLoc !
 ['] mouseloc call GlobalToLocal
 ['] mouseloc @ dup 
 DAWind ?inGrow  
 IFDAPort invalSize
 DAWind whereM ['] SizeRect call GrowWindow 
 DAWind swap unpack swap -1 call sizewindow
 DAPort invalSize
 ELSE 
   DAWind ?inZoom
   IF   ['] zoomState @
 IF 0 ['] zoomState !
    DAWind whereM 7 call TrackBox
 IF DAPort invalSize
    DAWind 7 0 call ZoomWindow THEN
 ELSE 1 ['] zoomState !   
    DAWind whereM 8 call TrackBox
 IF DAWind 8 0 call ZoomWindow 
    DAPort invalSize THEN
 THEN
   ELSE ( in content region )
 " Mouse down" tp crd
   THEN
 THEN
;

: update-cursor  { DAWind | -- }
 whereMouse DAWind portrect + call PtInRect
 IF call InitCursor THEN
;

: getDrvrID { dCtlEntry | -- num }
 dCtlEntry dCtlRefNum + w@ l_ext
 1+ negate
;

: ownResID ( resID drvrID )
 5 shl + -16384 +
;

: Open { DCtlEntry ParamBlockRec | DAWind -- }
 ['] oldPort call GetPort
 dCtlEntry dCtlWindow + @
 0= IF ( not open already )
 0 dCtlEntry getDrvrID ownResID 
 dup dCtlEntry DCtlMenu + w! 
 ( menu ref has to be updated )
 0 0 call getNewWindow -> DAWind
 DAWind  dCtlEntry dCtlWindow + !  
 ( store window pointer )
 DAWind  dCtlEntry dCtlRefNum + w@  
 swap windowKind + w!
 DAWind  call setport
 0 ['] zoomState !
 ['] sizerect 50 50 500 320 call setrect
 10 10   call moveto
 ['] oldPort @ call setPort
 THEN
;

: Close { DCtlEntry ParamBlockRec | -- }
 dCtlEntry dCtlWindow + 
 dup @ call DisposWindow  0 swap ! 
 ( so that Open will work again )
 DCtlEntry DCtlMenu + w@ ( get menu ID )
 dup call deletemenu
 call getRMenu call disposMenu call drawMenuBar
;

: Ctl 
  { DCtlEntry ParamBlockRec | DAWind event-rec menuItem -- }

 ['] oldPort call GetPort
 dCtlEntry dCtlWindow + @ dup -> DAWind call setport
 ParamBlockRec csCode + w@ l_ext 
 CASE
 goodByeOF 50 call sysbeep ENDOF
 accEvent OF 
 ParamBlockRec csParam + @ -> event-rec
 event-rec what + w@ 
 CASE
 mousedn-evtOF   
 DAWind event-rec mousedn-handler ENDOF

 keydn-evt OF DAWind cl
 DAWind call DrawGrowIcon
 10 10 call moveto  " Key down." tp crd
 ENDOF

 autokey-evtOF ENDOF

 update-evt OF
 DAWind event-rec update-handler ENDOF

 disk-evt OFENDOF

 activate-evt  OF
  DCtlEntry DCtlMenu + w@ ( get menu ID )
  DAWind event-rec activate-handler  ENDOF

 network-evtOF ENDOF
 driver-evt OF ENDOF

 ENDCASE

 ENDOF

 accRun OF    1 call sysbeep  ENDOF
 accCursor  OF DAWind update-cursor ENDOF
 accMenuOF
 ParamBlockRec csParam + 2+ w@ l_ext
 CASE 1 OF " Item1!" tp crd ENDOF
 2 OF " Item2!" tp crd ENDOF
 3 OF " Item3!" tp crd ENDOF
 4 OF " Item4!" tp crd ENDOF
 6 OF " Item6!" tp crd ENDOF
 ENDCASE
 0 call HiLiteMenu
 ENDOF
 accUndoOFENDOF
 accCut OFENDOF
 accCopyOFENDOF
 accPaste OFENDOF
 accClear OFENDOF
 ENDCASE
 ['] oldPort @ call setPort
;

: DrStatus { DCtlEntry ParamBlockRec | -- }
;

: Prime { DCtlEntry ParamBlockRec | -- }
;

( *** glue routines *** )
header local.stack 200 allot

CODE setup.local.stack
    LEA -8(PC),A6   ( local stack grows downward from here )
    RTS
END-CODE

CODE DAOpen 
 MOVEM.L A0-A1,-(A7)
 setup.local.stack
 MOVE.L  A1,-(A6) 
 MOVE.L  A0,-(A6)
 Open
 CLR.L  D0
 MOVEM.L (A7)+,A0-A1 
RTS END-CODE

CODE DAClose  
 MOVEM.L A0-A1,-(A7)
 setup.local.stack
 MOVE.L  A1,-(A6) 
 MOVE.L  A0,-(A6)
 Close
 CLR.L   D0
 MOVEM.L (A7)+,A0-A1 
RTS END-CODE

CODE DACtl 
 MOVEM.L A0-A1,-(A7)
 setup.local.stack
 MOVE.L  A1,-(A6) 
 MOVE.L  A0,-(A6)
 Ctl
 CLR.L   D0
 MOVEM.L (A7)+,A0-A1
 MOVE.L  JioDone,-(A7) 
RTS END-CODE

CODE DAStatus 
 MOVEM.L A0-A1,-(A7)
 setup.local.stack
 MOVE.L  A1,-(A6) 
 MOVE.L  A0,-(A6)
 DrStatus
 CLR.L   D0
 MOVEM.L (A7)+,A0-A1 
RTS END-CODE

CODE DAPrime 
 MOVEM.L A0-A1,-(A7)
 setup.local.stack
 MOVE.L  A1,-(A6) 
 MOVE.L  A0,-(A6)
 Prime
 CLR.L   D0
 MOVEM.L (A7)+,A0-A1 
RTS END-CODE

header endDA
 ( *** code written to DRVR resource ends here *** )

( *** initialization routines *** ) 

: setFlags  ['] drvrFlags w! ;
: setDelay  ['] drvrDelay w! ;
: setEMask  ['] drvrEMask w! ;
: setMenuID ['] drvrMenu  w! ;

: setOpen ['] drvrOpen  w! ;
: setPrime['] drvrPrime w! ;
: setCtl['] drvrCtlw! ;
: setStatus ['] drvrStatusw! ;
: setClose['] drvrClose w! ;

: setName { addr len | target -- }
 ['] drvrName -> target
 len target c!
 addr target 1+
 len 31 > if  31 else len then
 cmove
;
 
( write resource to file ) 
: $create-res ( str-addr - errcode )
 call CreateResFile
 call ResError L_ext
;

: $open-res { addr | refNum - refNum or errcode }
 addr call OpenResFile -> refNum
 call ResError L_ext
 ?dup IF ELSE refNum THEN
; 

: close-res ( refNum - errcode )
 call CloseResFile
 call ResError L_ext
;

: make-res { addr len rtype ID name | -- }
 addr len call PtrToHand 
 abort" Could not create resource handle"
 rtype ID name call AddResource
;

: write-out { filename | refnum -- } 
 filename $create-res 
 abort" That resource file already exists"
 filename $open-res
 dup 0< abort" Open resource file failed"
 -> refnum
 refnum call UseResFile
 ['] testDA ['] endDA over - 
 "drvr 12 " Mach 2 DA" make-res
 refnum close-res abort" Could not close resource file"
;

: install-system { | refnum -- }
 " System" $open-res
 dup 0< abort" Open resource file failed"
 -> refnum
 refnum call UseResFile
 "drvr 25 call getresource call rmveresource
 ['] testDA ['] endDA over - 
 "drvr 25 " Mach 2 DA" make-res
 refnum call UpdateResFile
;

: init-DA
( initialize offsets )
 ['] DAOpen ['] testDA -  setOpen 
 ['] DAPrime   ['] testDA -   setPrime
 ['] DACtl     ['] testDA -   setCtl 
 ['] DAStatus  ['] testDA -   setStatus
 ['] DAClose   ['] testDA -   setClose
( initialize driver name )
 " Mach 2 DA" count setname
( initialize driver flags, NeedTime, NeedGoodBye, CtlEnable )
 [ hex ] 3400 setFlags [ decimal ]
( initialize delay time )
 60 setDelay
( initialize event mask, events recommended in IM )
 DAEMask setEMask 
( initialize menu ID, local ID=0 for DRVR ID=12 )
 -16000 setMenuID 
 ( careful! this field will NOT be changed
 by the DA Mover when ID is changed )
;
 
: make-DA
 init-DA
 " Mach2 DA.rsrc" write-out
;

: install-DA init-DA install-system bye ;
{2}
Listing 2: RMaker input
file for the DA example

*   Resources for MACH 2 
desk accessory J. Langowski 1986

Mach2 DA
DFILDMOV

INCLUDE Mach2 DA.rsrc

Type MENU
     ,-16000
My DA
Item 1
Item 2
Item 3
Item 4
(-
Item 6


Type WIND
     ,-16000
Mach2 Desk Accessory
100 131 300 381
Visible GoAway
8
0
 
AAPL
$524.94
Apple Inc.
+5.93
MSFT
$40.01
Microsoft Corpora
-0.39
GOOG
$536.10
Google Inc.
-20.44

MacTech Search:
Community Search:

Software Updates via MacUpdate

VMware Fusion 6.0.3 - Run Windows apps a...
VMware Fusion allows you to create a Virtual Machine on your Mac and run Windows (including Windows 8.1) and Windows software on your Mac. Run your favorite Windows applications alongside Mac... Read more
Tweetbot 1.5.1 - Popular iOS twitter cli...
Tweetbot is a full-featured OS X Twitter client with a lot of personality. Whether it's the meticulously-crafted interface, sounds and animation, or features like multiple timelines and column views... Read more
Mac DVDRipper Pro 4.1.7 - Copy, backup,...
Mac DVDRipper Pro is the DVD backup solution that lets you protect your DVDs from scratches, save your batteries by reading your movies from your hard disk, manage your collection with just a few... Read more
PDFpenPro 6.2 - Advanced PDF toolkit for...
PDFpenPro allows users to edit PDF's easily. Add text, images and signatures. Fill out PDF forms. Merge or split PDF documents. Reorder and delete pages. Even correct text and edit graphics! Create... Read more
PDFpen 6.2 - Edit and annotate PDFs with...
PDFpen allows users to easily edit PDF's. Add text, images and signatures. Fill out PDF forms. Merge or split PDF documents. Reorder and delete pages. Even correct text and edit graphics! Features... Read more
Monolingual 1.5.9 - Remove unwanted OS X...
Monolingual is a program for removing unnecesary language resources from OS X, in order to reclaim several hundred megabytes of disk space. It requires a 64-bit capable Intel-based Mac and at least... Read more
Maya 2015 - Professional 3D modeling and...
Maya is an award-winning software and powerful, integrated 3D modeling, animation, visual effects, and rendering solution. Because Maya is based on an open architecture, all your work can be scripted... Read more
Starcraft II: Wings of Liberty 1.1.1.180...
Download the patch by launching the Starcraft II game and downloading it through the Battle.net connection within the app. Starcraft II: Wings of Liberty is a strategy game played in real-time. You... Read more
Sibelius 7.5.0 - Music notation solution...
Sibelius is the world's best-selling music notation software for Mac. It is as intuitive to use as a pen, yet so powerful that it does most things in less than the blink of an eye. The demo includes... Read more
Typinator 5.9 - Speedy and reliable text...
Typinator turbo-charges your typing productivity. Type a little. Typinator does the rest. We've all faced projects that require repetitive typing tasks. With Typinator, you can store commonly used... Read more

Latest Forum Discussions

See All

Have a Special Dead Trigger 2 Easter Bas...
Have a Special Dead Trigger 2 Easter Basket Full of Goodies, Courtesy of Madfinger Games Posted by Rob Rich on April 18th, 2014 [ permalink ] Dead Trigger 2 | Read more »
Almost All of Playdek’s Library is on Sa...
Almost All of Playdek’s Library is on Sale Right Now, and You Should Check it Out Posted by Rob Rich on April 18th, 2014 [ permalink ] Playdek has released quite a few great iOS ports of board and card games over the years, and now most of them... | Read more »
Zynga Launches Brand New Farmville Exper...
Zynga Launches Brand New Farmville Experience with Farmville 2: Country Escape Posted by Tre Lawrence on April 18th, 2014 [ permalink ] | Read more »
David. Review
David. Review By Cata Modorcea on April 18th, 2014 Our Rating: :: MINIMALISTIC IN A DIFFERENT WAYUniversal App - Designed for iPhone and iPad David is a minimalistic game wrapped inside of a soothing atmosphere in which the hero... | Read more »
Eyefi Unveils New Eyefi Cloud Service Th...
Eyefi Unveils New Eyefi Cloud Service That Allows Users to Share Media Across Personal Devices Posted by Tre Lawrence on April 18th, 2014 [ permalink ] | Read more »
Tales from the Dragon Mountain: The Lair...
Tales from the Dragon Mountain: The Lair Review By Jennifer Allen on April 18th, 2014 Our Rating: :: STEADY ADVENTURINGiPad Only App - Designed for the iPad Treading a safe path, Tales from the Dragon Mountain: The Lair is a... | Read more »
Yahoo Updates Flickr App with Advanced E...
Yahoo Updates Flickr App with Advanced Editing Features and More Posted by Tre Lawrence on April 18th, 2014 [ permalink ] | Read more »
My Incredible Body - A Kid's App to...
My Incredible Body - A Kid's App to Learn about the Human Body 1.1.00 Device: iOS Universal Category: Education Price: $2.99, Version: 1.1.00 (iTunes) Description: Wouldn’t it be cool to look inside yourself and see what was going on... | Read more »
Trials Frontier Review
Trials Frontier Review By Carter Dotson on April 18th, 2014 Our Rating: :: A ROUGH LANDINGUniversal App - Designed for iPhone and iPad Trials Frontier finally brings the famed stunt racing franchise to mobile, but how much does its... | Read more »
Evernote Business Notebook by Moleskin I...
Evernote Business Notebook by Moleskin Introduced – Support Available in Evernote for iOS Posted by Tre Lawrence on April 18th, 2014 [ permalink ] | Read more »

Price Scanner via MacPrices.net

Free HopTo 2.2 Helps Enhance Your Productivit...
The HopTo app helps you do more on your iPad by providing more and easier adaccess to files and documents. Version 2.2 adds Egnyte and HopTo’s Mac OSX File Connector. If you already have the hopTo... Read more
National Distracted Driving Awareness Month:...
As the country recognizes National Distracted Driving Awareness Month, Sprint is reminding wireless consumers to focus on driving while behind the wheel, to not text or email while driving, and to... Read more
13-inch 2.4GHz Retina MacBook Pro available f...
Abt has the 13″ 2.4GHz 128GB Retina MacBook Pro available for $1229 including free shipping. Their price is $70 off MSRP. Read more
iMacs on sale for up to $160 off MSRP this we...
Best Buy has iMacs on sale for up to $160 off MSRP for a limited time. Choose free home shipping or free instant local store pickup (if available). Prices are valid for online orders only, in-store... Read more
iPad Airs on sale this weekend for up to $100...
Best Buy has WiFi iPad Airs on sale for $50 off MSRP and WiFi + Cellular iPad Airs on sale for $100 off MSRP on their online store for a limited time, with prices now starting at $449. Choose free... Read more
Apple restocks refurbished Mac minis starting...
The Apple Store has restocked Apple Certified Refurbished Mac minis for up to $150 off the cost of new models. Apple’s one-year warranty is included with each mini, and shipping is free: - 2.5GHz Mac... Read more
Hyundai Brings Apple CarPlay To The 2015 Sona...
Hyundai Motor America has announced it will bring Apple CarPlay functionality to the 2015 Sonata. CarPlay is pitched as a smarter, safer and easier way to use iPhone in the car and gives iPhone users... Read more
Updated iPads Coming Sooner Than We Had Thoug...
MacRumors, cites KGI securities analyst Ming Chi Kuo, well-respected as an Apple product prognisticator, saying that Apple will introduce an upgraded iPad Air and iPad mini in 2014/Q3, meaning the... Read more
Toshiba Unveils New High And Low End Laptop M...
Toshiba has announced new laptop models covering both the high-end and low-end of the notebook computer spectrum. Toshiba 4K Ultra HD Laptop Toshiba’s new Satellite P55t features one of the world’s... Read more
Save up to $270 with Apple refurbished 13-inc...
The Apple Store has Apple Certified Refurbished October 2013 13″ Retina MacBook Pros available starting at $1099, with models up to $270 off MSRP. Apple’s one-year warranty is standard, and shipping... Read more

Jobs Board

*Apple* Automotive Parts Department position...
Apple Automotive is one of the fastest growing dealer…and it shows. Consider making the switch to the Apple Automotive Group today! At Apple Automotive, we Read more
*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
*Apple* Retail - Manager - Holyoke - Apple I...
Job Summary Keeping an Apple Store thriving requires a diverse set of leadership skills, and as a Manager, you’re a master of them all. In the store’s fast-paced, Read more
*Apple* Retail - Manager - Apple (United Sta...
Job SummaryKeeping an Apple Store thriving requires a diverse set of leadership skills, and as a Manager, you're a master of them all. In the store's fast-paced, dynamic Read more
*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.