TweetFollow Us on Twitter

Introduction to Scripting QuarkXPress

Volume Number: 22 (2006)
Issue Number: 10
Column Tag: AppleScript Essentials

Introduction to Scripting QuarkXPress

by Benjamin S. Waldie

My last two columns have focused on using AppleScript to automate graphic processing with Photoshop and GraphicConverter. This month, we are going to switch gears from graphic processing to discuss another commonly automated creative process - desktop publishing. Specifically, we will explore some initial steps necessary for automating a desktop publishing workflow using QuarkXPress, a popular page layout application.

History

QuarkXPress was one of the first applications to support AppleScript, with version 3.2. In fact, it is believed by some that QuarkXPress is actually partially responsible for AppleScript being around today. Rumor has it that, at one time, Apple had planned to do away with AppleScript, but received such a backlash from the publishing community, who threatened to move to PCs if their scripted workflows were taken away, that it was decided to keep AppleScript around.



Figure 1. QuarkXPress 7's New Icon

One great aspect of Quark's AppleScript support is its commitment to backward-compatibility. From the early days to today with version 7, see figure 1, Quark's AppleScript support has not changed all that much. New terminology has been added for new application features. However, existing terminology has stayed relatively the same, with only minor modifications along the way. This has allowed many users to upgrade their scripts for new versions of Quark without the hassle of making a large number of adjustments. In fact, the recent jump from Quark 6 - 7 introduced only a handful of changes to existing AppleScript terminology, allowing many Quark 6 scripts to function in Quark 7 without any changes whatsoever.

Getting Started

As you begin scripting Quark, be sure to refer to Quark's AppleScript dictionary regularly to determine the proper terminology to use. (See figure 2.) You will find that Quark's dictionary is broken into a number of logical suites of classes and commands, and that Quark's containment hierarchy is fairly straightforward.



Figure 2. QuarkXPress' AppleScript Dictionary

For Quark 6.x users, I highly recommend downloading and installing an updated copy of the Script.xnt XTension. This updated XTension will fix problems that may occur when printing Quark documents to PostScript format in Mac OS X 10.4 and higher. This XTension is part of a package named Output Enhancements XTensions software (user mode) for QuarkXPress and QuarkXPress Passport 6.5. This package is available for download from the Support > Desktop Downloads section of Quark's website at <http://www.quark.com/service/desktop/downloads/details.jsp?idx=601>.

Getting to Know Quark Projects

In QuarkXPress, the document in which you will work is known as a project, and a project contains one or more layout spaces. For example, a project could contain a print layout, a web layout, and more. Prior to Quark 6, layout spaces did not exist, nor did projects. At that time, a document was simply called a document.

As far as AppleScript is concerned, Quark's AppleScript terminology contains project, layout space, and document classes. The document class exists to allow for compatibility with scripts written for older versions of Quark.

When referring to a project in Quark, you do so as follows:

tell application "QuarkXPress"
   tell project 1
      -- Do something
   end tell
end tell

The code above would refer to the frontmost project. The following code demonstrates how you would address a layout space within that project. In this case, the first layout space is being addressed. Even if the project only has one layout space, you must still address the layout.

tell application "QuarkXPress"
   tell layout space 1 of project 1
      -- Do something
   end tell
end tell

As mentioned before, Quark also supports a class of document, which you may use if you choose to. For example:

tell application "QuarkXPress"
   tell document 1
      -- Do something
   end tell
end tell

Referring to a document in this manner is essentially the same as referring to the current layout space of a project. In this example, document 1 refers to the frontmost project document.

In the examples above, I referred to projects, layout spaces, and documents by their index, or front to back ordering. Of course, you may also refer to projects, layout spaces, and documents by their names, if desired. For example:

tell application "QuarkXPress"
   tell layout space "Layout 1" of project "Project1"
      -- Do something
   end tell
end tell

Creating a Project

To create a new project with a single layout space in QuarkXPress, use the make command, the result of which will be a reference to the newly created project. For example:

tell application "QuarkXPress"
   make new project at beginning
end tell
--> project "Project1" of application "QuarkXPress"

In Quark, layout spaces within the same project can be different sizes. In the code above, we did not specify a height and width for the layout space in the newly created project. Because of this, Quark's current default size settings will be used to create the project. However, these can be adjusted by modifying the page height and page width properties of the default document class, prior to creating the project. For example, the following code would create a project containing a layout space that is 6 inches high and 8 inches wide.

tell application "QuarkXPress"
   tell default document 1
      set page height to "6 in"
      set page width to "8 in"
   end tell
   make new project at beginning
end tell
--> project "Project1" of application "QuarkXPress"

The layout space class itself also has page height and page width properties, which can be modified after the project is created, if desired. For example, the following code would create a new project with a single layout space that is 4 inches high by 4 inches wide.

tell application "QuarkXPress"
   set theProject to make new project at beginning
   tell layout space 1 of theProject
      set page height to "4 in"
      set page width to "4 in"
   end tell
end tell

Creating a New Layout Space

The make command may also be used to create a new layout space within an existing project. In doing so, you may choose to specify properties of the layout space, such as page height and page width. For example:

tell application "QuarkXPress"
   tell project 1
      make new layout space at end with properties {page height:"11 in", page width:"8.5 in"}
   end tell
end tell

Working with Text

Creating a Text Box

A key aspect of scripting Quark involves working with text. In Quark, text is placed into text boxes on pages within layout spaces. To create a text box via AppleScript, you will need to determine where you would like the text box to be created, and how large you would like it to be.

First, determine the page on which the text box should be created. Next, determine where you would like the box to be positioned on that page, and how large it should be. This information will be communicated to Quark using a list of bounds. This list will be formatted as follows:

   {top position, left position, bottom position, right position}

Now, to create the text box, use the make command, and specify the bounds for the box as follows:

tell application "QuarkXPress"
   tell page 1 of layout space 1 of project 1
      make new text box at beginning with properties {bounds:{"1 in", "1 in", "3 in", "6 in"}}
   end tell
end tell
--> text box 1 of page 1 of layout space "Layout 1" of project "Project1" of application 
   "QuarkXPress"

Using the code above, a text box would be created on page 1 of the layout space. The top left corner of the box would be one inch down, and one inch from the left side of the page. The bottom right corner of the box would be 3 inches down, and 6 inches from the left side of the page. Therefore, this text box would be 2 inches high and 5 inches across.

Placing Text

In Quark, a story represents all of the text within a text box. Once a text box exists, you may set its text to a specified string by setting the value of its story element. For example:

tell application "QuarkXPress"
   tell page 1 of layout space 1 of project 1
      set story 1 of text box 1 to "My Project Text"
   end tell
end tell

Please note that the code above would replace existing text in the box, if present.

Styling Text

Stories possess numerous text properties, which are modifiable via AppleScript. I will cover only a few of these in this column. I encourage you to explore Quark's AppleScript dictionary for a complete list of these properties. Please note that many of these are found under the text properties and character properties classes, which are inherited by the story class.

The following example code demonstrates the modification of a number of different character properties within a story, including font, size, and color. As you can see, values for these properties may be applied to the story itself, such as in the case of the font property below. Or, values may be applied to elements of the story, such as specific paragraphs, words, or characters.

tell application "QuarkXPress"
   tell page 1 of layout space 1 of project 1
      tell story 1 of text box 1
         set font to "Arial"
         set size of word 2 to 24
         set color of word 1 to "Yellow"
         set color of word 2 to "Cyan"
         set color of word 3 to "Magenta"
      end tell
   end tell
end tell

Figure 3 shows an example of a text box containing text that was styled using the example code above.



Figure 3. Styled Text in QuarkXPress

Working with Pictures

Creating a Picture Box

As you will find, working with picture boxes in Quark is very similar to working with text boxes. To create a picture box, use the make command, and specify a value for the box's bounds property. Again, the bounds of the box will indicate its size and positioning on the specified page. The following example code will create a 3 inch high by 5 inch wide picture box.

tell application "QuarkXPress"
   tell page 1 of layout space 1 of project 1
      make new picture box at beginning with properties {bounds:{"3 in", "1 in", "6 in", "6 in"}}
   end tell
end tell
--> picture box 1 of page 1 of layout space "Layout 1" of project "Project1" of application 
   "QuarkXPress"

Placing a Picture

Once you have created a picture box, you will probably want to place a picture within it. To do this, set its image to a specified file path. For example:

set theImage to choose file with prompt "Please select an image to place:" without 
   invisibles
tell application "QuarkXPress"
   tell page 1 of layout space 1 of project 1
      tell picture box 1
         set image 1 to theImage
      end tell
   end tell
end tell

Figure 4 demonstrates a picture box in Quark that has been populated with an image file using the example code above.



Figure 4. A Placed Picture

Naming Boxes

In most of the examples so far, we have referred to text and picture boxes by their index, i.e. front to back ordering on the page. The problem with writing a script in this manner is that the ordering of the boxes on a page may change if boxes are added, grouped, or deleted.

To get around this limitation, and ensure that your script is always interacting with the correct boxes, it is good practice to assign names to boxes in your Quark documents. Just as projects, layout spaces, and documents can be referred to by name, text and picture boxes can also be referred to by name. The problem, however, is that Quark does not provide an interface for naming text and picture boxes. Therefore, this must by done using AppleScript, by modifying the name property of the desired box. For example:

tell application "QuarkXPress"
   tell page 1 of layout space 1 of project 1
      tell text box 1
         set name to "Photo Description"
      end tell
   end tell
end tell

Once a name has been assigned to a box, you can use its name, rather than its index, to refer to the box. For example:

tell application "QuarkXPress"
   tell page 1 of layout space 1 of project 1
      set text of text box "Photo Description" to "Photo Description"
   end tell
end tell

Next Steps and Resources

Documentation and Examples

If you are a serious QuarkXPress user, and you are planning to make yourself more efficient by introducing AppleScript automation into your workflow, there are several ways to get started. First, be sure to view Quark's Guide to Apple Events Scripting documentation. This is installed along with QuarkXPress, and can be found in the Documents > Apple Events Scripting folder in the main QuarkXPress folder.

Also, in the Apple Events Scripting folder, you will find a sample Layout Construction AppleScript file, which contains some example code to get you started. This script is unlocked and editable for you to modify, or to borrow code for insertion into your own scripts.

If you're interested in finding even more documentation on scripting QuarkXPress, you may want to check out X-Ray Magazine at <http://www.xraymag.com/>. X-Ray is geared entirely for Quark users, and (excuse the shameless plug), in addition to writing for MacTech, I also write a regular AppleScript column for X-Ray on... you guessed it, AppleScripting QuarkXPress.

If the above resources still can't contain your quest for more QuarkXPress AppleScript knowledge, then you should check out AppleScripting QuarkXPress, by Shirley Hopkins, which is available (although in short supply) from Amazon.com at <http://www.amazon.com/gp/product/0970726503/>.

Expanding QuarkXPress' AppleScript Support

Inevitably, you may encounter things that you wish were scriptable in Quark, but unfortunately, simply are not. Well, before you get too upset, you may want to check around to see if there is a third-party XTension that will add the functionality that you need. Quark's XTension architecture allows developers to create their XTensions that actually add new AppleScript terminology to Quark's dictionary. One such developer is Em Software (http://www.emsoftware.com), whose Xcatalog and Xdata XTensions are scriptable, and can allow users to automate quite complex document construction workflows. Gluon (http://www.gluon.com) is another developer that offers a number of scriptable XTensions for QuarkXPress.

Recording AppleScript Code in QuarkXPress

The dream of anyone getting started on scripting QuarkXPress, is to be able to record tasks they perform manually using the Script Editor's record functionality. Unfortunately, QuarkXPress (like most applications) does not support AppleScript recordability. To get around this limitation, however, be sure to check out ScriptMasterXT, a commercial XTension for QuarkXPress, available from Jintek, LLC (http://www.jintek.com/). ScriptMasterXT adds AppleScript recordability, as well as numerous useful AppleScript commands, to QuarkXPress. A limited demonstration version of ScriptMasterXT is available for download from the Jintek website.

In Closing

We have really only scratched the surface of scripting QuarkXPress. There are many, many more tasks that can be automated in Quark using AppleScript, and I would encourage you to continue exploring them on your own. With a little work, it's easily possible to automate even the most complex Quark-based workflows using AppleScript.

Until next time, keep scripting!


Ben Waldie is the author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from <http://www.spiderworks.com>, as well as an AppleScript Training CD, available from <http://www.vtc.com>. Ben is also president of Automated Workflows, LLC, a company specializing in AppleScript and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit <http://www.automatedworkflows.com>, or email Ben at <ben@automatedworkflows.com>.

 
AAPL
$112.01
Apple Inc.
-0.53
MSFT
$48.14
Microsoft Corpora
-0.31
GOOG
$528.77
Google Inc.
-1.82

MacTech Search:
Community Search:

Software Updates via MacUpdate

MegaSeg 5.9.4 - Professional MP3 DJ appl...
MegaSeg is a complete solution for pro audio/video DJ mixing, radio automation, and music scheduling with rock-solid performance and an easy-to-use design. Mix with visual waveforms and Magic... Read more
Parallels Desktop 10.1.2 - Run Windows a...
Parallels Desktop is simply the world's bestselling, top-rated, and most trusted solution for running Windows applications on your Mac. With Parallels Desktop for Mac, you can seamlessly run both... Read more
GarageSale 6.9.1 - Create outstanding eB...
GarageSale is a slick, full-featured client application for the eBay online auction system. Create and manage your auctions with ease. With GarageSale, you can create, edit, track, and manage... Read more
Quicksilver 1.2.2 - Application launcher...
Quicksilver is a light, fast and free Mac application that gives you the power to control your Mac with keystrokes alone. Quicksilver allows you to find what you need quickly and easily, then act... Read more
Mac DVDRipper Pro 5.0.1 - Copy, backup,...
Mac DVDRipper Pro is the DVD backup solution that lets you protect your DVDs from scratches, save your batteries by reading your movies from your hard disk, manage your collection with just a few... Read more
ClamXav 2.7 - Free virus checker, based...
ClamXav is a free virus checker for OS X. It uses the tried, tested, and very popular ClamAV open source antivirus engine as a back end. I hope you like and use ClamXav a lot and that it helps keep... Read more
FoldersSynchronizer 4.2 - Synchronize or...
FoldersSynchronizer is a popular and useful utility that synchronizes and backs-up files, folders, disks and boot disks. On each session you can apply special options like Timers, Multiple Folders,... Read more
Waltr 1.0.6 - Drag-and-drop any media fi...
WALTR is designed to make it easy to upload and convert any music or video file to an iPad or iPhone format for native playback. It supports a huge variety of media file types, including MP3, MP4,... Read more
Tonality Pro 1.1.3 - Professional-grade...
Tonality Pro gives you the power to create stunning and dramatic black & white images. This is a complete monochrome image editor with more than 150 one-click style presets, totally unique... Read more
OS X NTP Security Update 1.0 - Addresses...
The OS X NTP Security Update addresses a critical security issue with the software that provides the Network Time Protocol service on OS X, and is recommended for all users. Version 1.0: Initial... Read more

Latest Forum Discussions

See All

Forget the Gloves – It’s a Cage Match in...
Forget the Gloves – It’s a Cage Match in Real Boxing’s Underground Update Posted by Jessica Fisher on December 23rd, 2014 [ permalink ] | Read more »
Who Wore it Best? Best of 2014
It’s the end of the year, so it’s time for some arbitrary internet awards! In this wrap-up episode of Who Wore it Best? we present our winners for the best, worst, and flat-out weirdest cloned games that graced the App Store in 2014. [ Who... | Read more »
Now You Can Explore Mayan Temples in Ass...
Now You Can Explore Mayan Temples in Assassin’s Creed Pirates’ Newest Update Posted by Jessica Fisher on December 23rd, 2014 [ permalink ] | Read more »
Soft Design aims to do free-to-play righ...
They say a team is only as big as its fans and that’s also certainly the case with video games, judging from the sales certain AAA ‘heavyweights’ get year-after-year. Soft Design took that principle as a core design philosophy and worked closely... | Read more »
Bogga Christmas Tree
Bogga Christmas Tree By Amy Solomon on December 23rd, 2014 Our Rating: Universal App - Designed for iPhone and iPad Bogga Christmas Tree allows young children to trim a tree, any time or place.   | Read more »
Opera Coast 4.0 Launches on iOS with 4 N...
Opera Coast 4.0 Launches on iOS with 4 New Features Posted by Jessica Fisher on December 23rd, 2014 [ permalink ] Universal App - Designed for iPhone and iPad | Read more »
Cricket Kids: Christmas Presents
Cricket Kids: Christmas Presents By Amy Solomon on December 23rd, 2014 Our Rating: Universal App - Designed for iPhone and iPad Cricket Kids: Christmas Presents allows children to play with digital toys opened for the Christmas... | Read more »
Lara Croft & Tomb Raider Mobile Bund...
Lara Croft & Tomb Raider Mobile Bundle – Only $4.99 Posted by Jessica Fisher on December 23rd, 2014 [ permalink ] Lara Croft is coming to you in | Read more »
SimCity BuildIt Review
SimCity BuildIt Review By Nadia Oxford on December 23rd, 2014 Our Rating: :: BUILDING AN OK TOMORROWUniversal App - Designed for iPhone and iPad SimCity BuildIt is a competent city-building game, but its free-to-play trappings are... | Read more »
SimCity Buildit – Tips, Tricks, and Stra...
Hello, Budding Mayors Want to know what we made of all this upgrading and inevitable waiting? Check out our SimCity BuildIt review! SimCity BuildIt is a city-building game from EA. Your job as mayor is to build houses for people to live in, industry... | Read more »

Price Scanner via MacPrices.net

Will Apple Build An A-series ARM Processor Po...
In computer terms, it’s been a very long time since the MacBook Air had a major redesign. More than four years have elapsed since Apple recast what had originally been more a pricy boutique device... Read more
Last minute gift idea: Send an Apple Store Gi...
Send an Apple Store Gift Card by email this season, perhaps as a last minute Christmas gift. According to Apple, “Apple Store Gift Cards can be used to purchase Apple hardware and accessories at any... Read more
Share A Prayer Customizable iPhone App Launch...
Just in time for the Christmas holiday, Joe Bellissimo, founder of Share A Prayer, Inc., has announced the launch of Share A Prayer, a new iPhone app that allows Christians all over the world to... Read more
Holiday sale prices on MacBooks, $150 off sel...
 Best Buy has two MacBooks on sale today for $150 off MSRP. Both models are available for free instant in-store pickup, or choose free shipping if you aren’t concerned with receiving it by Christmas... Read more
Holiday sale prices up to $200 off on new Mac...
 B&H Photo is offering sale prices on new Macs ranging up to $200 off MSRP plus NY sales tax only. The following models qualify for free overnight delivery if ordered by 4pm ET on Dec 23rd: - 27... Read more
Apple offers free in store pickup and setup t...
Don’t want to wait for Apple to ship your order? Choose local store pickup when ordering from The Apple Store Online. Choose between shipping to your home address or local Apple Store pickup during... Read more
Apple Supply Chain Gears Up To Begin New MacB...
Digitimes’ Aaron Lee and Joseph Tsai report that with a pilot production to be completed by the year end 2014, mass production of Apple’s next-generation 12-inch MacBook Air is expected to ramp up in... Read more
Apple Releases OS X NTP Security Update For Y...
Apple has released the OS X NTP Security Update patch for OS X Mountain Lion v10.8.5, OS X Mavericks v10.9.5, OS X Yosemite v10.10.1. Interestingly OS X 10.7 Lion is not addressed by this update,... Read more
Strategy Analytics: Big Shakeup In Tablet App...
The global tablet processor market grew 30 percent year-on-year to reach $1.2 billion in Q3 2013, according to the Strategy Analytics Handset Component Technologies service report, “Tablet Apps... Read more
iFixIt Posts “How to Solder: A Beginner’s Gui...
iFixIt blogger Julia says: Sometimes, repairing electronics requires more than just spudgering up a few connectors and swapping out the offending parts. Sometimes batteries are soldered to the... Read more

Jobs Board

*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
Senior Event Manager, *Apple* Retail Market...
…This senior level position is responsible for leading and imagining the Apple Retail Team's global event strategy. Delivering an overarching brand story; in-store, Read more
*Apple* Store Leader Program (US) - Apple, I...
…Summary Learn and grow as you explore the art of leadership at the Apple Store. You'll master our retail business inside and out through training, hands-on experience, Read more
Project Manager, *Apple* Financial Services...
**Job Summary** Apple Financial Services (AFS) offers consumers, businesses and educational institutions ways to finance Apple purchases. We work with national and Read more
*Apple* Retail - Multiple Positions (US) - A...
Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, you're also the Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.