TweetFollow Us on Twitter

Code Tester
Volume Number:3
Issue Number:11
Column Tag:ABC's of Macintosh

Code Tester Shell for Pascal

By J. E. “Jeff” Fox, Houston, TX

Writing code for the Macintosh can be a very tedious process, unless you start with a shell program. The program in this example is designed to provide a simple shell supporting a window, menus, text edit and update events. You can select a desk accessory, move the window, zoom the window, and close the window. The window supports a text edit record and some quickdraw graphics, both of which are updated whenever the window is uncovered. The purpose of this shell program was to provide a simple working Macintosh program, which could then be used to test specific code examples. So I’ve called it Code Tester! The routines to be tested are placed in the TestStuff Unit. I’ve coded two routines called ‘theTest’, which displays some text edit message, and ‘theDrawing’, which draws some quickdraw stuff in color (if you have a Mac II). You can use this code tester shell to quickly test out procedures that will become a part of a larger Mac program, without having to re-invent the event loop programming of windows, events, menus and so forth. If you are new to Mac programming, this will also give you a good overview of how a Mac program is constructed. The black and white output of code tester is shown in figure 1.

This program was first written in TML Pascal using TML’s syntax of segmentation. The version presented here is written in LS Pascal using units instead of segments. It should be easily ported to either Turbo Pascal or back to TML Pascal. The program globals are placed in one unit, while the main program and the test unit make up the other two units.

LS Pascal 1.11 and the Macintosh II

The latest version of TML Pascal that I have is 2.2 which I used on this program. For LS Pascal, the latest version is 1.11 which is officially a ‘beta’. Think is distributing version 1.11 as a patcher program plus libraries that will automatically update your version 1.0 LS Pascal into the 1.11 version. This version runs on the Mac II and supports the new Mac II libraries. However, there are still problems in using the LS shell environment to run, debug and edit your programs. Apparently, not all of the system parameters required for a color video board on a Mac II are being properly reset and if you have your video set to 256 colors, you may find yourself crashing a lot when editing and running under the LS shell. Think is still trying to get all the bugs out of this. In black and white mode, this version seems very reliable on the Mac II.

Fig. 1 Text Edit, & Color Quickdraw (on a Mac II!)

Mac programs written in Pascal tend to have a very small main program. Find the end of the program listing ‘CodeTester’, and you’ll see our main program has only four items: PrimeMemory, MainSetUp, MainEventLoop and Close.

Does Anyone Understand Memory Management?

The first procedure called is Prime Memory. This routine is called first to do some memory management for us. A typical thing is to allocate additional master pointers and set up a grow zone proc in case we run out of memory. It is also possible to do some heap management such as calling MaxApplZone to grow the heap to the application limit. However, this might not be considered ‘MultiFinder friendly’ when we start dividing the heap into seperate application zones. As MultiFinder becomes available, and Inside Macintosh Volume 5 gets ‘debugged’ from all it’s errors, hopefully a more clear picture of how memory management is properly done will emerge. While I have not placed a grow zone proc in our program, an example is given here. A program’s grow zone function is called by the Memory manager when it needs a larger continuous chunk of memory then it has available. As usual though there are a couple of pitfalls here. I constructed this straight from IM and hope that I am correct. Memory management seems to be the most misunderstood of all Mac subjects and more information in this area would be welcome at MacTutor.

FUNCTION MyGrowZone(cbNeeded : Size) : LongInt;
Var
 AHandle : Handle;
Begin
 If NOT GZCritical Then
    MyGrowZone := 0 {don’t respond, post failure }
   ELSE
    Begin
        AHandle := GZSaveHnd;  { handle in danger? }
        If AHandle = NIL Then   {dump something }
          Begin
            SetFontLock(FALSE);
 (* Anything else *)
 MyGrowZone :=1;  {we freed some}
 End {AHandle = NIL}
 ELSE
 MyGrowZone := 0; 
 End;  {First Else, AHandle :=}
End;  

Another heap management routine that could be called in our ‘PrimeMemory’ routine is one to set the application heap limit. Again, under MultiFinder, this probably would not be desirable since MultiFinder is allocating each application it’s own heap space based on the size resource in the resource file. Also, this command seems to choke LS Pascal’s shell environment, so I have left it out of the code.

SetApplLimit(POINTER(ORD4(GetApplLimit)-4096));

What we are trying to do here is to add about 4k to the initial 8K stack size at start-up.

Then (Last but not least) we call MoreMasters. For EACH MoreMasters call we obtain 1 Master Ptr. block with 64 master pointers for the use of the program. All of our handles we declare in the program will use one of these master pointers.

Initializing the Macintosh Managers

Going back to the Main program, next comes ‘MainSetUp’, which collects all the init type calls. In the routine ‘Energize’ is the standard Macintosh inits for quickdraw, menus, fonts and so forth. One thing that is always handy is to place a pointer to a crash routine in the call to InitDialogs(). This will direct the Mac to your crash proc when the user hits the resume button during a system bomb. This could prevent damage from a system reset. In our program, our crash proc just returns to the Finder. Take a look at how the cursor is set up, course you don’t have to do it like this if you don’t want to. Here again just a convenience. Note the type coercion in the HLock call. HLock expects a HANDLE, not a CURSHANDLE. Watch (no pun) the spelling of curshandle. CursorHandle is wrong, and it’s real easy to do. Also watch out for ICN# NOT ICON# it can be a really frustrating experience (I’ve done it twice now sigh).

The other set up troutines are for a window, text edit, rectangles and menus. In our program, we have only two menus so this is pretty straight forward. The SetUpLimits routine is used to set our rectangles. Note here that we set the rectangle for our window in relation to the screenbit.bounds global variable. This variable is managed by Quickdraw and by referencing it, our window will open up to a size that is appropriate to whatever monitor our program is running on. All window manager rectangles should be defined in relation to screenbits.bounds so that they will be independent of the display being used. In setting up text edit, we define the view area for text edit in relation to the window’s port rectangle, then call TENew. This will associate a text edit record with this window. Note that the current grafport for quickdraw must be set to the window before TENew is called. This is so Text Edit can access the quickdraw globals for the text size, font, style and mode. In our program, we call SetUpWindow first, then call SetUpTE second, so everything is done in the right order.

The Main Event

The main event loop is of course, the heart of all Macintosh programs. Our event loop calls system task, idles the text edit cursor and gets an event. Under MultiFinder, you might want to replace GetNextEvent with WaitNextEvent if your program does not use null events. This will allow more time for MultiFinder to give to other applications that might be running in background during null events. Our program will process a mouse event, a menu key event, an activate/deactivate event and an update event. In our case, the activate event is trivial. All we do is call TEActivate, which sets the caret at the insertion point so it will blink when TEIdle is called. However, since we don’t have any typing implement in our keydown event, this isn’t of much interest.

The Mighty Update Event

Update events are the soul of the Macintosh. Mac guidelines suggest that all drawing on the Mac be done during an update event. The way this is done for text as an example, is to set up the text edit record and then invalidate an area of the screen. When the update event is generated, our update routine calls TEUpdate, and the text is automatically displayed. This is what we do in our ‘theText’ procedure. We don’t actually draw any text in the window. We just stuff it into our text edit record and invalidate the port rectangle of our window, generating an update event. But what about graphics? To update the graphics portion of our screen, we call our drawing routine. This requires that all drawing calls be stored so that they can collectively be called any time an update event takes place, re-drawing the display. This is where the Mac can get tricky when your drawing calls are user generated! In our update routine, we erase the port rectangle and re-draw the graphics by calling ‘theDrawing’ procedure. Note that we really are not erasing the whole window, nor does the whole window get re-drawn! When we call BeginUpdate, the visiRgn of the window is temporarily restricted to the update region so only the update region actually gets erased and re-drawn. After calling EndUpDate, the visiRgn is restored and the update region is left empty. The window manager is doing a lot of work behind the scenes during an update event.

Mouse Down Event

When we have a mousedown event, our event loop calls DealwithMouseDowns and here we find where the mouse event took place by calling FindWindow, and then we use a case statement to deal with each area a mouse can be in. If it is a menu bar click, we call our menu bar routines. If it is a click in a desk accessory or a window not belonging to us, then we call SystemClick, which passes the event on to the desk accessory. For a click in the content region of our window, we call SelectWindow to bring it to the front if it isn’t already. For the drag bar or the goaway box in the window frame, we have toolbox calls that allow us to drag the window or hide the window. Note that we do not close the window, since one of our menu bar routines allows us to show the window and draw in it and that might be a big difficult if we closed the window and released the window record. In fact it would bomb! So HideWindow is sufficient. For a zoom box click, we erase the port rectangle of the window and call ZoomWindow, which generates an update event, so the window contents will be re-drawn. See how important it is that all window drawing be re-producable during an update event? ZoomWindow is a relatively new routine described in Inside Macintosh, volume 4.

Our menu bar is pretty simple since it only has an apple menu and a file menu. Thus desk accessories are not properly supported, since there is no edit menu for them! However, desk accessories can be called if they can be used with just a mouse click. We call GetItem to find the name of the desk accessory, and then pass that name to OpenDeskAcc, which runs the da. To protect ourselves from sloppy da’s, we save our current grafport while the da is running.

If we select our ‘about ’ item in the Apple menu, the about dialog box comes up. One neat thing about the about box (did I really say that?) is it doesn’t have an “OK” Button. It was implemented by enabling the static text in the “R” file. What this means is that the text will be counted as an “ItemHit”. Clicking anywhere in the dialog box will result in closing the about box. Please note however that if you DO use a button, the Stat Text should be “Disabled” so an item hit won’t be reported. Rmaker assumes(theres that word again) that things are “Enabled” unless you tell it otherwise. The static text rectangle is defined to fill the entire about box, use carriage returns “\0D” and be sure that you have not disabled the text. Since Rmaker will enable it by default, when the user clicks you get an itemhit and dump the about box.

How To Make (or steal) Your Own Icon’s

First of all your going to need these programs (Tools).

The Easiest way is to launch ResEdit, then open a “New” window. Call the window anything you like, but don’t use the programs name you got it from, then go to a program and “Open” it.....

OK now open the ICN# resource. “Copy” it, then:

Paste it into your “New” window.

Close the Program you opened.

“Get Info” on your icon and set the ID to what you need, usually 128 for an application or 129 for it’s document. Modify the icon with the pencil to make what you want.

Close and save it.

Quit.

Now launch

Open the icon and choose “Decompile” and be sure to save the file.

Quit.

All Right !! You did it!

You now have one file containing your icon, which can be “Paste" into any Resource file and one file with a “Hard copy” of the Icon which you can use in a Rmaker .R file. Thats how Code Tester’s was done, my particular favorite way of doing it.

Don’t forget to launch Edit first and then the rsrc. doc since the decompiled icon file is not of type EDIT.

That’s all folks, may the mouse be with you.


PROGRAM CodeTester;
(* Version 1.1 *)
(* © CopyRight 1987 by J.E.Fox, for Mactutor™ *)
{I-}
USES
 ROM85, TestGlobals, TestStuff;

PROCEDURE crash;
BEGIN
 ExitToShell;
END;

PROCEDURE DoAbout;
 VAR
 MyAbout : DialogPtr;
 ItemHit : Integer;
BEGIN
 MyAbout := GetNewDialog(AboutId, NIL, Pointer(-1));
 ShowWindow(MyAbout);
 ModalDialog(NIL, ItemHit);
 CASE ItemHit OF
 1 : 
 DisposDialog(MyAbout);
 OTHERWISE
 BEGIN
 END;
 END;  (* Case of *)
END;  (* DoAbout *)

PROCEDURE ProcessMenu_in (CodeWord : longint);
 VAR
 Menu_No : integer;  {menu number selected}
 Item_No : integer;  {item in menu selected}
 Name : Str255;      {name holder for da or font}
 OpenDAResult : integer;
 TempPort : Grafptr; {protect against DA}
BEGIN
 IF CodeWord <> 0 THEN
 BEGIN {go ahead and process the command}
 Menu_No := HiWord(CodeWord); {get Hi word of...}
 Item_no := LoWord(CodeWord); {get Lo word of...}
 CASE Menu_No OF
 AppleMenu : 
 BEGIN
 CASE Item_No OF
 1 : 
 DoAbout;
 OTHERWISE
 BEGIN
 GetItem(AppleMHandle, Item_No, Name);
 GetPort(TempPort);
 OpenDAResult := OpenDeskAcc(Name);
 SetPort(TempPort);
 END;     (* Otherwise *)
 END         (* Case Item_No of *)
 END;        (* apple menu *)
 FileMenu : 
 BEGIN
 CASE Item_No OF
 1 : 
 theTest;
 2 : 
 BEGIN (* The dividing Line *)
 END;
 3 : 
 BEGIN
 SetCursor(Watch);
 Finished := True; (* quit *)
 END;
 END; (* Item_No of (File) *)
 END; (* file menu *)
 END; (* Case Menu_No of *)
 HiliteMenu(0);  (* unhilite after menu *)
 END; (* the If codeword <>0 *)
END; (* of ProcessMenu_in procedure *)

PROCEDURE DealwthMouseDowns (Event : EventRecord);
 VAR
 WindowPointedTo : WindowPtr;
 GlobalMouse, LocalMouse : Point;
 WindoLoc : integer;
 TempPort : GrafPtr;
BEGIN
GlobalMouse := Event.Where;
LocalMouse := GlobalMouse;
GlobalToLocal(LocalMouse);
WindoLoc := FindWindow(GlobalMouse, WindowPointedTo);
CASE WindoLoc OF
 inMenuBar : 
 ProcessMenu_in(MenuSelect(GlobalMouse));
 inSysWindow : 
 SystemClick(Event, WindowPointedTo);
 inContent : 
 BEGIN
 IF WindowPointedTo <> FrontWindow THEN
 BEGIN
 SelectWindow(WindowPointedTo);
 SetPort(WindowPointedTo);
 END;
 END; {InContent}
 inGrow : 
 BEGIN
 END;
 inDrag : 
 BEGIN
 DragWindow(WindowPointedTo, GlobalMouse, DragArea);
 END;
 inGoAway : 
 BEGIN
 IF TrackGoAway(WindowPointedTo, GlobalMouse) THEN
 HideWindow(WindowPointedTo);
 END;
 InZoomIn, InZoomOut : 
 BEGIN
 IF TrackBox(WindowPointedTo, GlobalMouse, WindoLoc) THEN
 BEGIN
 GetPort(TempPort);
 SetPort(WindowPointedTo);
 EraseRect(WindowPointedTo^.portRect);
 ZoomWindow(WindowPointedTo, WindoLoc, True);
 SetPort(TempPort);
 END;
 END;
 OTHERWISE
 BEGIN
 END;
 END;    (* CASE WindoLoc of *)
END;  (* DealwthMouseDowns *)

PROCEDURE DealwthKeyDowns (Event : EventRecord);
 VAR
 CharCode : char;
BEGIN
 CharCode := Chr(Event.message MOD 256);
 IF BitAnd(Event.modifiers, CmdKey) = CmdKey THEN
 ProcessMenu_in(MenuKey(CharCode));
END;

PROCEDURE Activate_DeActivate (Event : EventRecord);
 VAR
 TargetWindow : WindowPtr;
BEGIN
 TargetWindow := WindowPtr(Event.message);
 IF Odd(Event.modifiers) THEN
 BEGIN  (* then the window is becoming active *)
 SetPort(TargetWindow);
 TEActivate(JeffsText);
 END  (* If Odd *)
 ELSE
 BEGIN
 TEDeactivate(JeffsText);
 END;  (* Deactivate *)
END;  (* Activate_DeActivate *)

PROCEDURE DealwthUpdates (Event : EventRecord);
 VAR
 UpDateWindow, TempPort : WindowPtr;
BEGIN
 UpDateWindow := WindowPtr(Event.message);
 GetPort(TempPort);
 SetPort(UpDateWindow);
 BeginUpDate(UpDateWindow);
 EraseRect(UpDateWindow^.portRect);
 MoveHHi(handle(JeffsText));
 HLock(handle(JeffsText));
 TEUpdate(UpdateWindow^.portRect, JeffsText);
 theDrawing;  {update our graphics stuff}
 HUnlock(handle(JeffsText));
 EndUpDate(UpDateWindow);
 SetPort(TempPort);
END;

PROCEDURE MainEventLoop;
 VAR
 Event : EventRecord;
BEGIN
 REPEAT
 SystemTask;
 TEIdle(JeffsText);
 IF GetNextEvent(EveryEvent, Event) THEN
 CASE Event.what OF
 mouseDown : 
 DealwthMouseDowns(Event);
 KeyDown, AutoKey : 
 DealwthKeyDowns(Event);
 ActivateEvt : 
 Activate_DeActivate(Event);
 UpDateEvt : 
 DealwthUpdates(Event);
 OTHERWISE
 BEGIN
 END;
 END;(* of Case *)
 UNTIL Finished;
END;

PROCEDURE PrimeMemory;
BEGIN
 {MaxApplZone;  Grow Heap to Limit }
 MoreMasters;  (* Allot 5, 64 Mptr Blocks *)
 MoreMasters;
 MoreMasters;
 MoreMasters;
 MoreMasters;
END;

PROCEDURE Close;
 BEGIN
 END;

(* ŸŸŸ  Following are called by Set Up  ŸŸŸŸŸ *)

PROCEDURE Energize;
 VAR
 BeamH, WatchH : CursHandle;
BEGIN
 InitGraf(@thePort); (* Set up all Managers *)
 InitFonts;
 InitWindows;
 InitMenus;
 TEInit;
 InitDialogs(@crash);(* crash Proc to ‘Resume’ *)
 InitAllPacks;
 FlushEvents(everyEvent, 0);

 WatchH := GetCursor(watchCursor); {watchs Mptr addr stack}
 HLock(Handle(WatchH)); (* Note the type clash *)
 Watch := WatchH^^;(* DDeref and store *)
 SetCursor(Watch); (* Wrap 10 Mr. Sulu *)
 Finished := False;(* program terminator *)
END;

PROCEDURE SetupMenus;

BEGIN
 AppleMHandle := GetMenu(AppleMenu);
 InsertMenu(AppleMHandle, 0);
 FileMHandle := GetMenu(FileMenu);
 InsertMenu(FileMHandle, 0);
 AddResMenu(AppleMHandle, ‘DRVR’);

 MoveHHI(Handle(AppleMHandle));
 HLock(Handle(AppleMHandle));
 MoveHHI(handle(FileMHandle));
 HLock(Handle(FileMHandle));
 DrawMenuBar;
 END;

PROCEDURE SetupLimits;
BEGIN
 Screen := ScreenBits.Bounds;   {set the size of the screen}
 SetRect(DragArea, Screen.left + 4, Screen.top + 24, Screen.right - 4, 
Screen.bottom - 4);
 SetRect(GrowArea, Screen.left, Screen.top + 24, Screen.right, Screen.bottom);
 SetRect(WindowArea, Screen.left + 10, Screen.Top + 40, Screen.right 
- 200, Screen.bottom - 50);
END;

PROCEDURE SetUpWindow;
 VAR
 title : str255;
BEGIN
 title := ‘Code Tester’;
 JeffsWindow := NewWindow(NIL, WindowArea, title, FALSE, 8, pointer(-1), 
TRUE, 1);
 IF JeffsWindow = NIL THEN
 crash;
 SetPort(JeffsWindow);
 TextFont(applFont);
 TextSize(12);
 TextFace([]);
 TextMode(1);
END;

PROCEDURE SetUpTE;
BEGIN
 WITH JeffsWindow^.portRect DO
 BEGIN
  SetRect(ViewArea, left + 4, top + 4, right - 1, bottom - 1);
 END;
 DestArea := ViewArea;
 JeffsText := TENew(DestArea, ViewArea); 
 { must be done after setPort}
END;

PROCEDURE MainSetUp;
BEGIN
 Energize;
 SetupMenus;
 SetupLimits;
 SetUpWindow;  (* Save Room for windows if used *)
 SetUpTE;
 InitCursor; (* ready to go, show Arrow cursor *)
END;

(* ŸŸŸŸŸŸŸ Main Program ŸŸŸŸŸŸŸ *)

BEGIN
 PrimeMemory;
 MainSetUp;
 MainEventLoop;
 Close;
END.


UNIT TestGlobals;

INTERFACE

 USES
 ROM85;

 CONST
 AppleMenu = 256;(* Resourse ID’s *)
 FileMenu = 257;
 TestItem = 1;
 Quititem = 3;

 AboutId = 260;
 NoteId = 261;
 CautionId = 262;
 StopId = 263;

 DlogH = 100;    (* for SF Get & Put *)
 DlogV = 85;

 UntitledId = 300; (* Strings *)
 Saveit = 301;
 UndoIt = 302;

 VAR
 Finished : Boolean; (* terminate program *)
 Watch : Cursor; (* Cursors *)
 AppleMHandle, FileMHandle : MenuHandle;
 ResStr : Str255;
 ResStrHdl : StringHandle;
 Machine : integer;

 DragArea : Rect;     (* rectangles *)
 GrowArea : Rect;
 Screen : Rect;
 ViewArea, DestArea : Rect;
 WindowArea : Rect;

 JeffsText : TEHandle;
 JeffsWindow : WindowPtr;  (* ptr to window *)

IMPLEMENTATION

END.


UNIT TestStuff;

INTERFACE

 USES
 ROM85, TestGlobals;

 PROCEDURE theTest;
 PROCEDURE theDrawing;

IMPLEMENTATION

PROCEDURE theTest;
 VAR
 str0, str1, str2 : str255;
BEGIN
 str0 := chr(13);
 SysBeep(1);(* for now *)
 ShowWindow(JeffsWindow);
 ForeColor(blackColor);
 str1 := ‘This is a Test!’;
 str2 := ‘Put your test code here ’;
 TESetSelect(0, 0, JeffsText);
  TESetText(pointer(ORD(@str1) + 1), length(str1), JeffsText);
 TEInsert(pointer(ORD(@str0) + 1), 1, JeffsText);
 TEInsert(pointer(ORD(@str2) + 1), length(str2), JeffsText);
 InvalRect(JeffsWindow^.portRect);
END;

PROCEDURE theDrawing;
 VAR
 r : rect;
BEGIN
 PenSize(3, 3);
 PenMode(patCopy);
 PenPat(black);
 ForeColor(redColor);
 BackColor(whiteColor);
 MoveTo(40, 20);
 SetRect(r, 40, 40, 80, 100);
 FrameRect(r);
 OffsetRect(r, 10, 10);
 FrameRect(r);
 ForeColor(blueColor);
 OffsetRect(r, 10, 10);
 FrameRect(r);
 OffsetRect(r, 10, 10);
 FrameRect(r);
 ForeColor(yellowColor);
 SetRect(r, 20, 130, 100, 180);
 FillOval(r, dkGray);
 OffsetRect(r, 15, 15);
 ForeColor(greenColor);
 FillOval(r, gray);
 OffsetRect(r, 15, 15);
 ForeColor(cyanColor);
 FillOval(r, black);
 OffsetRect(r, 15, 15);
 ForeColor(magentaColor);
 FillOval(r, ltGray);
 ForeColor(blackColor);
END;

END.


* Code Tester.R resources
* by Jeff Fox
*
Testor.RSRC
????????

Type COTE = STR 
  ,0    ;;0 by convention
J. E. (JEFF) Fox   Ver. 1.1  8 Feb. 1987 \A9 J.E.Fox .

Type BNDL
  ,128
  COTE  0
  ICN# 1
  0 128  1 129
  FREF 2
  0 128  1 129

Type FREF
  ,128
  APPL  0 ;; local id 0 for icon list
  ,129 
  TEXT 1;;Doc’s File Type, Local id 1 for icon list 
  
* ------ Multifinder --------
 
Type SIZE = GNRL
 ,-1
.I
16384 ;; $4000 = bit 14 set
.L
223232  ;; 250K less 32K =220K (for 250K recomended)
.L
172032  ;; 200K less 32K = 120K (for 200K minimum)

Type ICN# = GNRL
  ,128 (4)  ;; The Appl. Icon
.H
FFFFFFFF C0000003 BFFFFFFD A0000005
A0000005 A0000005 A0000005 A0000005
A0000005 A3FC3FC5 A0402005 A0402005
A0402005 A0402005 A0402005 A0402005
A0403E05 A0402005 A0402005 A0402005
A0402005 A0402005 A0402005 A0403F85
A0000005 A0000005 A0000005 A0000005
A0000005 BFFFFFFD C0000003 FFFFFFFF
*
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF
FFFFFFFF FFFFFFFF FFFFFFFF FFFFFFFF

  ,129      ;; The Doc Icon
.H
0FFFFC00 08000600 08000500 08000480
0FE00440 09000420 090007F0 091F0010
09100010 09100010 091C0010 09100010
08100010 08100010 081F0010 08000010
08007C10 08004010 08004010 08007010
08004010 08004010 08004010 08004010
08000010 08EEBDD0 08000010 08000390
09AE7010 08000010 08000010 0FFFFFF0
*
0FFFFC00 0FFFFE00 0FFFFF00 0FFFFF80
0FFFFFC0 0FFFFFE0 0FFFFFF0 0FFFFFF0
0FFFFFF0 0FFFFFF0 0FFFFFF0 0FFFFFF0
0FFFFFF0 0FFFFFF0 0FFFFFF0 0FFFFFF0
0FFFFFF0 0FFFFFF0 0FFFFFF0 0FFFFFF0
0FFFFFF0 0FFFFFF0 0FFFFFF0 0FFFFFF0
0FFFFFF0 0FFFFFF0 0FFFFFF0 0FFFFFF0
0FFFFFF0 0FFFFFF0 0FFFFFF0 0FFFFFF0

*  ---------- MENUS ------------

Type MENU        
* the apple menu
  ,256
\14
About Code Tester...
(-

Type MENU
* the file menu
  ,257
File
  Run the Test/R
  (-
  Quit/Q

* ---- Dialogs --------
Type DLOG ;; About Box
    ,260 (4);; Purgeable
Mikey Likes it !!;; Title String
60 110 195 430   ;; H,V, Global
Visible  NoGoAway 
3
0
270

* ------ Alerts ------
Type ALRT
   ,261 (4) ;; Note Alert #1 in List
   100 100 200 400
   271
   F764
   
Type ALRT          
   ,262   ;; Caution Alert #2 in List
   100 100 200 400
   272
   F765

Type ALRT     
   ,263   ;; Stop Alert #3 in List
   100 100 200 400
   273
   F765

* ------ Dialog Items --------
Type DITL
    ,270  (4)    ;; AboutBox, Purgeable
1;; # of Items

*1 Static Text Items MUST be DISABLED 
*Other wise mouse clicks reported for Text item.
StatText
2 2 170 410 ;; H,V, Local, Zero ‘D’ not ‘OD’.
Code Test Version 1.1\0D\0D++
For Run Time tests of code\0D\0D++
\A9 1987 by J. E. (Jeff) Fox, for Mactutor™\0D\0D++
    All Rights Reserved

Type DITL
    ,271  (4)    ;; Note Alert
2;; # of Items

*1
BtnItem
12 175 32 270
OK

*2
Stat Disable
50 10 190 390
^0

Type DITL
    ,272 (4);; Caution Alert
3;; # of Items

*1
BtnItem
12 175 32 280
Okay with me

*2
BtnItem
43 175 62 280
Forget it

*3
Stat Disable
50 10 190 390
^0

Type DITL
  ,273  (4) ;; Error, Stop Alert
2;; # of Items

*1
BtnItem
12 175 32 295
EXIT To Finder

*2
Stat Disable
50 10 190 390
^0

*  ---- Strings ----------

Type STR 
  ,300 (4);; For the window, If needed
   UnTitled
  
  ,301 (4)
   Mikey Likes it 
   
  ,302 (4)
   What the &%$$$?
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Luminar 1.0.2 - Powerful, adaptive, conf...
Luminar is the new full-featured image editor that adapts to the way you edit photos. Over 300 essential tools to fix, edit, and enhance your photos with comfort. The future of photo editing is here... Read more
WhatRoute 2.0.10 - Geographically trace...
WhatRoute is designed to find the names of all the routers an IP packet passes through on its way from your Mac to a destination host. It also measures the round-trip time from your Mac to the router... Read more
Slack 2.3.3 - Collaborative communicatio...
Slack is a collaborative communication app that simplifies real-time messaging, archiving, and search for modern working teams. Version 2.3.3: Fixed window zoom jumping back-and-forth OS X 10.9... Read more
Lens Blur 1.4.3 - True out-of-focus boke...
Lens Blur transforms your existing photo into true SLR-quality out-of-focus bokeh effect! Everyone needs a gorgeous personalized background for a social profile, blog, Web/UI design, presentation, or... Read more
CleanMyMac 3.6.0 - $39.95
CleanMyMac makes space for the things you love. Sporting a range of ingenious new features, CleanMyMac lets you safely and intelligently scan and clean your entire system, delete large, unused files... Read more
DEVONthink Pro 2.9.8 - Knowledge base, i...
DEVONthink Pro is your essential assistant for today's world, where almost everything is digital. From shopping receipts to important research papers, your life often fills your hard drive in the... Read more
MacFamilyTree 8.1 - Create and explore y...
MacFamilyTree gives genealogy a facelift: modern, interactive, convenient and fast. Explore your family tree and your family history in a way generations of chroniclers before you would have loved.... Read more
HoudahSpot 4.2.7 - Advanced file-search...
HoudahSpot is a powerful file search tool. Use HoudahSpot to locate hard-to-find files and keep frequently used files within reach. HoudahSpot will immediately feel familiar. It works just the way... Read more
TunnelBear 3.0.7 - Subscription-based pr...
TunnelBear is a subscription-based virtual private network (VPN) service and companion app, enabling you to browse the internet privately and securely. Features Browse privately - Secure your data... Read more
Garmin Express 4.5.0.0 - Manage your Gar...
Garmin Express is your essential tool for managing your Garmin devices. Update maps, golf courses and device software. You can even register your device. Update maps Update software Register your... Read more

Latest Forum Discussions

See All

Telltale Games really is working on a Gu...
Telltale Games' next episodic adventure is indeed Guardians of the Galaxy. A document tied to the voice actors strike suggested that the project was in the work, but now we have direct confirmation following an announcement at the Game Awards that... | Read more »
Amateur Surgeon returns to iOS and Andro...
Amateur Surgeon and its two sequels disappeared from the App Store some time and it was sad days for all. But now, just in time for the holidays, the Adult Swim favorite makes its joyous return in the shape of Amateur Surgeon 4, a remake with... | Read more »
The best board games on mobile
Sometimes you need to ditch all of the high speed, high action games in favor of something a little more traditional. If you don't feel like parting ways from your mobile device, though, there are still plenty of ways to get that old-school fix.... | Read more »
The best Facebook Messenger Instant Game...
Facebook's new Instant Games is now here, meaning you can play games with your friends directly via Facebook. It's a fun new way to connect with friends, of course, but it's also proving to be a solid gaming experience in its own right, with a... | Read more »
You can now play game's on Facebook...
Facebook launched its new Instant Games platform in an exciting new attempt to engage its user base. As a result, you can now play a number of different games directly through Facebook Messenger. All of these games run with HTML5, meaning you play... | Read more »
Apollo Justice Ace Attorney (Games)
Apollo Justice Ace Attorney 1.00.00 Device: iOS Universal Category: Games Price: $.99, Version: 1.00.00 (iTunes) Description: Court Is Back In Session Star as rookie defense attorney, Apollo Justice, as he visits crime scenes,... | Read more »
KORG iWAVESTATION (Music)
KORG iWAVESTATION 1.0 Device: iOS Universal Category: Music Price: $19.99, Version: 1.0 (iTunes) Description: A revolutionary new world of sound.The Wave Sequence Synthesizer for iPad - KORG iWAVESTATION | Read more »
Don't Grind Guide: Tips for becomin...
Don’t Grind is a surprising, derpy little one touch game with fun hand-drawn graphics. The goal is simple -- get the high score without being chopped to bits. That can be tough when you’re not used to the game, and that’s compounded by the fact... | Read more »
The top 4 Final Fantasy games on mobile
Final Fantasy XV is out today, and to celebrate we’re breaking down the best Final Fantasy games on mobile. Porting a game to mobile is always tricky business, but many of the early Final Fantasy games have made the transition quite well. Let’s... | Read more »
Swap Sword (Games)
Swap Sword 1.0 Device: iOS Universal Category: Games Price: $2.99, Version: 1.0 (iTunes) Description: | Read more »

Price Scanner via MacPrices.net

Parallels Toolbox 1.3 for Mac Offers 25 Singl...
Parallels has launched Parallels Toolbox 1.3 for Mac, an upgrade that adds five new utilities to the stand-alone application which was released in August and is available exclusively online at http... Read more
OWC Mercury Elite Pro Dual mini Ultra-Portabl...
OWC has introduced the new OWC Mercury Elite Pro Dual mini, a powerful yet ultra-portable dual-drive RAID solution. The new Mercury Elite Pro Dual mini packs phenomenal performance into a small... Read more
Clearance 13-inch Retina MacBook Pros availab...
B&H Photo has clearance 2015 13″ Retina Apple MacBook Pros available for up to $200 off original MSRP. Shipping is free, and B&H charges NY tax only: - 13″ 2.7GHz/128GB Retina MacBook Pro: $... Read more
Roundup of 2016 13-inch 2.0GHz MacBook Pro sa...
B&H has the non-Touch Bar 13″ MacBook Pros in stock today for $50-$100 off MSRP. Shipping is free, and B&H charges NY sales tax only: - 13″ 2.0GHz MacBook Pro Space Gray (MLL42LL/A): $1449 $... Read more
New 13-inch 2.0GHz Space Gray MacBook Pro in...
Adorama has the new 13″ 2.0GHz Space Gray MacBook Pro (non-Touch Bar, MLL42LL/A) in stock for $1499 including a free 3-year AppleCare Protection Plan. Shipping is free, and Adorama charges sales tax... Read more
Finnair Adopts iOS Enterprise iPad Apps from...
Finnair and IBM have announced a first-of-its-kind agreement to utilize iOS enterprise apps from IBM to support the airline’s overall digital transformation. Finnair is focused on Asia-Europe traffic... Read more
Tech21 Launches Evo Go iPhone 7 Case Availabl...
Tech21 has announced the launch of the Evo Go case for Apple iPhone 7 and iPhone 7 Plus, exclusively at T-Mobile. Available online and at participating T-Mobile stores nationwide, Evo Go cases start... Read more
Apple Turns (RED) with More Ways to Join the...
In recognition of World AIDS Day, Apple is offering more ways than ever for customers to join (RED) in its mission to create an AIDS-free generation. Apple is the worlds largest corporate contributor... Read more
Deals on new 15-inch Touch Bar MacBook Pros,...
B&H Photo has new 2016 Apple 15″ Touch Bar MacBook Pro models in stock today with some available for $50 off MSRP, each including free shipping plus NY sales tax only: - 15″ 2.7GHz Touch Bar... Read more
12-inch Retina MacBooks on sale for up to $10...
12-inch Retina MacBooks remain on sale at B&H Photo with models available for up to $100 off MSRP. Shipping is free, and B&H charges NY sales tax only. B&H will also include a free copy... Read more

Jobs Board

*Apple* & PC Desktop Support Technician...
Apple & PC Desktop Support Technician job in Dallas TX Introduction: We have immediate job openings for several Desktop Support Technicians with one of our most Read more
*Apple* &Amp Pc Desktop Support Technici...
Apple & PC Desktop Support Technician job in Monroe, CT Introduction: We have immediate job openings for several Desktop Support Technicians with one of our most Read more
*Apple* Retail - Multiple Positions, Fort Wo...
Job Description:SalesSpecialist - Retail Customer Service and SalesTransform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Retail - Multiple Positions- Greenvi...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
US- *Apple* Store Leader Program - Apple (Un...
…Summary Learn and grow as you explore the art of leadership at the Apple Store. You'll master our retail business inside and out through training, hands-on Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.