TweetFollow Us on Twitter

PICT to RMaker
Volume Number:3
Issue Number:5
Column Tag:Toolbox Techniques

PICT to RMaker Source in MacForth

ArticleSubhead

By Larry Tannenbaum, Long Beach, CA

This program illustrates calling traps, using dialog boxes, the desk scrap, and the memory manager from MacFORTH. It takes a picture from the clipboard and converts it to RMaker resource format. The converted picture is put back into the desk scrap, so you can paste it into your resource file, using MockWrite or other editor.

Dialog boxes make programs more Mac-like and more "attractive", but they can be a bit tricky in MacFORTH. The reason is that the MacFORTH window always executes an ABORT when it is activated, and it is always activated when the dialog box is erased, if it was active before the dialog was drawn (To see what else is done when the MacFORTH window is activated, try SYS.WINDOW +ON.ACTIVATE W@. Use the forth decompiler from MacTutor Vol 1,#2 to decompile this token). For example, you start your program that calls a modal dialog box by typing the highest-level word in the MacFORTH window. When the dialog box is drawn in front, the MacFORTH window is de-activated. When the dialog is disposed of, the MacFORTH window is automatically activated and your program is aborted. This program works because all processing is done, before the dialog box is disposed of.

A couple of words in the program are from Thinking Forth:

: \  >IN @ 3C0 AND C/L + >IN ! ;  IMMEDIATE  (skips rest of line)
: ASCII  BL WORD 1+ C@ COMPILING IF [COMPILE] LITERAL THEN ;

IMMEDIATE  (leaves ascii value of following character on stack, or compiles 
it as a literal if used within a definition)

I also used one naming convention from Thinking Forth. Word names starting with "/" imply "bytes per", so /Row means bytes per row. I also tried to use descriptive names and ample comments. Forth can be hard to decipher, but doesn't have to be.

MacFORTH provides several pre-defined words for defining your own trap-calling words. What they do is compile machine code into your definitions that formats the stack for you, such as converting items that are supposed to be integers from the 32 bits that MacFORTH uses for everything, to 16 bits, or taking all of the arguments off the stack, reserving space for a returned result, then putting the arguments back on the stack. They also compile the trap code into the word.

Fig. 1 Pict to RMaker source Dialog Box

These pre-defined words are listed in table 1 along with the argument patterns they work for. Since the "FUNC" words must reserve space on the stack for a returned value underneath the arguments, they are for very specific cases only; the "MT" words are more general. For example, W>MT may be used with a trap that needs one 16-bit item on top of any number of 32-bit items, but W>FUNC>L must be used with a trap that takes one 16-bit argument only. If the trap you want to use doesn't fit any of these patterns, you must format the stack yourself and use MT for your definition.

Blocks 1 to 4 contain examples of calling traps from MacFORTH. The word WAdj, in Block 1, converts 32-bit items to 16 bits; it adds 2 to the stack pointer, essentially chopping off the two most significant bytes of the top stack item. I couldn't get OPEN.RSRC, supplied by MacFORTH 1.2 K2.3, to work, so I defined my own word, OpenRFile, to do the job. The 2nd line of code in block 2 is executed while the file is loading. It takes the name of the loading file as the resource file name. This way, if you rename the file, the resource fork will be opened properly without changing the code.

How do you get resources into a block's file? First, compile the resources with RMaker. The type and creator of the output file should be BLKS M4TH. Go to MacFORTH and open the new resource file with OPEN" rfilename". You have just opened the empty data fork of the file. Append enough blocks to it to hold the program (APPEND.BLOCKS). Either type in the program, or use XFER.BLOCKS (block 12 of Forth Blocks) to transfer it from another block's file. It's easier to use separate resource and blocks files, when developing a program. Finally, change the name of your completed file, because RMaker will delete it, if you recompile the resources.

I decided to use the desk scrap for the input and output of this program so that I could paste the picture resource into the middle of an existing file. It's also easy to select a portion of a picture with Paint Grabber or similar desk accessory and retrieve it from the desk scrap using GET.SCRAP.

Table 1: MacForth trap calling defining words

GET.SCRAP copies the scrap data to a handle that you pass to it. The handle is automatically sized, so it can be any length, including zero. You must also specify the type of data you are looking for. The most common types are text and pictures. Use the constant "TEXT or "PICT to designate the type you want. If the data in the scrap is different from the type you asked for, error code -102 is returned. An error code of zero indicates no error.

PUT.SCRAP works similarly. Give it the address and length of the data, and the data type. It will copy your data to the end of the desk scrap and return a result code.

ZERO.SCRAP deletes all data in the desk scrap and sets the scrap length to zero. You must execute ZERO.SCRAP before the first time you execute PUT.SCRAP, and before putting data into the scrap of the same type that is already there. This last restriction is necessary because GET.SCRAP always returns the first block of data of the type requested. If more than one chunk of data of a particular type is in the scrap, only the first one that was written is accessible.

Two other words help conserve memory: LOAD.SCRAP and UNLOAD.SCRAP. UNLOAD.SCRAP writes the desk scrap to the clipboard file on disk, releasing the memory used by the scrap. LOAD.SCRAP "knows" whether the scrap data is on disk or not and reads it into memory, if necessary. GET.SCRAP apparently will not get the data from the disk, even though Inside Macintosh says it will, so call LOAD.SCRAP first, if there is the possibility of it being in the clipboard file.

SCRAP.HANDLE returns the address where the handle to the desk scrap is stored. SCRAP.COUNTER returns the number of times the scrap has been zeroed since system start-up. According to Inside Macintosh, you can check to see if this value has changed during the operation of a desk accessory. If so, the accessory has probably put some data into the scrap.

SCRAP.LEN returns the address containing the length of the scrap data. This length includes 8 bytes for the scrap header. Sometimes the scrap is 8 bytes longer than the picture length, and sometimes it is 9 bytes longer. I suspect this has to do with whether the picture size is odd or even. The program needs the length of the picture. The easiest way to get it is from the first two bytes of the picture itself, so I don't use SCRAP.LEN. Block 8 contains the definitions using the scrap interface words.

Block 5 holds the memory manager interface definitions. Many programs in MacTutor have dealt with getting, releasing, resizing, locking, and unlocking handles, so I won't go into detail. The MacFORTH words that do these things have explicit names, except maybe FROM.HEAP, which gets a handle, and TO.HEAP, which releases one.

The program uses only one handle. GET.SCRAP copies the picture into it, then the handle is resized to hold the ascii. To avoid overwriting the data, the program starts converting from the end of the picture.

Blocks 9 and 10 contain the code that actually does the conversion. The constant /Row, in block 9, determines how many bytes of the picture are represented on each row of text. It can be changed to any convenient value.

Using this program, you can personalize your dialog and alert boxes, and keep the pictures in your source, rather than having to paste them in after compilation with ResEdit. The output format could also be changed to MDS or MacASM.

( Block 0    ***********Instructions*********** )

To use this program:
    1.  Cut or copy picture to be used as resource so it will
        be in the ClipBoard.
    2.  Load this file.
    3.  Execute Pict>Rsrc. The PICT in the clipboard
        will be converted to type TEXT in RMaker hex format.
    4.  Using MockWrite or other editor, paste the data from
        the clipboard into the RMaker file.

( Block #1   ***********Toolbox interface***********)

HEX

Create WAdj -2 Allot 548F { ADDQ.L #2,SP} W, 4ED4 W,

A997 L>FUNC>W <OpenRFile>        A99A W>MT <CloseRFile>
A97C MT <GetNewDlog>             A983 MT <DisposDlog>
A98D MT <GetDItem>               A991 MT <ModalDlog>
A990 MT <GetIText>               A98F MT <SetIText>
A95F MT <SetCTitle>              A95D W>MT <HiliteControl>
A987 MT <NoteAlert>

DECIMAL
    2 11 Thru

( Block #2   ******ToolBox InterfaceVariables*********)

Create   RFileName    30 Allot \ same name as this file
Block-File @ @File.Name    Dup C@ 1+ RFileName Swap CMove
Variable RFileRefNum           \ returned by OpenRFile
Variable DlogPtr               \ returned by GetNewDlog
Create   ItemHit 2 Allot       \ returned by ModalDlog
Create   ItemType 2 Allot      \ returned by GetDItem
Variable ItemHandle            \ returned by GetDItem
Create   ItemRect 8 Allot      \ returned by GetDItem
Create   Item$ 30 Allot        \ for manipulating text items
Create   Ok$ ," Done"          \ new title for control
1 Constant ConvertButton       \ compared to ItemHit when
                               \ ModalDlog returns

( Block #3    ***********Resource File/Alert***********)

: OpenRFile    RFileName <OpenRFile> Dup 0>
    If   RFileRefNum !
    Else Abort" Couldn't open resource file!" Then ;
: CloseRFile   RFileRefNum @ <CloseRFile> ;
: NoPictAlert  128 WAdj ( id) 0 ( filter proc) <NoteAlert> ;

( Block #4    ***********Dialog Interface***********)

: GetDlog    0 ( reserve stack space for returned dptr)
    128 WAdj ( id) 0 ( on heap) -1 ( in front)
    <GetNewDlog>    DlogPtr ! ;
: DisposeDlog  DlogPtr @ <DisposDlog> ;
: ModalDlog    0 ( filter proc) ItemHit <ModalDlog> ;
: GetDItem    ( item#)    DlogPtr @ Swap WAdj
    ItemType  ItemHandle ItemRect <GetDItem> ;
: GetIHandle  ( item#--handle)    GetDItem ItemHandle @ ;
: GetIText    ( $\item#)    GetIHandle Swap <GetIText> ;
: SetIText    ( item#)    GetIHandle Item$ <SetIText> ;
: Ok>Done  1  ( item#) GetIHandle Ok$ <SetCTitle> ;
: Can'tCancel 2 ( item#) GetIHandle 255 <HiliteControl> ;

( Block #5    ***********Memory Manager***********)

Variable DataH    \ holds handle to data

: GetH ( size--handle)    From.Heap Dup DataH ! Dup 0=
    If DisposeDlog CloseRFile
        1 Abort" Handle Allocation Error!" Then ;
: DataPtr ( --ad of data)    DataH @@ Mask.Handle ;
: /Data ( --data size in bytes)    DataH @ Handle.Size ;
: ResizeH ( new size--)    DataH @ Dup Rot Resize.Handle
        0< If   DisposeDlog CloseRFile
            1 Abort" Handle Resize Error!"
        Else Lock.Handle Then ;
: ReleaseH
   /Data 0< Not If DataH @ Dup Unlock.Handle To.Heap Then ;

( Block #6    ***********PICT Resource Header***********)

13 Constant CRet    \ ascii for carriage return
: AddCR ( ad--)     Count 1- +    CRet Swap C! ;
\ Asterisk in string is place holder for carriage return
Create Type$ ," TYPE PICT = GNRL*"  Type$ AddCR
Create Hex$  ," .H*"                Hex$  AddCR
Create Name$ 25 Allot
Create ID#$  10 Allot
: /Header ( --n)    Type$ C@ Hex$ C@ Name$ C@ ID#$ C@ + + + ;
: (Header>Text) ( ptr\$--updated ptr)
    Count >R Over R@ CMove R> + ;
: !Header    DataPtr            Type$ (Header>Text)
             Name$ (Header>Text) Id#$  (Header>Text)
             Hex$  (Header>Text) Drop ;

( Block #7    ***********Get/Set Dialog Items***********)

: Num>Str ( n)       <# #S #> Item$ 2Dup C!    1+ Swap Cmove ;
: AddChar ( $\char)  Over Count + C!    Dup C@ 1+ Swap C! ;
: SetPictSize        DataPtr W@ Num>Str 9 SetIText ;
: SetPictWidth
    DataPtr Dup 8+ W@ Swap 4+ W@ - Num>Str 11 SetIText ;
: SetPictHeight
    DataPtr Dup 6+ W@ Swap 2+ W@ - Num>Str 13 SetIText ;
: GetPictName    Name$ Dup 5 GetIText Ascii , AddChar ;
: GetPictID#     ID#$ Dup 7 GetIText CRet AddChar ;
: GetHeader      GetPictName    GetPictID# ;
: SetUpDlog
    GetDlog SetPictSize SetPictWidth SetPictHeight ModalDlog ;
: DoneDlog       Ok>Done Can'tCancel ModalDlog ;

( Block #8    ***********Desk Scrap Interface***********)

: ScrapErr? ( result code--)
    0< IF ReleaseH DisposeDlog CloseRfile
          1 Abort" Scrap Error!" Then ;
: /Pict ( --bytes)
    Scrap.Handle @ Dup 0< If Drop 0 Else @ 4+ @ Then ;
: PictFromScrap ( --result code)   Load.Scrap ScrapErr?
    /Pict GetH    "PICT Get.Scrap ;
: Text>Scrap    Zero.Scrap ScrapErr?
    DataPtr /Data "TEXT Put.Scrap ScrapErr?
    ReleaseH    Unload.Scrap ScrapErr? ;

( Block #9    ***********Picture conversion***********)

16 Constant /Row   \ 1 row of text represents 16 bytes of pict
: #CR'S ( pict size--# of CR's in text )
    /Row W/Mod Swap If 1+ Then ;
: /Text ( --text size) /Pict Dup 2* Swap #CR'S + /Header + ;
: PictEnd ( --ad)    DataPtr /Pict + 1- ;
: TextEnd ( --ad)    DataPtr /Text + 1- ;
    Create Char$ ," 123456789ABCDEF"    Ascii 0 Char$ C!
:  >Ascii ( nybble--char)    Char$ + C@ ;
: !Byte  ( ad\byte--new ad)    Dup>R 15 And >Ascii Over C! 1-
                               R> 16/    >Ascii Over C! 1- ;
: !Cr    ( ad--new ad)    CRet Over C! 1- ;

( Block #10   ***********Picture conversion***********)

Variable PictAd

: RowLimits ( #bytes--limit\index)
    PictAd @ Dup Rot - Dup PictAd ! 1+ Swap ;
: !Row    ( dest ad\#bytes--new dest ad)
    RowLimits Do IC@ !Byte -1 +Loop ;
: !Pict    PictEnd PictAd !    TextEnd
    1 /Pict Do !Cr   I /Row Min !Row  /Row Negate +Loop Drop ;
: Pict>Text    Watch Set.Cursor  GetHeader
        /Text ResizeH    !Pict !Header   Init.Cursor ;

( Block #11    ***********User Interface***********)

: Convert?    ItemHit W@ ConvertButton = If
    Pict>Text Text>Scrap DoneDlog Then ;
: ConvertPict    SetUpDlog Convert? DisposeDlog ;
: Pict>Rsrc      OpenRFile PictFromScrap
    0< If   NoPictAlert
       Else ConvertPict
       Then CloseRFile ;
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Monosnap 3.4.0 - Versatile screenshot ut...
Monosnap lets you capture screenshots, share files, and record video and .gifs! Capture Capture full screen, just part of the screen, or a selected window Make your crop area pixel perfect with our... Read more
Tweetbot 2.5.3 - Popular Twitter client.
Tweetbot is a full-featured OS X Twitter client with a lot of personality. Whether it's the meticulously-crafted interface, sounds and animation, or features like multiple timelines and column views... Read more
Default Folder X 5.1.6 - Enhances Open a...
Default Folder X attaches a toolbar to the right side of the Open and Save dialogs in any OS X-native application. The toolbar gives you fast access to various folders and commands. You just click on... Read more
Evernote 6.12.3 - Create searchable note...
Evernote allows you to easily capture information in any environment using whatever device or platform you find most convenient, and makes this information accessible and searchable at anytime, from... Read more
Geekbench 4.1.2 - Measure processor and...
Geekbench provides a comprehensive set of benchmarks engineered to quickly and accurately measure processor and memory performance. Designed to make benchmarks easy to run and easy to understand,... Read more
Carbon Copy Cloner 5.0.2 - Easy-to-use b...
Carbon Copy Cloner backups are better than ordinary backups. Suppose the unthinkable happens while you're under deadline to finish a project: your Mac is unresponsive and all you hear is an ominous,... Read more
BetterTouchTool 2.305 - Customize multi-...
BetterTouchTool adds many new, fully customizable gestures to the Magic Mouse, Multi-Touch MacBook trackpad, and Magic Trackpad. These gestures are customizable: Magic Mouse: Pinch in / out (zoom... Read more
calibre 3.8.0 - Complete e-book library...
Calibre is a complete e-book library manager. Organize your collection, convert your books to multiple formats, and sync with all of your devices. Let Calibre be your multi-tasking digital librarian... Read more
BetterTouchTool 2.305 - Customize multi-...
BetterTouchTool adds many new, fully customizable gestures to the Magic Mouse, Multi-Touch MacBook trackpad, and Magic Trackpad. These gestures are customizable: Magic Mouse: Pinch in / out (zoom... Read more
calibre 3.8.0 - Complete e-book library...
Calibre is a complete e-book library manager. Organize your collection, convert your books to multiple formats, and sync with all of your devices. Let Calibre be your multi-tasking digital librarian... Read more

The best new games we played this week -...
It's pretty much been one big release after another. We were privy to a bunch of surprises this week, with a lot of games we'd been waiting for quite some time dropping unexpectedly. We hope you're free this weekend, because there is a lot for... | Read more »
Stormbound: Kingdom Wars guide - how to...
Stormbound: Kingdom Wars is an excellent new RTS turned card battler out now on iOS and Android. Lovers of strategy will get a lot of enjoyment out of Stormbound's chess-like mechanics, and it's cardbased units are perfect for anyone who loves the... | Read more »
The best AR apps and games on iOS right...
iOS 11 has officially launched, and with it comes Apple's ARKit, a helpful framework that makes it easier than ever for developers to create mobile AR experiences. To celebrate the occassion, we're featuring some of the best AR apps and games on... | Read more »
Phoenix Wright: Ace Attorney - Spirit of...
Phoenix Wright: Ace Attorney - Spirit of Justice 1.00.00 Device: iOS Universal Category: Games Price: $.99, Version: 1.00.00 (iTunes) Description: ************************************************※IMPORTANT※・Please read the “When... | Read more »
Kpressor (Utilities)
Kpressor 1.0.0 Device: iOS Universal Category: Utilities Price: $4.99, Version: 1.0.0 (iTunes) Description: The ultimate ZIP compression application for iPhone and iPad. - Full integration of iOS 11 with support for multitasking.-... | Read more »
Find out how you can save £35 and win a...
Nothing raises excitement like a good competition, and we’re thrilled to announce our latest contest. We’ll be sending one lucky reader and a friend to the Summoners War World Arena Championship at Le Comedia in Paris on October 7th. It’s the... | Read more »
Another Lost Phone: Laura's Story...
Another Lost Phone: Laura's Story 1.0 Device: iOS Universal Category: Games Price: $2.99, Version: 1.0 (iTunes) Description: Another Lost Phone is a game about exploring the social life of a young woman whose phone you have just... | Read more »
The Witness (Games)
The Witness 1.0 Device: iOS Universal Category: Games Price: $9.99, Version: 1.0 (iTunes) Description: You wake up, alone, on a strange island full of puzzles that will challenge and surprise you. You don't remember who you are, and... | Read more »
Egg, Inc. guide - how to build your gold...
Egg, Inc.'s been around for some time now, but don't you believe for one second that this quirky clicker game has gone out of style. The game keeps popping up on Reddit and other community forums thanks to the outlandish gameplay (plus, the... | Read more »
The best deals on the App Store this wee...
Good news, everyone! Your favorite day of the week has arrived at last -- it's discount roundup day! This fine Wednesday evening we're gathering up the hottest deals on the App Store. We've got action platformers, we've got puzzle games, we've got... | Read more »

Price Scanner via MacPrices.net

Looking for a 2017 12″ Retina MacBook? Save $...
Apple has Certified Refurbished 2017 12″ Retina MacBooks available for $200-$240 off the cost of new models. Apple will include a standard one-year warranty with each MacBook, and shipping is free.... Read more
Apple Offering Up To $455 Credit Toward iPhon...
iPhone 8 and 8 Plus are now available at the Apple Store, and you can receive up to $375 credit toward a new iPhone purchase when you trade in your eligible smartphone. Photo Courtesy Apple Just... Read more
AnyTrans Offers iOS Users Three Ways For Movi...
iMobie Inc. today announceed AnyTrans v6.0.1, which now can help iOS users move all data to iPhone 8/8 Plus seamlessly. The software is available both on Mac and Windows and fully able to move all... Read more
Snag a 13-inch 2.3GHz MacBook Pro for $100 of...
B&H Photo has 2017 13″ 2.3GHz MacBook Pros in stock today and on sale for $100 off MSRP, each including free shipping plus NY & NJ sales tax only: – 13-inch 2.3GHz/128GB Space Gray MacBook... Read more
Verizon offers new iPhone 8 for $100-$300 off...
Verizon is offering the new iPhone 8 for up to $300 off MSRP with an eligible trade-in: • $300 off: iPhone 6S/6S Plus/7/7 Plus, Google Pixel XL, LG G6, Moto Z2 Force, Samsung Galaxy S7/S7 edge/S8/S8... Read more
Apple Refurbished 2017 13-inch MacBook Pros a...
Apple has Certified Refurbished 2017 13″ Touch Bar MacBook Pros in stock today and available for $200-$300 off MSRP. A standard Apple one-year warranty is included with each MacBook, and shipping is... Read more
OWC USB-C Travel Dock with 5 Ports Connectivi...
OWC have announced the new OWC USB-C Travel Dock, the latest addition to their line of connectivity solutions. The USB-C Travel Dock lets you connect its integrated USB-C cable to a Mac or PC laptop... Read more
Pelican Products, Inc. Unveils Cases For All...
Pelican Products, Inc. has announced the launch of its full line of cases including Voyager, Adventurer, Protector, Ambassador, Interceptor (for the Apple iPhone 8 and 8 Plus backwards compatible... Read more
$100 off new 2017 13-inch MacBook Airs
B&H Photo has 2017 13″ MacBook Airs on sale today for $100 off MSRP including free shipping. B&H charges NY & NJ sales tax only: – 13″ 1.8GHz/128GB MacBook Air (MQD32LL/A): $899, $100 off... Read more
Apple restocks Certified Refurbished 13-inch...
Apple has Certified Refurbished 2015 13″ MacBook Airs available starting at $719 and 2016 models available starting at $809. An Apple one-year warranty is included with each MacBook, and shipping is... Read more

Jobs Board

*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Development Operations and Site Reliability E...
Development Operations and Site Reliability Engineer, Apple Payment Gateway Job Number: 57572631 Santa Clara Valley, California, United States Posted: Jul. 27, 2017 Read more
Specialist - Retail Customer Services and Sal...
The position listed below is not with Tennessee Interviews but with Apple , Inc. Tennessee Interviews is a private organization that works in collaboration with Read more
Specialist - Retail Customer Services and Sal...
The position listed below is not with South Carolina Interviews but with Apple , Inc. South Carolina Interviews is a private organization that works in collaboration Read more
Behavior Technician with *Apple* Consulting...
The position listed below is not with Washington Interviews but with APPLE CONSULTING Washington Interviews is a private organization that works in collaboration Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.