TweetFollow Us on Twitter

VBL with Mach1
Volume Number:2
Issue Number:6
Column Tag:Threaded Code

Install a VBL Task with Mach1

By Jörg Langowski, EMBL, c/o I.L.L., Grenoble, Cedex, France, Editorial Board

Installing a Forth VBL Task - another CRT saver

Bob Denny's Article on vertical blanking tasks (MT V1#9) has been a constant challenge to me ever since it appeared. It seemed that there are certain things that one just could not do in Forth - the installation of an independently running task in the system heap being one of them. After all, where do you put the Forth runtime support when you leave Forth and want the task to run?

Another thing that would be difficult to do in Forth, for example, would be a desk accessory. In general, any tasks that will run independently and concurrently in the Mac operating system are almost impossible to handle with a language that needs a runtime interpreter to work.

After Mach1 came in, one could sort of see the light at the end of the tunnel. Here was a Forth that created real 68000 machine language output, and in principle its code could run anywhere without ever needing any runtime package. Maybe this makes some of the 'impossible' things that I mentioned less impossible.

Still, Mach1 does contain runtime support. Multitasking is the most important one, but by no means all, even the LOOP of a DO...LOOP structure is compiled as a JSR to a kernel routine.

The first rule for creating programs that are not only 'stand-alone applications', but self-contained code, is to avoid all references to kernel routines from within the program. This general statement will hold for any Forth system; given a Forth assembler, enough patience and a good set of macro definitions one will always be able to write code that is self-contained and won't need the runtime interpreter (e.g. using inline macros similar to the ones defined in MT V1#9, Forth column). Mach1 code doesn't contain too many references to its kernel anyway, so it should be much easier to accomplish what we try to do.

Our problem is to create a piece of code that does exactly what Bob Denny's CRT saver does: intercepts the GetNextEvent trap and updates a counter to keep track of when the last non-null event happened, and a VBL task that looks at that counter and blanks the screen whenever a certain time has elapsed after the last non-null event. Furthermore, the GetNextEvent intercept routine will repaint the screen after it has been blanked when a new non-null event occurs.

For the purpose of illustration, Listing 1 shows some Mach1 code that installs a very similar screen blanker as a background task under Mach1. This is the simple way to do it and will of course run only within the Mach1 system.

Short explanation of the program: the blankout routine opens a new GrafPort and paints its portRect (default size: whole screen) with the default pattern (black).

This routine is installed into one background task, CRTsaver, that checks continuously whether the time after the last 'relevant' event is larger than a preset value and blanks the screen if it is; thereafter, it unblanks the screen when a new event is received. The task's infinite loop contains a PAUSE to give control back to the scheduler.

The second background task, eventmonitor, checks for events by calling EventAvail. Whenever a 'relevant' event occurs, it is intercepted by this routine and the event tracking counter last.action updated.

Try and install these routines on your Mach1 system, and you'll have a fine CRT saver. Note that the multitasking system is not running while the screen is dark; I did this to keep it completely blank. You can insert a PAUSE in the event waiting loop of do.blank; in that case, all tasks will keep running, but you'll have a small white rectangle on the black screen (the cursor which is still active).

Installing the CRT saver as an independent VBL task

The example in Listing 1 contains many things that will just not work independently of the Mach1 runtime package:

- background tasks;

- variable definitions, which are kept separate from the main code block;

- JSR references to the kernel are not contained here, but could be easily in other tasks (as mentioned, a simple DO...LOOP);

- there are certain trap calls that are incompatible with the VBL task mechanism; as mentioned in IM, trap routines that move, purge or reallocate memory may not be called from a VBL task, the reason being that if the task happens to interrupt the memory manager and then calls the memory manager itself, very strange effects may result.

The list of 'forbidden' routines (IM, Addison-Wesley Vol. III in the appendix) is impressive, and EventAvail is one of them. The Quickdraw calls in blankout are also forbidden.

-The Mach1 data stack is maintained through the A6 register. In self-contained code, this register will have to be set up to point to a local stack area when the code is first entered. Also, for safety reasons the complete register file should be saved on entering and restored on exit.

An impressive list of restrictions; however, the example in Listing 2 shows that it is not that bad after all.

First, we may not use variables anymore. Any variable storage space should be defined within our piece of code. This can be done using create or header. References to variables thus defined must be through ['] (in colon definitions) or ' (in direct execution). If a create variable is referenced by name in a colon definition, a JSR to its code is compiled. create's own code again references the kernel and therefore cannot be used for self-contained programs.

If you use variables in this way, you can't call them directly by name after storing something there, because the create execution code will be overwritten. You'll always have to 'tick' their addresses on the stack.

Second, the screen blanker has to be rewritten; we store the black pattern into the screen area directly instead of calling Quickdraw routines, which may not be used. This is a little slower (Quickdraw really deserves its name), making the blanking less 'instantaneous'. Also, we may not use a DO...LOOP (reference to the kernel), so the blanking loop is implemented using BEGIN...UNTIL, a little more cumbersome, but still readable; and self-contained. See the definition of blankout in Listing 2. Note that HideCursor is not in the list of 'forbidden' traps.

Third, we cannot intercept events from within the VBL task using EventAvail. This is the reason why in Bob Denny's example from V1#9 a GetNextEvent filter procedure was used. We'll have to do the same thing.

The GNEFilter procedure

A short review of the method to install a GetNextEvent hook:

There is an (undocumented) system global at $29A which contains a location that GetNextEvent jumps to right after removing an Event from the queue. Through this hook, one can install a routine that will be called whenever GetNextEvent receives an event. A pointer to the event record is contained in A1. At the end of this routine, of course, one will have to jump to the location that was contained in $29A.

The GNE hook routine that we are going to install will, each time a non-null event is received, update the last.action counter with the current number of system ticks and repaint the screen if it was blank. In order to keep the definition short, we call traps directly instead of going through the Mach1 'glue' mechanism.

The GNEintfc routine saves most of the registers and restores them after exiting. A local stack (100 bytes) is set up for the Mach1 A6 stack pointer. Some inline assembly code is used to move arguments between the A7 and A6 stacks, and to setup a jump vector at the end of the routine.

The vertical blanking task

one.run is the heart of the vertical blanking task that will be the other part of the CRT saver. It checks whether one minute has passed since the last non-null event and blanks the screen in that case. Furthermore, it then sets a global flag, dark, to indicate to GNEintfc that the screen is dark. At the end of each run, screen blanked or not, the task reschedules itself by resetting the counter in its VBL queue element. Registers are saved and restored, and the routine also uses the local stack. (Note: writing this I realize that in the case that the GetNextEvent filter is interrupted by the vertical blanking and one.run is run during that same interrupt, it will use the same local stack. This might create a problem; so far the CRT saver has not crashed on me. You might think of duplicating the stack area so that the two routines use independent stacks.)

Installation of the CRT saver in the system heap

Of course, the code that we defined so far is local to the Mach1 system and will disappear as soon as Mach1 is exited. If we happened to install the CRT saver before, too bad! Most certainly the system won't survive this kind of abuse. Therefore it remains to copy the routines to a safe place in memory; we'll move them to the system heap before installing. The code that we have to copy is marked by the two headers START and END. The word install.blanker gets a pointer to a chunk of system heap (END - START) bytes long and copies the code to it. The offset is placed into the variable (yes, here we may use a good old variable) blockoffset. All references to the copied routines during installation (for initialization of flags and counters, and for the address passed to the VBL queue element) are made through the original addresses offset by this value.

After the installation (install.blanker and install.GNEfilter), you may leave Mach1, wait one minute and see your screen go dark. Any keypress or mouseclick will make reappear whatever was there.

Turnkeying the CRT saver installer

The word CRTsaver installs the tasks and quits Mach1. This word is used for turnkeying the program:

turnkey CRTsaver CRT

will create an application file CRT, 19K long (Mach1 runtime overhead of 16K) which installs the CRT saver.

Listing 1: CRT saver background task to run in the Mach1 system
( CRT saver task, © 1986 JL for MacTutor)
only forth definitions
also assembler also mac

hex
904 constant currentA5
9EE constant grayRgn
16A constant Ticks
 74 constant screenbits
 10 constant portrect

decimal

( first define port structure )
header screenport
     2 allot ( device )
    14 allot ( bitmap )
     8 allot ( portrect   )
    84 allot ( remaining bytes )


( *** now define background task that does the blanking *** )

variable last.action
variable max.ticks
3600 max.ticks !  ( 1 minute in ticks )

header myevents
    2 allot ( code )
    4 allot ( message )
    4 allot ( when )
    4 allot ( where )
    2 allot ( modifiers )

: relevant.action
    138 ( disk + key + mouse ) 
    ['] myevents call EventAvail
;

: redraw
    call drawmenubar
    call frontWindow
    grayRgn @ call paintBehind
    call showcursor
;

: blankout
    call hidecursor
    ['] screenport call openport
    ['] screenport portrect + call paintrect
    BEGIN relevant.action UNTIL
    ticks @ last.action !
    ['] screenport call setport
    redraw 
;

: monitor.events
    activate
    BEGIN
    PAUSE
    relevant.action 
        IF ticks @ last.action ! THEN
    AGAIN
;

: do.blank
    activate
    BEGIN
    PAUSE
    ticks @ last.action @ - max.ticks @ >
        IF blankout THEN
    AGAIN
;

400 1000 background CRTsaver
CRTsaver build
400 1000 background eventmonitor
eventmonitor build

: saver.start
    ticks @ last.action !
    eventmonitor monitor.events
    CRTsaver do.blank
;

Listing 2: CRT saver, written in Forth, for installation into system 
heap and Mach1 - independent execution

( CRT saver task for installation into VBLTask queue, © 1986 JL for MacTutor 
)
only forth definitions
also assembler also mac

hex
29A constant JGNEFilter
824 constant screenbase
904 constant currentA5
9EE constant grayRgn
16A constant Ticks
 74 constant screenbits
 10 constant portrect
FFFFFFFF constant minusone

.TRAP   _drawmenubar    $A937
.TRAP   _frontwindow    $A924
.TRAP   _paintbehind    $A90D
.TRAP   _newptr,sys     $A51E
.TRAP   _showcursor     $A853

CODE save.regs
    MOVE.W  SR,-(A7)
    MOVEM.L A1-A6/D0-D7,-(A7)
    RTS
END-CODE    MACH

CODE restore.regs
    MOVEM.L (A7)+,A1-A6/D0-D7
    MOVE.W  (A7)+,SR
    RTS
END-CODE    MACH

CODE getA1
    MOVE.L  A1,-(A6)
    RTS
END-CODE    MACH

decimal

header START

( *** we need a local stack after the relocation *** )    
 
header local.stack 100 allot

CODE setup.local.stack
    LEA -8(PC),A6 ( stack grows downward from here )
    RTS
END-CODE

( *** define port structure + some global variables *** )

header screenport
     2 allot ( device )
    14 allot ( bitmap )
     8 allot ( portrect   )
    84 allot ( remaining bytes )

header myevents
    2 allot ( code )
    4 allot ( message )
    4 allot ( when )
    4 allot ( where )
    2 allot ( modifiers )

( *** VBL queue element to be installed *** )

header VBLqelem
    4 allot ( qLink )
    2 allot ( qType )
    4 allot ( vblAddr )
    2 allot ( vblCount )
    2 allot ( vblPhase )

 1 constant vType
 4 constant qType
 6 constant vblAddr
10 constant vblCount
12 constant vblPhase
     
( *** GetNextEvent filter proc definitions *** )

header SavedJGNEFilter 4 allot
header dark  4 allot     
header last.action 4 allot
header max.ticks   4 allot
   3600 ' max.ticks !  ( 1 min in ticks )


: GNEIntfc
    save.regs
    setup.local.stack
    
    getA1 w@ ( event received? )
      IF ticks @ ['] last.action !
        ['] dark @
        IF 
            0 ['] dark !
            _drawmenubar
            CLR.L    -(A7)
            _frontwindow 
            grayrgn @
            MOVE.L   (A6)+,-(A7)
            _paintbehind
            _showcursor
        THEN
      THEN

    ['] SavedJGNEFilter @
    MOVE.L  (A6)+,A0
    restore.regs
    JMP     (A0)
;
    

( *** definitions for VBLtask that does the blanking *** )

: blankout 
    call hidecursor
    screenbase @ 21888 + 
    screenbase @
    BEGIN
        minusone over !
        4 + 2dup < 
    UNTIL 2drop 
    1 ['] dark !
;

: one.run
    save.regs
    setup.local.stack
    ticks @ ['] last.action @ - ['] max.ticks @ >
    ['] dark @ 0=
    AND
    IF  blankout  THEN
    60 ['] VBLqelem vblCount + w! ( reschedule )
    restore.regs
;

header END


( *** install CRT blanker task 'one.run' into VBL queue *** )

variable blockoffset

: get.sys.block  
    ['] end ['] start - 
    MOVE.L (A6)+,D0
    _newptr,sys ( get memory block in system heap )
    MOVE.L A0,-(A6)
;
    
: install.blanker   { | pointer offset -- }
    get.sys.block   -> pointer
    pointer IF
        0 ['] dark !
        ticks @ ['] last.action !
        pointer ['] start -  -> offset
        offset blockoffset !
        ['] start pointer ['] end ['] start - cmove
    ( now make all the moves on the relocated block )
        ['] VBLqelem offset +
        dup qtype + vtype swap w!
        dup vblAddr + ['] one.run offset + swap !
        dup vblCount + 60 swap w!
        dup vblPhase + 5 swap w!
        call Vinstall drop
    ELSE ." Not enough system heap for installation." cr
    THEN
;

: install.GNEfilter
    JGNEFilter @ ['] SavedJGNEFilter blockoffset @ + !
    ['] GNEIntfc blockoffset @ + JGNEFilter !
;

: remove.blanker
    ['] VBLqelem blockoffset @ + call Vremove drop
;

: remove.GNEfilter
    ['] SavedJGNEFilter blockoffset @ +  JGNEFilter ! 
;

: CRTsaver 
    install.blanker
    install.GNEfilter
    bye
;
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

LooperSonic (Music)
LooperSonic 1.0 Device: iOS Universal Category: Music Price: $4.99, Version: 1.0 (iTunes) Description: LooperSonic is a multi-track audio looper and recorder that will take your loops to the next level. Use it like a loop pedal to... | Read more »
Space Grunts guide - How to survive
Space Grunts is a fast-paced roguelike from popular iOS developer, Orange Pixel. While it taps into many of the typical roguelike sensibilities, you might still find yourself caught out by a few things. We delved further to find you some helpful... | Read more »
Dreii guide - How to play well with othe...
Dreii is a rather stylish and wonderful puzzle game that’s reminiscent of cooperative games like Journey. If that sounds immensely appealing, then you should immediately get cracking and give it a whirl. We can offer you some tips and tricks on... | Read more »
Kill the Plumber World guide - How to ou...
You already know how to hop around like Mario, but do you know how to defeat him? Those are your marching orders in Kill the Plumber, and it's not always as easy as it looks. Here are some tips to get you started. This is not a seasoned platform... | Read more »
Planar Conquest (Games)
Planar Conquest 1.0 Device: iOS Universal Category: Games Price: $12.99, Version: 1.0 (iTunes) Description: IMPORTANT: Planar Conquest is compatible only with iPad 3 & newer devices, iPhone 5 & newer. It’s NOT compatible with... | Read more »
We talk to Cheetah Mobile about its plan...
Piano Tiles 2 is a fast-paced rhythm action high score chaser out now on iOS and Android. You have to tap a series of black tiles that appear on the screen in time to the music, being careful not to accidentally hit anywhere else. Do that and it's... | Read more »
Ultimate Briefcase guide - How to dodge...
Ultimate Briefcase is a simple but tricky game that’s highly dependent on how fast you can react. We can still offer you a few tips and tricks on how to survive though. Guess what? That’s exactly what we’re going to do now. Take it easy [Read more... | Read more »
SoundPrism Link Edition (Music)
SoundPrism Link Edition 1.0 Device: iOS Universal Category: Music Price: $4.99, Version: 1.0 (iTunes) Description: ***Introductory price for a the first few days after launch - if you're reading this, get it while it's fresh out of... | Read more »
Pre-register now for hack and slasher An...
Fincon, which won Facebook's Studio to Watch award in 2015, has announced that pre-registration is now open for the massive 3.0 update for its award-winning hack and slasher Angel Stone. Angel Stone is a post-apocalyptic action RPG in which the... | Read more »
Google has named Piano Tiles 2 as its Be...
Google has named Piano Tiles 2, which launched back in August last year, as its Best Game of 2015. If you're yet to play it, now's a good time to do so. It's a sequel to the hugely successful viral hit Piano Tiles (Don't Tap the White Tile) but... | Read more »

Price Scanner via MacPrices.net

Apple refurbished 2014 13-inch Retina MacBook...
Apple has Certified Refurbished 2014 13″ Retina MacBook Pros available for up to $400 off original MSRP, starting at $979. An Apple one-year warranty is included with each model, and shipping is free... Read more
Macs available for up to $300 off MSRP, $20 o...
Purchase a new Mac or iPad using Apple’s Education Store and take up to $300 off MSRP. All teachers, students, and staff of any educational institution qualify for the discount. Shipping is free, and... Read more
Watch Super Bowl 50 Live On Your iPad For Fre...
Watch Super Bowl 50 LIVE on the CBS Sports app for iPad and Apple TV. Get the app and then tune in Sunday, February 7, 2016 at 6:30 PM ET to catch every moment of the big game. The CBS Sports app is... Read more
Two-thirds Of All Smart Watches Shipped In 20...
Apple dominated the smart watch market in 2015, accounting for over 12 million units and two-thirds of all shipments according to Canalys market research analysts’ estimates. Samsung returned to... Read more
12-inch 1.2GHz Retina MacBooks on sale for up...
B&H Photo has 12″ 1.2GHz Retina MacBooks on sale for $180 off MSRP. Shipping is free, and B&H charges NY tax only: - 12″ 1.2GHz Gray Retina MacBook: $1499 $100 off MSRP - 12″ 1.2GHz Silver... Read more
12-inch 1.1GHz Gray Retina MacBook on sale fo...
B&H Photo has the 12″ 1.1GHz Gray Retina MacBook on sale for $1199 including free shipping plus NY sales tax only. Their price is $100 off MSRP, and it’s the lowest price available for this model... Read more
Apple now offering full line of Certified Ref...
Apple now has a full line of Certified Refurbished 2015 21″ & 27″ iMacs available for up to $350 off MSRP. Apple’s one-year warranty is standard, and shipping is free. The following models are... Read more
Free GUI Speedometer – The Ultimate Digital D...
Miami, Florida based RMKapps has announced the official release of GUI Speedometer 1.0, their digital dashboard display developed for iOS devices. GUI Speedometer allows users to track their precise... Read more
FutureCalc: Ergonomic iOS Calculator App For...
London, United Kingdom based Independent software developer and entrepreneur, Hovik Melikyan has announced the release and immediate availability of FutureCalc 1.0, his new ergonomic calculator app... Read more
Save up to $600 with Apple refurbished Mac Pr...
Apple has Certified Refurbished Mac Pros available for up to $600 off the cost of new models. An Apple one-year warranty is included with each Mac Pro, and shipping is free. The following... Read more

Jobs Board

*Apple* Subject Matter Expert - Experis (Uni...
This position is for an Apple Subject Matter Expert to assist in developing the architecture, support and services for integration of Apple devices into the domain. Read more
*Apple* Macintosh OSX - Net2Source Inc. (Uni...
…: * Work Authorization : * Contact Number(Best time to reach you) : Skills : Apple Macintosh OSX Location : New York, New York. Duartion : 6+ Months The associate would Read more
Computer Operations Technician ll - *Apple*...
# Web Announcement** Apple Technical Liaison**The George Mason University, Information Technology Services (ITS), Technology Support Services, Desktop Support Read more
Restaurant Manager - Apple Gilroy Inc./Apple...
…in every aspect of daily operation. WHY YOU'LL LIKE IT: You'll be the Big Apple . You'll solve problems. You'll get to show your ability to handle the stress and Read more
Simply Mac *Apple* Specialist- Service Repa...
Simply Mac is the largest premier retailer of Apple products in the nation. In order to support our growing customer base, we are currently looking for a driven Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.