TweetFollow Us on Twitter

Trace Pascal
Volume Number:5
Issue Number:1
Column Tag:Programmer's Workshop

Trace LightSpeed Pascal

By Alan Wootton, Santa Monica, CA, MacTutor Contributing Editor

Note: Source code files accompanying article are located on MacTech CD-ROM or source code disks.

Alan Wootton currently of MTS Informix Software, Los Angeles, is a famous early contributor of MacTutor and is well known in Mac programming circles. We welcome his return with this article.

A method of obtaining an indented listing recording the execution history, and call chain, of any LightSpeed Pascal program, is presented.

Introduction

Once upon a time (in 1975) in a far away land (Arizona) there was a young man (your humble author) who went to a great place of learning (ASU) to seek his fame and fortune. While he was there he happened upon a course of study that involved the learning of a strange new numerical language (Fortran) that could be read and understood by a new breed of Machine Folk known as ‘Computers’. Unfortunately for the students in this class, it was necessary to learn to read and understand as Machine Folk, and the ways of the Machine Folk were strange indeed. This was a most tedious and difficult job. Surely only Wizards could train their brains to such a task!

Often was the day when these poor disciples would be presented with a riddle (translated here into a more moderne language for all ye moderne folk) such as:

PROBLEM SET #4 (25 points) Given the procedure: 

PROCEDURE A (i: integer);
 begin
 if i > 2 then
 begin  
 write(i);
 A(i div 2);
 A(i - i div 2);
 end;
 end;

4a) Please write the the output produced by the call:

A(123); 

Whereupon the diligent student would, after much mental effort, correctly write:

123 61 30 15 7 3 4 8 4 4 15 7 3 4 8 4 4 31 15 7 3 4 8 4 4 16 8 4 4 8 
4 4 62 31 15 7 3 4 8 4 4 16 8 4 4 8 4 4 31 15 7 3 4 8 4 4 16 8 4 4 8 
4 4

The result of such a wizardly task was the bestowal of the desirable, yet non-negotiable, commendation known as the ‘A’. Provided of course that the student correctly answered the other parts:

4b) How many times is the procedure A invoked?

4c) What is the maximum depth to which A recurses?

The answers being, of course:

{See if you can guess. Answers at the end of the article}

As you might imagine, a great call was heard throughout the land (or at least the classroom). “Why must we learn to do the work of the machine folk when it is so admirably done by those very folk”. The answer was “so that ye may all be able to recognize the errors of the machine folk”. Errors of the machine folk? Yes, the machine folk, being of simple nature, were capable of doing only as told. When those directions were the least bit imprecise then resulting machine actions could defy all gentle reason.

At that time I thought “why don’t we teach the machines to find their own mistakes?” Being a neophyte, and not knowing the nature of the machine instructions required for such a task, I did not pursue this topic any further.

Now, things are different.

A Goal

Often I am faced with the daunting task of understanding the execution of a large, complicated, and sometimes foreign, pieces of code. My tools are the writeln, the breakpoint, the observe window, and the rest of the fine features of the LightSpeed development environment. Additionally I usually code routines to monitor the correctness of difficult data structures. And recently, I have developed a method of using the ‘hooks’ that LightSpeed puts in its code to monitor the entire execution of a program.

Having the ability to monitor the execution of a program brings up several possibilities. One could stop at the end of every procedure and verify that all the data structures are intact, or that the heap is not damaged, or that an excessive amount of time has not elapsed. As space is limited in this article I shall present what I think is a most interesting utility: A method of producing an indented listing of all procedures called.

Given the procedure above we wish to obtain a listing such that the call: A(7) produces the result:

BEGIN A       
 . BEGIN A       
 .  . BEGIN A       
 .  . END   A       
 .  . BEGIN A       
 .  . END   A       
 . END   A       
 . BEGIN A       
 .  . BEGIN A       
 .  . END   A       
 .  . BEGIN A       
 .  . END   A       
 . END   A       
END   A       

From this one can immediately deduce that A is called 7 times and that A recurses 2 levels deep (do you know what is output?). While I must stick with short examples, traces of complex programs can easily exceed 1,000,000 characters. For instance, it is very hard to trace through the sources of a MacApp program and observe what the execution order is. Given a trace (The MacApp debugger will do this) in the proper format (MacApp uses a very bad format, we use a better one here) one can very easily follow the path of execution and see immediately which procedure calls another one and when.

In order to obtain the desired result two things are needed. One, a way of putting ‘hooks’ into all the procedures. To obtain the format shown above we will need a hook at the start and at the end of every procedure. One way would be to type in a procedure call at the beginning and end of every procedure. Fortunately, there is a way to get LightSpeed to do this using the debug option. Second, we need a way for the ‘hooks’ to find the name of the procedure currently executing. The names option in LightSpeed (and other compilers) embeds the names in the code. Our hook routines can find, and use, these names.

How To Work It

To trace your program follow this simple recipe:

1) Modify your program so that it Uses the unit ‘LightTrace’.

2) Add the files ‘LightTrace.p’ and ‘LightTrace.a.lib’ to your project. Turn OFF the debug (D) option for these files. Turn ON the debug option for all files you wish traced.

3) Before any of the LightTrace routines are called you should call the routine ‘InitTracing’.

4) When you wish to start tracing, call StartTracing(false, true, true);. The first parameter specifies whether you want output in the Text (WriteLn) window. The second, if you want to open a window and show the output there. And the third, whether you want output to the file ‘Trace_File’ in the current directory.

5) (optional) Call one or more procedures or functions that may or may not have the debug option set. Try not to call StartTracing again. You may call EndTracing more than once.

6) To stop tracing you must have a call to EndTracing.

For most people this is all you need. Please skip now to the section titled “The Example:”.

How it Works

Let’s quickly run through the procedures in LightTrace and I’ll explain their operation. Please refer to listing 1.

First, InitTracing. This simply initializes the global variables used in the unit. Mostly this prevents explosions if you inadvertently call EndTracing or WriteComment at the wrong time.

Then, one calls StartTracing. The options are saved in globals, and then windows and files are opened as needed (MakeScreenWindow: opens a small window. MakeTraceFile: creates and/or opens an MPW text file). Then some of the low memory variables, holding the locations of the code to be run when the processor encounters a TRAP instruction, are hacked. They are set to the assembly language routines ReplaceTrap7 and ReplaceTrap8. These, very short, routines go directly to TraceProcTop and TraceProcBot. The effect is one of TraceProcTop being called at the start of every procedure and TraceProcBot being called at the end of every procedure.

TraceProcTop: As mentioned, all your procedures will now call TraceProcTop as the first thing they do. TraceProcTop first gets the address of the routine that called it (GetRTS returns the address that will be returned to) and then passes this address to GetTheName. What GetTheName does is to call ScanForRTS to find the end of the routine pointed at by iP. Then, assuming that the N (names) option is turned on there should be an 8 character string at that position. This string is copied to str and GetTheName returns. Actually, some MPW programs provide 16 bit names and GetTheName is setup to handle those too. Having gotten the name of the routine TraceProcTop then calls WriteStr to output the indent, the word ‘BEGIN ‘ and then the name that was found. The indent level is incremented.

TraceProcBot does almost exactly the same thing as TraceProcTop except it prints ‘END ‘ and decrements the indent level.

WriteStr, and WriteStrLn are the output routines I use here. They go through a simple bottleneck and, according to the settings of the global variables, output is sent to the window, to the file or to the WriteLn window.

EndTracing is very simple. It closes any window or file and replaces the trap vectors. It is designed to not break even if you call it twice.

How it Really Works

LightSpeed Pascal inserts a Trap8 instruction at the beginning of every procedure or function compiled with the debug option on. Trap7 is inserted similarily at the end. We repoint the vectors for these traps to our code named ReplaceTrap8 and ReplaceTrap7 respectively.

The goal was for the same code to run on my Mac+ and also on my MacII. In order to accomplish this I observed that, even though the exception stacks are different on the 68000 and the 68020, the value of the PC is in the same place relative to A7. So, I move the return PC to D0, and replace the return PC with the address of 88tmp. Then when the RTE is executed control is returned to 88tmp and not to the routine where the Trap8 was encountered (the target procedure). It is then a simple matter (having the old return PC in D0) to reformat the stack like a normal procedure call and jump to TraceProcTop. From the point of view of TraceProcTop it is as if TraceProcTop was called directly from the target procedure. ie. TraceProcTop will return (RTS) directly to the target procedure.

Since the stack is set for TraceProcTop to return directly to the target routine it is a simple matter to get this vector by simply fetching it from 4(A6). I use the inline function GetRTS to do this.

Having an address in the beginning of the target procedure does not automatically give us the information we need, the name of the target procedure! Assuming that the names option is on, we look for the end of the target procedure from which we can BlockMove the name to a string.

In order to find the end of the target procedure we scan down looking to recognize the return sequence. This is the function of the procedure ScanForRTS. I have incorporated into ScanForRTS every return sequence I have ever seen. A summary follows.

Procedure and Function end sequences. This list was compiled by looking at the endings produced by LightSpeed Pascal v1.11, LightSpeed C v2.0, MPW Pascal, and MPW C. I think it represents all of the possible endings produced by just about any compiler. TML and Turbo users: If you see any different endings produced by your compiler, then please let me know.

1)    No parameter ending
 UNLK
 RTS    ;2 words
2) Longint parameter ending
 UNLK
 MOVE.L (SP)+,(SP)
 RTS    ;3 words
4) General ending #1
 UNLK
 MOVE.L (SP)+,A0
 LEA    X(SP),SP
 JMP    (A0);5 words
5) Wasteful general ending
 UNLK
 MOVE.L (SP)+,A0
 ADD.L  #X,SP
 JMP    (A0);6 words
6) General ending #2
 UNLK
 MOVE.L (SP)+,A0
 ADD.W  #X,SP
 JMP    (A0);5 words
7) Wasteful no parameter ending.
 UNLK
 MOVE.L (SP)+,A0
 JMP    (A0)

Xtra for Xperts

Please note that the name at the end of the target procedure has the high bit of the first byte set. In some cases, notably MacApp method calls, a 16 byte name is supplied by the compiler. I have noticed that when 16 byte names are supplied then the high bit of the first two bytes are set. GetTheName takes this into account.

OK, so you’re wondering why I make allowances for all these other compilers when this article is for LightSpeed Pascal (works with 1.11 and 2.0). This is because I have used this code to trace code from other compilers, and I didn’t want to change it back.

MPW Pascal has an option (D++) where the compiler inserts a call to %_BP at the beginning of every procedure, and a call to %_EP at the end. If you modify StartTraceTime to hack the A5 jump table instead of the trap vectors then you can use this to trace your MPW and MacApp programs.

Furthermore, if you start a timer at StartTraceTime and pause it during TraceProcTop and TraceProcBot it is possible to get a real useful performance analysis at the same time as you get a trace.

Many other possibilities manifest themselves, given a little thought. Anyone want to do a heap scramble? How about a gadget that measures the maximum amount of stack that is used?

The Example

The code that follows is an example, for LightSpeed Pascal, of how to trace the execution of two procedures.

Listing 1 is the text of the unit ‘LightTrace’.

Listing 2 is the source for LightTrace.a. Note that if you get the disks from MacTutor you will not need an assembler. You can just use the library LightTrace.a.lib.

Listing 3 is a short sample program. This is the way that your program should invoke tracing.

Listing 4 is the ‘Echo File’ produced by the WriteLn’s in the sample. The Text window shows the same.

Listing 5 is the trace output produced by setting the third parameter in StartTracing.

Listing 6 is the project for this example in LSP 1.11 format. This code works in the new (2.0) version also but the project is different. You will also need to convert the .lib to the new format.

Listing 1  
This is the file LightTrace.p.  It, along with LightTrace.a, contain all the code necessary 
for tracing procedure and function calls in LightSpeed Pascal. 

unit LightTrace;
interface

 procedure InitTracing;
{ call this to init Trace vars to safe values }

 procedure StartTracing 
 (toText, toScreen, toFile: boolean);
{ Start tracing all Subroutines }

 procedure EndTracing;
{ return to normal operation }

 procedure WriteComment (Str: str255);
{ write Str to Trace output }

{ The ‘Of’ functions are useful when formatting output }  
{ that must be a Str255.  Also, try them in your observe } { window. 
eg. Rectof(ThePort^.ClipRgn^^.RgnBBox) }

 function IntOf (Int: longint): str255;
{ convert the Int to a Decimal Str255 }

 function HexOf (lll: longint): str255;
{ convert the Int to a Hex Str255 }

 function PointOf (fff: Point): str255;
{ convert the Point to a Str255 }

 function RectOf (R: Rect): str255;
{ convert the Rect to a Str255 }

 procedure TraceProcTop;{ don’t call this yourself}

 procedure TraceProcBot;{ don’t call this yourself}

implementation

 type
 intsArr = array[0..16000] of integer;
 intsArrP = ^intsArr;

 var
 indent: integer;
 OldTrap7, OldTrap8: longint;
 doText, doScreen, doFile, started: boolean;
 ScreenWindow: grafPtr;
 TracePB: paramBlockRec;

 procedure ScanForRts (var iP: intsArrP);
 forward;

{ see  LightTrace.asm } 
 procedure ReplaceTrap7;
 external;
 procedure ReplaceTrap8;
 external;

{ retreive the addesss of the calling routine }
 function GetRTS: longint;
 inline
 $2EAE, $0004;{ move.l 4(A6),(sp) }

 function IntOf; {(int : longint) : str255}
 var
 str: str255;
 begin
 NumToString(int, str);
 IntOf := str;
 end;

 function HexOf; { (lll : longint) : str255}
 var
 str, str2: str255;
 i: integer;
 c: char;
 begin
 if lll = 0 then
 str := ‘$0’
 else
 begin
 str := ‘’;
 while (lll <> 0) do
 begin
 i := lll mod 16;
 if i < 10 then
 c := chr(ord(‘0’) + i)
 else
 c := chr(ord(‘A’) + (i - 10));
 str2 := ‘x’;
 str2[1] := c;
 str := concat(str2, str);
 lll := BitShift(lll, -4);
 end;
 str := concat(‘$’, str)
 end;
 HexOf := str;
 end;

 function Pointof;{  (fff :  Point) : str255}
 var
 str: str255;
 begin
 str := concat(IntOf(fff.h), ‘ ‘, IntOf(fff.v));
 Pointof := str;
 end;


 function RectOf; {(R : Rect) : str255}
 var
 str: str255;
 begin
 with R do
 str := concat(Intof(left), ‘ ‘, Intof(top), ‘ ‘,              
 Intof(right), ‘ ‘, Intof(bottom), ‘ ‘);
 RectOf := str;
 end;

{ set the globals to safe values }
 procedure InitTracing;
 begin
 started := false;
 doText := true;
 doScreen := false;
 doFile := false;
 indent := 0;
 end;

{ Open a small window in the back to see our output }
{ set ScreenWindow to point to this window }
 procedure MakeScreenWindow;
 var
 r: rect;
 OldPort: GrafPtr;
 begin
 getPort(OldPort);
 setRect(r, 4, 40, 156, 140);
 ScreenWindow := NewWindow(nil, r, ‘Trace Info’,
 true, 0, nil, false, 0);
 setport(ScreenWindow);
 textmode(srccopy);
 textFont(1);
 textsize(9);
 textFont(4);{monaco}
 moveto(4, 16);
 setport(OldPort);
 end;

{ remove ScreenWindow from the screen and from}
{memory }
 procedure RemoveScreenWindow;
 begin
 if doScreen then
 DisposeWindow(ScreenWindow);
 end;

{ do this to write a cr to the screen }
 procedure ScreenLn;
 var
 ThePen, poi: point;
 r: rect;
 aRgn: RgnHandle;
 OldPort: GrafPtr;
 begin
 GetPort(OldPort);
 SetPort(ScreenWindow);
 r := ScreenWindow^.PortRect;
 GetPen(ThePen);
 ThePen.h := r.left + 4;
 ThePen.v := ThePen.v + 12; { move thePen down }
 if (ThePen.v + 12) > r.bottom then
 begin { scroll up if necessary }
 aRgn := NewRgn;
 ScrollRect(r, 0, -12, aRgn);
 DisposeRgn(aRgn);
 ThePen.v := ThePen.v - 12;
 setorigin(0, 0);
 repeat { pause feature }
 GetMouse(poi);
 until not ptInRect(poi, r);
 end;
 moveto(ThePen.h, ThePen.v);
 setPort(OldPort);
 end;

{ This does a Write to our window }
 procedure WriteScreen (str: str255);
 var
 ThePen: point;
 r: rect;
 OldPort: GrafPtr;
 cr: str255;
 begin
 cr := ‘x’;
 cr[1] := chr(13);
 GetPort(OldPort);
 SetPort(ScreenWindow);
 r := ScreenWindow^.PortRect;
 GetPen(ThePen);
 if (ThePen.h + stringwidth(str) > r.right) or
 (pos(cr, str) > 0) then
 ScreenLn;
 DrawString(str);
 SetPort(OldPort);
 end;

{ This does a WriteLn to our window }
 procedure WriteScreenLn (str: str255);
 var
 i: integer;
 ThePen: point;
 r: rect;
 OldPort: GrafPtr;
 begin
 GetPort(OldPort);
 SetPort(ScreenWindow);
 WriteScreen(str);
 ScreenLn;
 SetPort(OldPort);
 end;

 procedure MakeTraceFile;
 var
 err: integer;
 str: str255;
 begin
 str := ‘Trace_File’;
 with TracePB do
 begin
 ioCompletion := nil;
 ioNamePtr := @str;
 ioVRefNum := 0;
 ioVersNum := 0;
 ioPermssn := 0;
 ioMisc := nil;
 err := PBOpen(@TracePB, false);
 if err = fnfErr then
 begin
 err := PBCreate(@TracePB, false);
 if err = 0 then
 err := PBOpen(@TracePB, false);
 end;
 if err = 0 then
 begin
 ioMisc := pointer(0);
 err := PBSetEOF(@TracePB, false);
 if err = 0 then
 begin
 err := PBGetFInfo(@TracePB, false);
 if err = 0 then
 with TracePB.ioFlFndrInfo do
 begin
                         { we’ll make this an MPW text file }
 fdType := ‘TEXT’;
 fdCreator := ‘MPS ‘;
 err := PBSetFInfo
 (@TracePB, false);
 end;{ with finder info }
 end;{ if getFinfo OK }
 end { if open OK }
 else
 doFile := false;
 end; { with TracePB }
 end;{ proc MakeTraceFile }

 procedure CloseTraceFile;
 var
 err: integer;
 begin
 if doFile then
 err := PBClose(@TracePB, false);
 end;

{ same as write except the str goes to the file }
 procedure WriteFile (str: str255);
 var
 err: integer;
 eof: longint;
 begin
 if length(str) > 0 then
 if doFile then
 with TracePB do
 begin
 err := PBGetEof(@TracePB, false);
 { ever Fail??}
 if err <> 0 then
 repeat
 sysbeep(1)
 until button;

 eof := ord(ioMisc);
 ioMisc := pointer(eof + length(str));
 err := PBSetEof(@TracePB, false);
 if err = 0 then
 begin
 ioBuffer := pointer(ord(@str) + 1);
 ioReqCount := length(str);
 ioPosMode := fsFromstart;
 ioPosOffset := eof;
 err := PBWrite(@TracePB, false);
 end;{ setEof OK }
 end;{ with TracePB }
 end;{ proc WriteFile }

{ same as writeLn(str) except output is to the file}
 procedure WriteFileLn (str: str255);
 begin
 writeFile(str);
 str := ‘x’;
 str[1] := chr(13);
 writeFile(str);
 end;

{ These two proc’s are our output bottleneck }

 procedure WriteStr (str: str255);
 begin
 if doText then
 Write(str);
 if doScreen then
 WriteScreen(str);
 if doFile then
 WriteFile(str);
 end;

 procedure WriteStrLn (str: str255);
 begin
 if dotext then
 WriteLn(str);
 if doScreen then
 WriteScreenLn(str);
 if doFile then
 WriteFileLn(str);
 end;

{ Call ScanForRTS to find the end of a procedure.  iP is}
{pointed past the end (at the name) Copy the name into}
{the str.  If it is a MacApp name (16 char), then add}
{more.}
 procedure GetTheName (var iP: intsArrP;
 var str: str255);
 begin
 str := ‘12345678’;
 ScanForRts(iP);
 blockMove(@iP^, pointer(ord(@str) + 1), 8);
 if ord(str[1]) >= 128 then
 str[1] := chr(ord(str[1]) - 128);
 if ord(str[2]) >= 128 then
 begin
 str[2] := chr(ord(str[2]) - 128);
 str := concat(str, ‘12345678’);
 blockMove(pointer(ord(@iP^) + 8),
  pointer(ord(@str) + 9), 8);
 end;
 end;

 procedure TraceProcTop;
 var
 str: str255;
 iP: intsArrP;
 i: integer;
 begin
 iP := pointer(GetRTS);
 GetTheName(iP, str);
 for i := 1 to indent do
 writeStr(‘ . ‘);
 indent := indent + 1;
 writeStr(‘BEGIN ‘);
 writeStrLn(str);
 end;

 procedure TraceProcBot;
 var
 str: str255;
 iP: intsArrP;
 i: integer;
 begin
 iP := pointer(GetRTS);
 GetTheName(iP, str);
 indent := indent - 1;
 for i := 1 to indent do
 writeStr(‘ . ‘);
 writeStr(‘END   ‘);
 writeStrLn(str);
 end;

 procedure WriteComment;{ (str : str255)}
 var
 i: integer;
 begin
 for i := 1 to indent do
 writeStr(‘ . ‘);
 writeStr(‘REM ‘);
 writeStrLn(str);
 end;

{ This routine moves the pointer , iP, down in memory}
{until the end sequence of a procedure or function is}
{found.  Or, it quits after 16000 bytes.  If an end }
{sequence is found then the pointer if set past the last}
{word.  If not, then the pointer is pointed at the text}
{‘unknown ‘ (8 char, including the space). See article}
{text for a list of end sequences.}

 procedure ScanForRts; { (var iP : intsArrP)}
 var
 count, size: longint;
 str: str255;
 begin
 count := 8000;{ max size of any procedure ??? }
 size := 0;
 while size = 0 do
 begin
 if iP^[0] = $4E5E then   { UNLK }
 begin
 if (iP^[1] = $2E9F) and (iP^[2] = $4E75) then
 size := 6
     {   MOVE.l (A7)+,A7  RTS}
 else if iP^[1] = $4E75 then
 size := 4{ RTS }
 else if iP^[1] = $205F then
 { MOVEA.L (A7)+,A0 }
 begin
 if (iP^[2] = $4FEF) and 
 (iP^[4] = $4ED0) then
 { LEA x(A7),A7  JMP (A0) }
 size := 10
 else if (iP^[2] = $DFFC) and 
 (iP^[5] = $4ED0) then
    { ADD.l #x,A7  JMP (A0) }
 size := 12
 else if (iP^[2] = $DEFC) and
  (iP^[4] = $4ED0) then
  { ADD.w #x,A7  JMP (A0) }
 size := 10
 else if iP^[3] = $4ED0 then
 size := 8  {JMP (A0) }
 end;
 end;
 count := count - 2;
 if count <= 0 then
 size := 22222;
 if size <> 0 then
 iP := pointer(ord(iP) + size)
 else
 iP := pointer(ord(iP) + 2)
 end;{ while size=0 }
 if count <= 0 then
 begin
 str := ‘unknown ‘;
 iP := pointer(ord(@str) + 1);
 end;
 end; { proc scan for Rts }

 procedure StartTracing; 
 { (toText, toScreen, toFile : boolean)}
 var
 lP: ^longint;
 begin
 InitTracing;{ initialize global vars }
 { save the options as globals }
 doText := toText;
 doScreen := toScreen;
 doFile := toFile;
 started := true;
 if doscreen then
 MakeScreenWindow;
 if doFile then
 MakeTraceFile;
 if doText then
 ShowText;

 lP := pointer($80 + 4 * 7);{ trap 7}
 OldTrap7 := lP^;
 lP^ := ord(@ReplaceTrap7);
 lP := pointer($80 + 4 * 8);{ trap 8}
 OldTrap8 := lP^;
 lP^ := ord(@ReplaceTrap8);
 end;{ proc StartTracing }

 procedure EndTracing;
 var
 lP: ^longint;
 begin
 if Started then
 begin
 lP := pointer($80 + 4 * 7);{ trap 7}
 lP^ := OldTrap7;
 lP := pointer($80 + 4 * 8);{ trap 8}
 lP^ := OldTrap8;
 RemoveScreenWindow;
 CloseTraceFile;
 end;
 InitTracing;
 end;{ proc EndTracing }
end.{ unit lightTrace }
Listing 2  
This is the file LightTrace.a.  It makes the two code fragments ReplaceTrap8, and ReplaceTrap7 
available to the pascal code.  What these fragments do is convert the stack from exception 
(RTE or interrupt) format to subroutine (RTS) format, and then jump to TraceProcTop 
(or TraceProcBot).  We take advantage of the fact that in all 680XX machines the program 
counter that we RTE to is at 2(a7).  Note that the amount of stack used by the RTE can be 
different depending upon processor type.

 import TraceProcTop:CODE 
 import TraceProcBot:CODE 

ReplaceTrap8 proc export

 move.l 2(sp),d0 ;address to RTS to
  lea    @88tmp,a0
 move.l a0,2(sp) ;fake address to RTE to
 RTE

@88tmp
 move.l  d0,-(sp);setup stack for rts
 jmp     TraceProcTop(a5)
 
ReplaceTrap7 proc export

 move.l 2(sp),d0 ;address to RTS to
  lea    @77tmp,a0
 move.l a0,2(sp) ;fake address to RTE to
 RTE

@77tmp
 move.l  d0,-(sp);setup stack for rts
 jmp     TraceProcBot(a5)
 
 end ; of file LightTrace.a
Listing 3  
This is the file Test_LightTrace.p.  Here we exercise the LightTrace routines with 
two short numerical  algorithms.

program test_LightTrace;
 uses
 LightTrace;
 var
 i, j: integer;

 procedure Decompose (Num: integer);
  { factor Num, report smallest factors first }
 var
 i, factor: integer;

 function check (factor: integer): boolean;
 begin
 if (Num div factor) * factor = Num then
 check := true
 else
 check := false;
 end;

 begin
 write(IntOf(Num), ‘=1’);
 while check(2) and (Num > 1) do
 begin
 write(‘*2’);
 Num := Num div 2;
 end;
 factor := 3;
 while (Num > 1) do
 begin
 while check(factor) and (Num > 1) do
 begin
 write(‘*’, IntOf(factor));
 Num := Num div factor;
 end;
 factor := factor + 2;
 end;
 writeln;
 end;

 procedure Reduce
  (var numerator, denominator: integer);
 {reduces fraction to lowest terms}
 var
 commonDivisor: integer;

 function GCD (m, n: integer): integer;
 var
 r: integer;
 begin
 writeComment(
 concat(‘GCD ‘, IntOf(m), ‘ ‘, IntOf(n)));
 r := m mod n;
 if r = 0 then
 GCD := n
 else
 GCD := GCD(n, r)
 end;{ funct GCD }

 begin { proc reduce }
 commonDivisor := GCD(numerator, denominator);
 numerator := numerator div commonDivisor;
 denominator := denominator div commonDivisor;
 end; { proc reduce }

begin
 showtext;
 InitTracing;
 StartTracing(false, true, true);
 decompose(1 * 2 * 3 * 4 * 5);
 i := 1 * 2 * 3 * 4 * 5;
 j := 6 * 7 * 8 * 9;
 write(IntOf(i), ‘/’, IntOf(j), ‘=’);
 reduce(i, j);
 writeln(IntOf(i), ‘/’, IntOf(j));
 EndTracing;
end.{ of main program test_LightTrace }
Listing 4  
This is the file ‘Echo File’.  This is what is sent to the text window by writeln’s. It 
is only two lines long and shows the result of factoring a number and reducing a fraction.

120=1*2*2*2*3*5
120/3024=5/126
Listing 5  
This is the file ‘Trace_File’.  It was created automatically because the third argument 
to StartTracing was true.  It contains the trace output, including comments.  It does not 
contain any writeln’s. Please notice that there are two sections.  The first is the trace of 
the procedure Decompose. The second is the trace of the procedure Reduce, which recurses.

 BEGIN DECOMPOS
 . BEGIN CHECK   
 . END   CHECK   
 . BEGIN CHECK   
 . END   CHECK   
 . BEGIN CHECK   
 . END   CHECK   
 . BEGIN CHECK   
 . END   CHECK   
 . BEGIN CHECK   
 . END   CHECK   
 . BEGIN CHECK   
 . END   CHECK   
 . BEGIN CHECK   
 . END   CHECK   
 . BEGIN CHECK   
 . END   CHECK   
END   DECOMPOS
BEGIN REDUCE  
 . BEGIN GCD     
 .  . REM GCD 120 3024
 .  . BEGIN GCD     
 .  .  . REM GCD 3024 120
 .  .  . BEGIN GCD     
 .  .  .  . REM GCD 120 24
 .  .  . END   GCD     
 .  . END   GCD     
 . END   GCD     
END   REDUCE  

Listing 6

This is the project window for the example presented here. Note that the procedures to be traced must have the debug (D) and names (N) selected. Also note, The LightTrace unit must not have the debug (D) option selected.

Answers to problems 4b and 4c being, of course:127 and 6

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

TunnelBear 3.5.1 - Subscription-based pr...
TunnelBear is a subscription-based virtual private network (VPN) service and companion app, enabling you to browse the internet privately and securely. Features Browse privately - Secure your data... Read more
Typinator 7.4 - Speedy and reliable text...
Typinator turbo-charges your typing productivity. Type a little. Typinator does the rest. We've all faced projects that require repetitive typing tasks. With Typinator, you can store commonly used... Read more
Fantastical 2.4.5 - Create calendar even...
Fantastical 2 is the Mac calendar you'll actually enjoy using. Creating an event with Fantastical is quick, easy, and fun: Open Fantastical with a single click or keystroke Type in your event... Read more
Monosnap 3.4.9 - Versatile screenshot ut...
Monosnap lets you capture screenshots, share files, and record video and .gifs! Features Capture Capture full screen, just part of the screen, or a selected window Make your crop area pixel... Read more
Skim 1.4.32 - PDF reader and note-taker...
Skim is a PDF reader and note-taker for OS X. It is designed to help you read and annotate scientific papers in PDF, but is also great for viewing any PDF file. Skim includes many features and has a... Read more
ForkLift 3.1.1 - Powerful file manager:...
ForkLift is a powerful file manager and ferociously fast FTP client clothed in a clean and versatile UI that offers the combination of absolute simplicity and raw power expected from a well-executed... Read more
Direct Mail 5.2.1 - Create and send grea...
Direct Mail is an easy-to-use, fully-featured email marketing app purpose-built for macOS. Create, send, and track great looking email campaigns that get results. Start your newsletter by selecting... Read more
Direct Mail 5.2.1 - Create and send grea...
Direct Mail is an easy-to-use, fully-featured email marketing app purpose-built for macOS. Create, send, and track great looking email campaigns that get results. Start your newsletter by selecting... Read more
Skim 1.4.32 - PDF reader and note-taker...
Skim is a PDF reader and note-taker for OS X. It is designed to help you read and annotate scientific papers in PDF, but is also great for viewing any PDF file. Skim includes many features and has a... Read more
ForkLift 3.1.1 - Powerful file manager:...
ForkLift is a powerful file manager and ferociously fast FTP client clothed in a clean and versatile UI that offers the combination of absolute simplicity and raw power expected from a well-executed... Read more

Latest Forum Discussions

See All

What mobile gaming can learn from the Ni...
While Nintendo might not have had things all its own way since it began developing for mobile, one thing it has got right is the release of the Switch. After the disappointment of the WiiU, which I still can't really explain, the Switch felt a... | Read more »
Programmer of Sonic The Hedgehog launche...
Japanese programmer Yuji Naka is best known for leading the team that created the original Sonic The Hedgehog. He’s moved on from the speedy blue hero since then, launching his own company based in Tokyo – Prope Games. Legend of Coin is the... | Read more »
Why doesn't mobile gaming have its...
The Overwatch League is a pretty big deal. It's an attempt to really push eSports into the mainstream, by turning them into, well, regular sports. But slightly less sweaty. It's a lavish affair with teams from all around the world, and more... | Read more »
Give Webzen’s new billiard game PoolTime...
Best known for producing hugely popular MMO titles, South Korean publisher Webzen is now taking aim at a different genre altogether. PoolTime is a realistic eight ball pool simulator, allowing you to compete in real-time matches against players... | Read more »
Let Them Come Guide - How to survive aga...
Let Them Come is all about making it as far as possible against overwhelming odds. Check out some of these tips to help you last a little longer in your unwinnable fight: [Read more] | Read more »
All the best games on sale for iPhone an...
Happy last day of the week. I hope you've been having a good one. I have. I saw ten doggos today. So because I'm in a good mood, I thought I'd round up all of the best games that are currently on sale on the App Store. [Read more] | Read more »
The very best games that came out for iP...
We're getting to the end of the first real, full, proper week of 2018. And in that time we've seen some pretty awesome games landing on the App Store. Of course, we've seen some absolute duffers as well. The sort of games that you look at and... | Read more »
Rusty Lake Paradise (Games)
Rusty Lake Paradise 1.4 Device: iOS Universal Category: Games Price: $2.99, Version: 1.4 (iTunes) Description: Jakob, the oldest son of the Eilander family, is returning to Paradise island after his mother passed away. Since her... | Read more »
Antihero Guide - Sneaky tricks to get ah...
Games of Antihero start out small and streamlined, but they quickly turn into long strategic conquests as you fight for control of the Victorian-era streets. If you find yourself struggling in the skullduggery department, here are a few things you... | Read more »
Here's why Niantic pulling Pokemon...
If there's one thing that Pokemon GO did well, it was bringing people together. I still remember seeing groups of people around the marina near where I live in the weeks after the game came out, all of them trying to grab some water Pokemon. There... | Read more »

Price Scanner via MacPrices.net

10″ iPad Pros on sale for $50-$75 off MSRP, n...
B&H Photo has 10″ and #Apple #iPad Pros on sale for up to $75 off MSRP. Shipping is free, and B&H charges sales tax in NY & NJ only. Note that some sale prices are restricted to certain... Read more
Apple refurbished Mac minis available startin...
Apple has restocked Certified Refurbished Mac minis starting at $419. Apple’s one-year warranty is included with each mini, and shipping is free: – 1.4GHz Mac mini: $419 $80 off MSRP – 2.6GHz Mac... Read more
Amazon offers Silver 13″ Apple MacBook Pros f...
Amazon has new Silver 2017 13″ #Apple #MacBook Pros on sale today for up to $150 off MSRP, each including free shipping: – 13″ 2.3GHz/128GB Silver MacBook Pro (MPXR2LL/A): $1199.99 $100 off MSRP – 13... Read more
Sale: 12″ 1.3GHz MacBooks on sale for $1499,...
B&H Photo has Space Gray and Rose Gold 12″ 1.3GHz #Apple MacBooks on sale for $100 off MSRP. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 12″ 1.3GHz Space... Read more
Apple offers Certified Refurbished 2017 iMacs...
Apple has a full line of Certified Refurbished iMacs available for up to $350 off original MSRP. Apple’s one-year warranty is standard, and shipping is free. The following models are available: – 27... Read more
13″ MacBook Airs on sale for $120-$100 off MS...
B&H Photo has 2017 13″ 128GB MacBook Airs on sale for $120 off MSRP. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 13″ 1.8GHz/128GB MacBook Air (MQD32LL/A): $... Read more
15″ Touch Bar MacBook Pros on sale for up to...
Adorama has Space Gray 15″ MacBook Pros on sale for $200 off MSRP. Shipping is free, and Adorama charges sales tax in NJ and NY only: – 15″ 2.8GHz MacBook Pro Space Gray (MPTR2LL/A): $2199, $200 off... Read more
21″ 3.4GHz 4K iMac on sale for $1399, $100 of...
Adorama has the 21″ 3.4GHz 4K #Apple #iMac on sale today for $1399. Their price is $100 off MSRP. Shipping is free, and Adorama charges sales tax in NJ and NY only: – 21″ 3.4GHz 4K iMac (MNE02LL/A... Read more
B&H offering 13″ Apple MacBook Pros for u...
B&H Photo has 13″ MacBook Pros on sale for up to $75-$120 off MSRP. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 13-inch 2.3GHz/128GB Space Gray MacBook Pro (... Read more
B&H continues to offer clearance 2016 15″...
B&H Photo has clearance 2016 15″ #MacBook Pros available for up to $800 off original MSRP. Shipping is free, and B&H charges NY & NJ sales tax only: – 15″ 2.7GHz Touch Bar MacBook Pro... Read more

Jobs Board

*Apple* Retail - Multiple Positions - Apple,...
Job Description:SalesSpecialist - Retail Customer Service and SalesTransform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Site Reliability Engineer, *Apple* Pay - Ap...
# Site Reliability Engineer, Apple Pay Job Number: 113356036 Santa Clara Valley, California, United States Posted: 12-Jan-2018 Weekly Hours: 40.00 **Job Summary** Read more
UI Tools and Automation Engineer, *Apple* M...
# UI Tools and Automation Engineer, Apple Media Products Job Number: 86351939 Santa Clara Valley, California, United States Posted: 11-Jan-2018 Weekly Hours: 40.00 Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
UI Tools and Automation Engineer, *Apple* M...
# UI Tools and Automation Engineer, Apple Media Products Job Number: 113136387 Santa Clara Valley, California, United States Posted: 11-Jan-2018 Weekly Hours: 40.00 Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.