TweetFollow Us on Twitter

File Package
Volume Number:1
Issue Number:7
Column Tag:MacPascal

Standard File Package, unpack & copy the bits

By Alan Wootton

Here is a program to view MacPaint documents from MacPascal (like “showpage”). I use the File Manager, the Standard File Package, the toolbox procedure UnPackBits, and QuickDraw’s CopyBits to display the image loaded in memory.

In MacTutor #5, Gary Palmer asked about loading MacPaint files in MacPascal. Well, I remembered once running across a description of MacPaint docs by Bill Atkinson. After some digging, I found the description in part of a mailing from tech support to developers dated Dec. 1983.

Atkinson explains that the resource fork is not used and that a 512 byte header precedes the packed bitmap data. The header is an array of patterns and some empty space. To simply view the picture we can ignore the header. The MacPaint ‘page’ is 720 lines of 72 bytes each. This is almost 51K and since we wish to load this into memory, a FatMac will probably be required. Atkinson gives a short routine to decode the data into a page. He uses UnpackBits, which is on page 7 of ToolBox Utilities.

Reading the data was a problem. I tried to use the file I/O routines provided with MacPascal. One must either read data byte-at-a-time, which takes forever, or, if you read large blocks, you can never get the last partially filled block. At this point I decided that Real Programmers use the low level File Manager routines. In other words PBOpen, PBRead, and then PBClose.

Another MacPascal shortcoming is the GetOldFile function. Once again, Real Programmers go straight past the limitations of the language and consult the bible (Inside Mac). We shall use the Standard File Package.

The Standard File Package

MacPascal’s function GetOldName will only select files of type TEXT. To select MacPaint docs it will be necessary to call the Standard File Package directly (OldPaintName in following program). On page 30 of Packages in “Inside Macintosh”, the procedure SFGetFile is described. To call it, use trap $A9EA, which is Pack3, and be sure to push a 2, the ‘selector’, on the stack last. You must type in the SFReply record on page 25. [For a complete description of SFReply, see the Assembly Column in this issue.] Since our type list will just be one type (PNTG) it will not be necessary to declare an array. Pass nil for filefilter and dlghook. There is an argument to pass a prompt string that Inside Mac says is historical only. I find that it works fine.

Low Level File Manager

The filecall interface in the following program simulates the PB calls of the File Manager. This is an example of the OS call I presented in MacTutor #6. [Please refer to issue #6 for details on calling OS routines from Pascal.] Before you can use the the PB routines, you must type the lengthy Parameter Block declarations. There are four variant parts to this record. I have only used the ioParam part here because that is all that was needed in this example. You should type the whole thing and save it somewhere for later use. Note that 8 bit types do not come out right, so one must take care that the declaration has the correct length. The routine descriptions (starting on page 31 of the File Manager) give a nice list of those parameters that must be set before calling (assembly programmers note: in some places ioRefNum is listed as 22, but the correct number is 24). You should carefully check that each parameter is set correctly before calling. The exception is ioCompletion, which can be ignored since we will be making synchronous calls. If ioNamePtr is not nil then the File Manager assumes that its value is the address of a string. This could badly mess up memory. In MacPascal, declared variables are cleared to 0’s so you can get away with this, but later, when you compile, nasty bugs pop up (this actually happened to me).

UnPackBits

UnPackBits is actually very simple. I have complicated things by not reading all the data into memory at once. The scheme used is to read 1024 bytes into memory (skipping the header) and when the first 512 bytes are used I slide the upper 512 bytes down and add 512 bytes onto the end. The program unpacks 72 bytes at a time for 720 lines. For faster operation you can unpack 4 lines at a time. Change 720 to 180 and 72 to 288.

After the page array is filled, it would be nice to take a look at it. Copybits is used to move the image onto the drawing window. The nice thing about copybits is that it will scale the image to fit. Simply setup a Quickdraw Bitmap record for page, set destrect to the desired size, and call copybits as shown. If you change 144 to 576 and 180 to 720 you can see the painting full size.

To write a MacPaint document (not done in this program) it is necessary to know the format of the header. The header is a 4 byte version number (default = 2) and then 38*8 = 304 bytes of patterns and then 204 unused bytes for a total of 512. However, Atkinson’s example writes 512 zeros for a header so I guess that would work. To pack the data you use the reverse of the unpack procedure. Things can be made simpler though because you can use one destination buffer and then write it out after every PackBits.

It is my contention that everything in Inside Mac can be demonstrated and used from MacPascal (except things like Vertical Retrace routines). If there is anything that you have trouble with and would like to see in MacTutor, write a letter to MacTutor and I will see if there isn’t a way to do it.


program Read_MacPaint_doc;{by Alan Wootton 4/85}
           { This program reads a MacPaint file and shows            
        the picture 1/4 size in Drawing }
 uses
  Quickdraw2;
 type
  ptr = ^integer;
  OStype = longint;

  SFReply = record { this is used by the standard file               
                           package, see Packages }
    good : integer;
    ftype : OSType;
    vrefNum : integer;
    version : integer;
    fname : string[63];
   end;

{ Parameter Block information contained in File Manager 
chapter of Inside Macintosh.  Note that MacPascal won’t do 8 bit fields 
right }

  ParamBlkPtr = ^ParamBlockRec;
  ParamBlockRec = record
{ data structure of File Manager }
    qLink : Ptr;
    qType : integer;
    ioTrap : integer;
    ioCmdAddr : ptr;
    ioCompletion : ptr;
    ioResult : integer;
    ioNamePtr : ^str255;
    ioVrefNum : integer;
{  case ParamBlkType of  ...  ioParam:  }
    ioRefNum : integer;
{       ioVersNum : byte;  }
    ioPermssn : integer;{ byte }
    ioMisc : ptr;
    ioBuffer : ptr;
    ioReqCount : longint;
    ioActCount : longint;
    ioPosMode : integer;
    ioPosOffset : longint;
   end;

  diskBlock = packed array[0..511] of char;

  paintPage = array[0..35, 0..719] of integer;
{  576*720 bitmap  = 72 bytes * 720 lines =  51,840           bytes }




 var
  reply : SFReply;{ used by OldPaintName, declared here              
                   to access vRefNum }
  filename : str255;
  fileblock : ParamBlockRec;
  buff : array[0..1] of diskblock;{ 1K }

  Page : paintPage;{ Huge variable, almost 52K  }

  srcPnt : ^diskBlock;
  destPnt : ^paintPage;

  lines, err : integer;

  curport : Grafptr;
  pageBits : bitmap;
  destRect : Rect;


{ common OS trap code, could be done with ‘Generic’ call}
{see MacTutor Vol. 1 No. 6 for assembly source code}
 function filecall (Pb : ParamBlkPtr;
         trap : integer) : integer;
  var
   access : array[0..12] of integer;
   d0, a0 : longint;
 begin
  stuffHex(@access, ‘2848548C41FA000C309F245F265F20522013FFFF224826804ED4’);
  a0 := ord(pb);
  inlineP($4E75, @d0, @a0, trap, @access);
  filecall := loword(d0);
 end;

{ The following File Manager calls work just like   }
{ those described in Inside Macintosh for the Lisa Pascal Workshop.  
}
{ Except that the async parameter is a dummy; all calls are sync }

 function PBOpen (Pb : ParamBlkPtr;
         async : boolean) : integer;
 begin
  PBOpen := filecall(pb, $A000);
 end;

 function PBClose (Pb : ParamBlkPtr;
         async : boolean) : integer;
 begin
  PBClose := filecall(pb, $A001);
 end;

 function PBRead (Pb : ParamBlkPtr;
         async : boolean) : integer;
 begin
  PBRead := filecall(pb, $A002);
 end;


{  same as OldFileName, only for MacPaint docs }
 function OldPaintName (prompt : str255) : str255;
  var
   where : point;
   typelist : longint;
 begin
  reply.good := 0;
  typelist := $504E5447;{ ‘PNTG’ }
  setPT(where, 100, 100);
  inlineP($A9EA, where, @prompt, nil, 1, @typelist, nil, @reply, 2);
{ $A9EA is pack3 ,  2 is SFGetFile, see Packages  }
  if reply.good <> 0 then
   OldPaintName := reply.Fname
  else
   OldPaintName := ‘’;
 end;


{  This procedure moves buff[1] down onto buff[0], adjusts srcPnt to 
point at it’s same data and tacks more data on end in buff[1].     }
 procedure Refill_Buffer;
 begin
  blockmove(@buff[1], @buff[0], 512);
  srcPnt := pointer(ord(srcPnt) - 512);
  fileBlock.ioBuffer := @buff[1];
  fileBlock.ioReqCount := 512;
  fileBlock.ioPosMode := 0;
  err := PBRead(@fileBlock, false);{ fill buff[1] }
 end;


begin { main }
 ShowDrawing;
 fileName := OldPaintName(‘ Select Painting to examine’);
 while filename <> ‘’ do
  begin
   fileBlock.ioVrefNum := reply.vrefnum;
   fileBlock.ioNamePtr := @fileName;
   fileBlock.ioPermssn := 1;{ read only, version number              
                                   is in upper byte and is 0 }
   fileBlock.ioMisc := nil;
   if PBOpen(@fileBlock, false) = 0 then
    begin
     refill_buffer;{  first block is skipped }
     refill_buffer;{   fill 1 }
     refill_buffer;{ 1 onto 0, refill 1 }

     srcPnt := @buff[0];{ <-- pointer to start of data }
     destPnt := @Page;{ <----  pointer to Page bitmap }

{------> This is the part that actually decodes the packed MacPaint data 
<------}
{ $A8D0 is UnPackBits, see page 7 in Toolbox Utilities   }
{ srcPnt and destPnt are updated by UnPackBits so use @}
     for lines := 1 to 720 do{ 720 lines in paint doc }
      begin
       inlineP($A8D0, @srcPnt, @destPnt, 72);
                                     { UnPackBits for 72 bytes }
       if ord(srcpnt) >= ord(@buff[1]) then
        Refill_Buffer; { if src no longer in buff[0] }
      end;{ of 720 lines }

     if PBClose(@fileBlock, false) <> 0 then
      writeln(‘close error’);

{  now show drawing  in current port  (drawing window) }
     GetPort(curPort);

 
{  set up bitmap record }
    pagebits.baseaddr := pointer(ord(@page));
    pagebits.rowbytes := 72;
    setRect(pagebits.bounds, 0, 0, 576, 720);

     setRect(destRect, 0, 0, 144, 180);
{ 144,180 =1/4 normal, image will be squashed to fit }

     copyBits(pagebits, curport^.portbits, pagebits.bounds,          
           destRect, srcCopy, nil);
     moveto(4, 190);
     drawstring(‘Click to open another MacPainting’);
     repeat
     until button;

    end;{ if no Open error }
   fileName := OldPaintName(‘ Select another Painting ?’);
  end;{ if name<>’’ loop }
end.
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Arq 5.8.5 - Online backup to Google Driv...
Arq is super-easy online backup for Mac and Windows computers. Back up to your own cloud account (Amazon Cloud Drive, Google Drive, Dropbox, OneDrive, Google Cloud Storage, any S3-compatible server... Read more
Backblaze 4.3.0.44 - Online backup servi...
Backblaze is an online backup service designed from the ground-up for the Mac. With unlimited storage available for $5 per month, as well as a free 15-day trial, peace of mind is within reach with... Read more
Instaradio 7.1 - Listen to your favorite...
Instaradio is fast, and it could be the radio player you have been waiting for. Try the app thousands of people rely on for listening to radio. Features Listen to radio from all around the world... Read more
EtreCheck 3.3.3 - For troubleshooting yo...
EtreCheck is an app that displays the important details of your system configuration and allow you to copy that information to the Clipboard. It is meant to be used with Apple Support Communities to... Read more
Hopper Disassembler 4.2.1- - Binary disa...
Hopper Disassembler is a binary disassembler, decompiler, and debugger for 32-bit and 64-bit executables. It will let you disassemble any binary you want, and provide you all the information about... Read more
Slack 2.6.2 - Collaborative communicatio...
Slack is a collaborative communication app that simplifies real-time messaging, archiving, and search for modern working teams. Version 2.6.2: Fixed Inexplicably, context menus and spell-check... Read more
Apple Final Cut Pro X 10.3.4 - Professio...
Apple Final Cut Pro X is a professional video editing solution.Completely redesigned from the ground up, Final Cut Pro adds extraordinary speed, quality, and flexibility to every part of the post-... Read more
Numi 3.15 - Menu-bar calculator supports...
Numi is a calculator that magically combines calculations with text, and allows you to freely share your computations. Numi combines text editor and calculator Support plain English. For example, '5... Read more
TunnelBear 3.0.14 - Subscription-based p...
TunnelBear is a subscription-based virtual private network (VPN) service and companion app, enabling you to browse the internet privately and securely. Features Browse privately - Secure your data... Read more
Apple iMovie 10.1.6 - Edit personal vide...
With an all-new design, Apple iMovie lets you enjoy your videos like never before. Browse your clips more easily, instantly share your favorite moments, and create beautiful HD movies and Hollywood-... Read more

Latest Forum Discussions

See All

Goat Simulator PAYDAY (Games)
Goat Simulator PAYDAY 1.0 Device: iOS Universal Category: Games Price: $4.99, Version: 1.0 (iTunes) Description: ** IMPORTANT - SUPPORTED DEVICES **iPhone 4S, iPad 2, iPod Touch 5 or better Goat Simulator: Payday is the most... | Read more »
Zombie Gunship Survival Beginner's...
The much anticipated Zombie Gunship Survival is here. In this latest entry in the Zombie Gunship franchise, you're tasked with supporting ground troops and protecting your base from the zombie horde. There's a lot of rich base building fun, and... | Read more »
Mordheim: Warband Skirmish (Games)
Mordheim: Warband Skirmish 1.2.2 Device: iOS Universal Category: Games Price: $3.99, Version: 1.2.2 (iTunes) Description: Explore the ruins of the City of Mordheim, clash with other scavenging warbands and collect Wyrdstone -... | Read more »
Mordheim: Warband Skirmish brings tablet...
Legendary Games has just launched Mordheim: Warband Skirmish, a new turn-based action game for iOS and Android. | Read more »
Magikarp Jump splashes onto Android worl...
If you're tired ofPokémon GObut still want something to satisfy your mobilePokémon fix,Magikarp Jumpmay just do the trick. It's out now on Android devices the world over. While it looks like a simple arcade jumper, there's quite a bit more to it... | Read more »
Purrfectly charming open-world RPG Cat Q...
Cat Quest, an expansive open-world RPG from former Koei-Tecmo developers, got a new gameplay trailer today. The video showcases the combat and exploration features of this feline-themed RPG. Cat puns abound as you travel across a large map in a... | Read more »
Jaipur: A Card Game of Duels (Games)
Jaipur: A Card Game of Duels 1.0 Device: iOS Universal Category: Games Price: $1.99, Version: 1.0 (iTunes) Description: ** WARNING: iPad 2, iPad Mini 1 & iPhone 4S are NOT compatible. ** *** Special Launch Price for a limited... | Read more »
Subdivision Infinity (Games)
Subdivision Infinity 1.03 Device: iOS Universal Category: Games Price: $2.99, Version: 1.03 (iTunes) Description: Launch sale! 40% Off! Subdivision Infinity is an immersive and pulse pounding sci-fi 3D space shooter. https://www.... | Read more »
Clash of Clans' gets a huge new upd...
Clash of Clans just got a massive new update, and that's not hyperbole. The update easily tacks on a whole new game's worth of content to the hit base building game. In the update, that mysterious boat on the edge of the map has been repaired and... | Read more »
Thimbleweed Park officially headed to iO...
Welp, it's official. Thimbleweed Park will be getting a mobile version. After lots of wondering and speculation, the developers confirmed it today. Thimbleweed Park will be available on both iOS and Android sometime in the near future. There's no... | Read more »

Price Scanner via MacPrices.net

Free Tread Wisely Mobile App Endorsed By Fath...
Just in time for the summer driving season, Cooper Tire & Rubber Company has announced the launch of a new Tread Wisely mobile app. Designed to promote tire and vehicle safety among teens and... Read more
Commercial Notebooks And Detachable Tablets W...
Worldwide shipments of personal computing devices (PCDs), comprised of traditional PCs (a combination of desktop, notebook, and workstations) and tablets (slates and detachables), are forecast to... Read more
Best value this Memorial Day weekend: Touch B...
Apple has Certified Refurbished 2016 15″ and 13″ MacBook Pros available for $230 to $420 off original MSRP. An Apple one-year warranty is included with each model, and shipping is free: - 15″ 2.6GHz... Read more
13-inch MacBook Airs on sale for up to $130 o...
Overstock.com has 13″ MacBook Airs on sale for up to $130 off MSRP including free shipping: - 13″ 1.6GHz/128GB MacBook Air (sku MMGF2LL/A): $869.99 $130 off MSRP - 13″ 1.6GHz/256GB MacBook Air (sku... Read more
2.8GHz Mac mini available for $973 with free...
Adorama has the 2.8GHz Mac mini available for $973, $16 off MSRP, including a free copy of Apple’s 3-Year AppleCare Protection Plan. Shipping is free, and Adorama charges sales tax in NY & NJ... Read more
15-inch 2.2GHz Retina MacBook Pro on sale for...
Amazon has 15″ 2.2GHz Retina MacBook Pros (MJLQ2LL/A) available for $1749.99 including free shipping. Apple charges $1999 for this model, so Amazon’s price is represents a $250 savings. Note that... Read more
Huawei Unveils New ‘Business-Styled’ MateBook...
Huawei has introduced a trio of new MateBook laptops, expanding its mobile portfolio and building on its success in delivering attractive and powerful high-end devices. The company claims the HUAWEI... Read more
Deal! Gold 12-inch 1.2GHz Retina MacBook for...
Amazon has the 2016 Gold 12″ 1.2GHz Retina MacBook (MLHF2LL/A) on sale for $350 off MSRP for a limited time. Shipping is free: - 12″ 1.2GHz Gold Retina MacBook: $1249.99 $350 off MSRP We expect this... Read more
13-inch 2.0GHz MacBook Pros on sale for $100...
B&H has the non-Touch Bar 13″ 2.0GHz MacBook Pros in stock today and on sale for $100 off MSRP. Shipping is free, and B&H charges NY & NJ sales tax only: - 13″ 2.0GHz MacBook Pro Space... Read more
15-inch 2.2GHz Retina MacBook Pro, Apple refu...
Apple has Certified Refurbished 2015 15″ 2.2GHz Retina MacBook Pros available for $1699. That’s $300 off MSRP, and it’s the lowest price available for a 15″ MacBook Pro. An Apple one-year warranty is... Read more

Jobs Board

*Apple* Retail - Multiple Positions, White P...
Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, you're also the Read more
Best Buy *Apple* Computing Master - Best Bu...
**509110BR** **Job Title:** Best Buy Apple Computing Master **Location Number:** 000048-Topeka-Store **Job Description:** **What does a Best Buy Apple Computing Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description:SalesSpecialist - Retail Customer Service and SalesTransform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Systems Engineer - California Polyte...
Cal Poly, San Luis Obispo Apple Systems Engineer Department: ITS - Customer & Tech Support (134900) College/Division: Academic Affairs Salary Range: Position Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.