TweetFollow Us on Twitter

Providing Progress Feedback During Script Execution

Volume Number: 22 (2006)
Issue Number: 1
Column Tag: Programming

AppleScript Essentials

Providing Progress Feedback During Script Execution

by Benjamin S. Waldie

Many AppleScripts do not provide progress updates to the user during processing. Most of the time, when a script is run, it simply performs the appropriate tasks "behind the scenes," so to speak. If run as an application, a script may appear in the Dock when launched. However, this hardly provides detailed information to the user about what is actually occurring. Sometimes, a script may not need to provide progress updates to the user. However, there are situations when providing such feedback is a good idea.

In this month's column, we will walk through the process of creating a script that will provide visual progress information to the user during processing. The script we will create will save selected email messages in Mail as text files into a user-specified output folder. Since the script will have the ability to process multiple selected email messages, we will write our code to provide a visual indication to the user of which message is currently being processed. Once you learn how to provide this type of feedback, then you can begin integrating this same technique into your other scripts, making them more user friendly.

If you followed along with some of my past AppleScript Essentials columns, then you are probably familiar with AppleScript Studio, a feature set of Xcode and Interface Builder, the Mac OS X developer tools that come with OS X. AppleScript Studio provides a way for developers to build AppleScript-based applications, complete with robust interfaces. In this month's column, we will use AppleScript Studio to add a progress interface to our script, complete with text feedback and a progress bar.

Displaying a Basic Progress Interface with AppleScript

Before we get started with AppleScript Studio, let's discuss how to provide progress information to the user in a non-AppleScript Studio-based script.

In some cases, taking the time to construct an AppleScript Studio application may not be the best solution. For example, your script may be very simple, or it may be an existing script that is too complex to warrant conversion to AppleScript Studio at this time. You may just want a quick and easy way to provide feedback to the user. In these types of situations, the easiest method is to make use of the display dialog command, which can be found in the User Interaction suite of the Standard Additions scripting addition that is installed with Mac OS X.

Using the display dialog command, you can configure a script to display text messages in a no-frills dialog window at various times during script execution. The following example code demonstrates how a display dialog command can be used to provide such feedback.

set theOutputFolder to (choose folder with prompt "Select an output folder:") as string
tell application "Mail"
   set theSelectedMessages to selection
   set theMessageCount to count theSelectedMessages
   repeat with a from 1 to theMessageCount
      display dialog "Processing message " & a & " of " & theMessageCount giving up after 
         1 with icon note
      set theMessageContent to content of item a of theSelectedMessages
      set theArchivePath to theOutputFolder & "Archived Message " & a & ".txt" as string
      set theArchiveFile to open for access theArchivePath with write permission
      set eof of theArchiveFile to 0
      write theMessageContent to theArchiveFile
      close access theArchiveFile
   end repeat
end tell

In the previous code, the first line of the script will prompt the user to select an output folder. Next, the script will retrieve a list of selected email messages in Mail. The script will then proceed to loop through each of these messages. During each repeat loop cycle, the script will retrieve the content of the current message, and save it into a file in the output folder chosen by the user.

As you can see, in order to provide visual feedback to the user during processing, I have made use of a display dialog command within the script's repeat loop. This will cause the script to display a message to the user each time the script begins processing one of the selected email messages. I have configured the display dialog command to indicate the current message count, as well as the total count of selected messages. See figure 1.


Figure 1. A Basic Script Progress Dialog

I have also configured the display dialog command to automatically dismiss the dialog after it has been displayed for 1 second. This will ensure that the script can proceed automatically with further execution, without the user being required to actually click a button in order to proceed.

Upon the successful execution of the previous code, the output folder specified by the user should contain text files containing the contents of the selected email messages. See figure 2.


Figure 2. Archived Email Messages

The display dialog command can also be used independently, rather than within a repeat loop to indicate various tasks that are being performed by the script.

Now that we have discussed providing basic progress information to the user, let's move on to AppleScript Studio. In the remainder of this month's column, we will walk through the process of creating a script that will perform the exact same function as the previous code, only with a more robust interface.

Building the AppleScript Studio Project

You may recall that the first step in building an AppleScript Studio project is to create a new project in Xcode. Begin by launching Xcode.

    Please note that the AppleScript Studio project covered in this article was developed using Mac OS X 10.4.2 and Xcode 2.1. Please be aware that new software versions often result in changes in AppleScript terminology. Therefore, if you are using software versions other than those that I have specified, your required terminology may differ slightly from that which I am using in this article.

    Create a new project by selecting New Project... from the File menu in Xcode. When prompted, select a project type of AppleScript Application from the list of available project templates, enter a project name of Archive Selected Messages, and specify an output folder for the project. Xcode will duplicate the AppleScript Application project template into the specified output folder, and open it for you. See figure 3.


Figure 3. Archive Selected Messages Project Window

Building the Interface

Next, we will create an interface for providing progress information during processing. Double click on the MainMenu.nib file within your Xcode project window. This will open the project's default view in the Interface Builder application.

Designing the Window

By default, the project's interface should already contain an empty window view. This window will be the basis for our interface. Click on the window, and give the window a name by entering Archive Selected Messages Progress into the Window Title field in the Inspector palette. See figure 4. If the Inspector palette is not visible, select Show Inspector from the Tools menu in Interface Builder.


Figure 4. Preparing the Progress Window

Once you have specified the title for the window, de-select the Visible at launch time checkbox in the Inspector palette. This will cause the window to be hidden when the project is first launched.

You may want to make some other adjustments to the window configuration at this time, as well. For example, you may want to disable the ability for the user to close or zoom the window. Refer to figure 4 for the settings that I have specified for my progress window.

Next, click on the Cocoa Controls and Indicators tab in the toolbar of the Palettes window. If the Palettes window is not visible, select Palettes > Show Palettes from the Tools menu. Next, locate an NSProgressIndicator progress bar interface element in the Palettes window, and drag it into your project's window. See figure 5.


Figure 5. Adding an NSProgressIndicator

Next, click on the Cocoa Text Controls button in the toolbar of the Palette window, and drag an NSTextField into your interface window. Enter some default text, such as Waiting to process... into the text field's contents.

Continue to arrange and design the interface, making sure to adhere to Apple's standards for human user interface guidelines, which can be found in the ADC Reference Library, both online and in Xcode's documentation. See figure 6 for an example of my completed interface design.


Figure 6. Example Progress Interface Design

Preparing the Interface for AppleScript Interaction

Once you have finished designing your progress interface, the elements that make up the interface must be prepared to interact with the AppleScript code within your project. To do this, you must assign AppleScript names to various interface elements, as well as configure certain elements of the interface to respond to event handlers.

First, we will assign an AppleScript name to the main window itself. To do this, click on the window to select it. Next, choose AppleScript from the popup button at the top of the Inspector palette, and enter the name Progress Window into the Name field. See figure 7. The process of assigning AppleScript names to the other interface elements will be the same.


Figure 7. Assigning an AppleScript Name to the Progress Window

Select the progress indicator bar and text field in the window, and assign AppleScript names of Progress Bar and Progress Text, respectively.

As the last step in configuring the progress interface, we must configure the solution to run our AppleScript code when launched. This will be done by enabling an event handler. To do this, first select File's Owner in the MainMenu.nib window. A list of available event handlers will be visible on the Inspector palette, beneath the Name field. Enable the launched event handler by selecting its checkbox in the list of event handlers. Next, link the event handler to the AppleScript code in your project by selecting the checkbox next to Archive Selected Messages.applescript in the Script area at the bottom of the Inspector palette, beneath the event handler list. See figure 8.


Figure 8. Enabling the Launched Event Handler

Adding the AppleScript code

Now that you have configured your interface, it is time to begin adding the AppleScript code into your project. Return to Xcode, and double click on Archive Selected Messages.applescript file in your project to begin editing the AppleScript code.

Preparing the Launched Event Handler

Since we configured our interface to respond to the launched event handler, we will need to add this handler to our project's code. If you saved your project's interface in Interface Builder, then this code may have been automatically inserted for you within your main project script in Xcode. If it does not exist, enter it as follows:

on launched theObject

end launched

Any code that is entered into this launched handler will be executed when our project application is launched. As we proceed, enter all code below within the launched handler.

Get the Output Folder

It is now time to begin adding the processing code to our project. Begin by entering the following code, which will prompt the user to select an output folder. Take note that this code is identical to that used in our non-AppleScript Studio example.

set theOutputFolder to (choose folder with prompt "Select an output folder:") as string

Get the Selected Messages

Next, add the following code, which will retrieve a list of any selected email messages in Mail, and will then count the detected messages.

tell application "Mail"
   set theSelectedMessages to selection
end tell
set theMessageCount to count theSelectedMessages

Show the Progress Window

You may recall that we configured our progress window to not be visible on launch. The following code will now make this window visible to the user.

set visible of window "Progress Window" to true

Prepare the Progress Bar

We are now ready to begin preparing the progress bar within our window. First, we will set the maximum value property of the progress bar to the number of detected email messages.

set maximum value of progress indicator "Progress Bar" of window 
   "Progress Window" to theMessageCount

Next, in order to ensure that our progress bar will display incremental progress, we will set the indeterminate property of the progress bar to a value of false. A progress bar with an indeterminate property value of true will appear as a blue and white striped bar, as can be seen in figure 6, and this is not desirable for providing incremental progress.

set indeterminate of progress indicator "Progress Bar" of window 
   "Progress Window" to false

Looping Through the Selected Messages

We will now add code to loop through the selected email messages. Enter the following code into the script:

repeat with a from 1 to theMessageCount

end repeat

Updating the Progress Text

The following code should be added immediately within the repeat statement. It will update the text field in our interface to indicate the current message being processed. As in our non-AppleScript Studio example, this text will tell the user the current message count, as well as the total message count.

set contents of text field "Progress Text" of window "Progress Window" to 
   "Processing message " & a & " of " & theMessageCount

Getting the Current Message's Contents

Next, add the code below, which will retrieve the content of the current email message.

tell application "Mail"
      set theMessageContent to content of item a of theSelectedMessages
end tell

Saving the Contents to a File

Again, using the exact code from our non-AppleScript Studio example, add the following to your script. This code will write the content of the current message to a text file in the specified output folder.

set theArchivePath to theOutputFolder & "Archived Message " & a & ".txt" as string
set theArchiveFile to open for access theArchivePath with write permission
set eof of theArchiveFile to 0
write theMessageContent to theArchiveFile
close access theArchiveFile

Updating the Progress Bar

Finally, for the last section of code within the repeat loop, add the following code. This code will set the content of the progress bar to the current repeat loop increment, thus increasing the progress bar's display to accurately reflect the current number of messages processed.

set content of progress indicator "Progress Bar" of window "Progress Window" to a
update window "Progress Window"

Please note that the last line in the preceding code will update the window, ensuring that the progress bar's interface is refreshed each time its content value is changed.

Completing the Code

To complete the handler, add a quit command at the end of the handler, just outside of the repeat statement. This will ensure that the application quits, once processing is complete.

quit

Next, wrap all of the code within the handler inside of a try statement, configured as follows:

try

on error theErrorMessage number theErrorNumber
   if theErrorNumber = -128 then quit
   error theErrorMessage number theErrorNumber
end try

This try statement will trap for a user cancelled error, error number -128, which would occur if the user clicks the Cancel button when prompted to select an output folder.

Now that your script is complete, the following example code shows how the completed launched handler should appear within your main project script.

on launched theObject
   try
      set theOutputFolder to (choose folder with prompt "Select an 
         output folder:") as string
      tell application "Mail"
         set theSelectedMessages to selection
      end tell
      set theMessageCount to count theSelectedMessages
      set visible of window "Progress Window" to true
      set maximum value of progress indicator "Progress Bar" of window 
         "Progress Window" to theMessageCount
      set indeterminate of progress indicator "Progress Bar" of window 
         "Progress Window" to false
      repeat with a from 1 to theMessageCount
         set contents of text field "Progress Text" of window "Progress Window" 
            to "Processing message " & a & " of " & theMessageCount
         tell application "Mail"
            set theMessageContent to content of item a of theSelectedMessages
         end tell
         set theArchivePath to theOutputFolder & "Archived Message " & a & ".txt" as string
         set theArchiveFile to open for access theArchivePath with write permission
         set eof of theArchiveFile to 0
         write theMessageContent to theArchiveFile
         close access theArchiveFile
         set content of progress indicator "Progress Bar" of window "Progress Window" to a
         update window "Progress Window"
      end repeat
      quit
   on error theErrorMessage number theErrorNumber
      if theErrorNumber = -128 then quit
      error theErrorMessage number theErrorNumber
   end try
end launched

Testing the Project

Now that our project is complete, it is ready for testing. To test the project, first launch Mail, and select multiple email messages. For best results, you may want to select a large number of messages, in order to ensure that the progress bar will increment properly. Next, select Build and Run from the Build menu in Xcode. If everything works as expected, your solution should launch, and you should be prompted to select an output folder. After choosing a folder, the project's interface should be displayed, and the selected messages should be processed and saved into the specified output folder.


Figure 9. The Completed Progress Interface

Other Options

In AppleScript Studio, a progress indicator may be displayed as a bar, as we have seen. However, a progress indicator may also be displayed as a spinner. See figure 10.


Figure 10. Example of a Progress Spinner

A progress spinner may be useful in situations where your code does not warrant providing incremental feedback to the user, yet you still wish to indicate that processing is occurring.

In Closing

The project discussed in this month's column should give you some basic ways to implement progress feedback in your scripts. Now, it is up to you to begin making your scripts more user friendly by providing such feedback to your users.

If you have difficulty getting any of the specified code to work, or if you prefer to review the actual project files, you may wish to download the example code. I have made the sample project discussed in this article available for download from my web site at the following URL:

http://www.automatedworkflows.com/files/demos/MacTECH.01.06.Example.zip

Until next time, keep scripting!


Ben Waldie is author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from http://www.spiderworks.com. Ben is also president of Automated Workflows, LLC, a firm specializing in AppleScript and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit http://www.automatedworkflows.com, or email Ben at applescriptguru@mac.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Quicken 4.6.4 - Complete personal financ...
Quicken makes managing your money easier than ever. Whether paying bills, upgrading from Windows, enjoying more reliable downloads, or getting expert product help, Quicken's new and improved features... Read more
Yasu 4.0.5 - System maintenance app.
Yasu was created with system administrators who service large groups of workstations in mind, Yasu (Yet Another System Utility) was made to do a specific group of maintenance tasks quickly within a... Read more
Stacks 3.5.5 - New way to create pages i...
Stacks is a new way to create pages in RapidWeaver. It's a plugin designed to combine drag-and-drop simplicity with the power of fluid layout. Features Fluid Layout: Stacks lets you build pages... Read more
Things 3.2 - Elegant personal task manag...
Things is a task management solution that helps to organize your tasks in an elegant and intuitive way. Things combines powerful features with simplicity through the use of tags and its intelligent... Read more
Tweetbot 2.5.3 - Popular Twitter client.
Tweetbot is a full-featured OS X Twitter client with a lot of personality. Whether it's the meticulously-crafted interface, sounds and animation, or features like multiple timelines and column views... Read more
Hopper Disassembler 4.2.19- - Binary dis...
Hopper Disassembler is a binary disassembler, decompiler, and debugger for 32- and 64-bit executables. It will let you disassemble any binary you want, and provide you all the information about its... Read more
Monosnap 3.4.0 - Versatile screenshot ut...
Monosnap lets you capture screenshots, share files, and record video and .gifs! Capture Capture full screen, just part of the screen, or a selected window Make your crop area pixel perfect with our... Read more
Duet 1.6.5.5 - Use your iPad as an exter...
Duet is the first app that allows you to use your iDevice as an extra display for your Mac using the Lightning or 30-pin cable. Note: This app requires a $14.99 iOS companion app. Version 1.6.5.5:... Read more
Hopper Disassembler 4.2.19- - Binary dis...
Hopper Disassembler is a binary disassembler, decompiler, and debugger for 32- and 64-bit executables. It will let you disassemble any binary you want, and provide you all the information about its... Read more
Duet 1.6.5.5 - Use your iPad as an exter...
Duet is the first app that allows you to use your iDevice as an extra display for your Mac using the Lightning or 30-pin cable. Note: This app requires a $14.99 iOS companion app. Version 1.6.5.5:... Read more

The best new games we played this week -...
It's pretty much been one big release after another. We were privy to a bunch of surprises this week, with a lot of games we'd been waiting for quite some time dropping unexpectedly. We hope you're free this weekend, because there is a lot for... | Read more »
Stormbound: Kingdom Wars guide - how to...
Stormbound: Kingdom Wars is an excellent new RTS turned card battler out now on iOS and Android. Lovers of strategy will get a lot of enjoyment out of Stormbound's chess-like mechanics, and it's cardbased units are perfect for anyone who loves the... | Read more »
The best AR apps and games on iOS right...
iOS 11 has officially launched, and with it comes Apple's ARKit, a helpful framework that makes it easier than ever for developers to create mobile AR experiences. To celebrate the occassion, we're featuring some of the best AR apps and games on... | Read more »
Phoenix Wright: Ace Attorney - Spirit of...
Phoenix Wright: Ace Attorney - Spirit of Justice 1.00.00 Device: iOS Universal Category: Games Price: $.99, Version: 1.00.00 (iTunes) Description: ************************************************※IMPORTANT※・Please read the “When... | Read more »
Kpressor (Utilities)
Kpressor 1.0.0 Device: iOS Universal Category: Utilities Price: $4.99, Version: 1.0.0 (iTunes) Description: The ultimate ZIP compression application for iPhone and iPad. - Full integration of iOS 11 with support for multitasking.-... | Read more »
Find out how you can save £35 and win a...
Nothing raises excitement like a good competition, and we’re thrilled to announce our latest contest. We’ll be sending one lucky reader and a friend to the Summoners War World Arena Championship at Le Comedia in Paris on October 7th. It’s the... | Read more »
Another Lost Phone: Laura's Story...
Another Lost Phone: Laura's Story 1.0 Device: iOS Universal Category: Games Price: $2.99, Version: 1.0 (iTunes) Description: Another Lost Phone is a game about exploring the social life of a young woman whose phone you have just... | Read more »
The Witness (Games)
The Witness 1.0 Device: iOS Universal Category: Games Price: $9.99, Version: 1.0 (iTunes) Description: You wake up, alone, on a strange island full of puzzles that will challenge and surprise you. You don't remember who you are, and... | Read more »
Egg, Inc. guide - how to build your gold...
Egg, Inc.'s been around for some time now, but don't you believe for one second that this quirky clicker game has gone out of style. The game keeps popping up on Reddit and other community forums thanks to the outlandish gameplay (plus, the... | Read more »
The best deals on the App Store this wee...
Good news, everyone! Your favorite day of the week has arrived at last -- it's discount roundup day! This fine Wednesday evening we're gathering up the hottest deals on the App Store. We've got action platformers, we've got puzzle games, we've got... | Read more »

Price Scanner via MacPrices.net

Sunday sale: 13-inch 3.1GHz MacBook Pros for...
Amazon has 2017 13″ 3.1GHz MacBook Pros on sale today for up to $150 off MSRP, each including free shipping: – 13″ 3.1GHz/256GB Space Gray MacBook Pro (MPXV2LL/A): $1649.99 $150 off MSRP – 13″ 3.1GHz... Read more
Looking for a 2017 12″ Retina MacBook? Save $...
Apple has Certified Refurbished 2017 12″ Retina MacBooks available for $200-$240 off the cost of new models. Apple will include a standard one-year warranty with each MacBook, and shipping is free.... Read more
Apple Offering Up To $455 Credit Toward iPhon...
iPhone 8 and 8 Plus are now available at the Apple Store, and you can receive up to $375 credit toward a new iPhone purchase when you trade in your eligible smartphone. Photo Courtesy Apple Just... Read more
AnyTrans Offers iOS Users Three Ways For Movi...
iMobie Inc. today announceed AnyTrans v6.0.1, which now can help iOS users move all data to iPhone 8/8 Plus seamlessly. The software is available both on Mac and Windows and fully able to move all... Read more
Snag a 13-inch 2.3GHz MacBook Pro for $100 of...
B&H Photo has 2017 13″ 2.3GHz MacBook Pros in stock today and on sale for $100 off MSRP, each including free shipping plus NY & NJ sales tax only: – 13-inch 2.3GHz/128GB Space Gray MacBook... Read more
Verizon offers new iPhone 8 for $100-$300 off...
Verizon is offering the new iPhone 8 for up to $300 off MSRP with an eligible trade-in: • $300 off: iPhone 6S/6S Plus/7/7 Plus, Google Pixel XL, LG G6, Moto Z2 Force, Samsung Galaxy S7/S7 edge/S8/S8... Read more
Apple Refurbished 2017 13-inch MacBook Pros a...
Apple has Certified Refurbished 2017 13″ Touch Bar MacBook Pros in stock today and available for $200-$300 off MSRP. A standard Apple one-year warranty is included with each MacBook, and shipping is... Read more
OWC USB-C Travel Dock with 5 Ports Connectivi...
OWC have announced the new OWC USB-C Travel Dock, the latest addition to their line of connectivity solutions. The USB-C Travel Dock lets you connect its integrated USB-C cable to a Mac or PC laptop... Read more
Pelican Products, Inc. Unveils Cases For All...
Pelican Products, Inc. has announced the launch of its full line of cases including Voyager, Adventurer, Protector, Ambassador, Interceptor (for the Apple iPhone 8 and 8 Plus backwards compatible... Read more
$100 off new 2017 13-inch MacBook Airs
B&H Photo has 2017 13″ MacBook Airs on sale today for $100 off MSRP including free shipping. B&H charges NY & NJ sales tax only: – 13″ 1.8GHz/128GB MacBook Air (MQD32LL/A): $899, $100 off... Read more

Jobs Board

Development Operations and Site Reliability E...
Development Operations and Site Reliability Engineer, Apple Payment Gateway Job Number: 57572631 Santa Clara Valley, California, United States Posted: Jul. 27, 2017 Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Instructional Designer, *Apple* Product Doc...
Job Summary The Apple Product Documentation team is looking for an instructional designer or a video editor to write user documentation for its professional video Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Development Operations and Site Reliability E...
Development Operations and Site Reliability Engineer, Apple Payment Gateway Job Number: 57572631 Santa Clara Valley, California, United States Posted: Jul. 27, 2017 Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.