Simple Graphics Objects

By Andrew Shalit, Cambridge, MA

Graphics Objects in MacScheme

Welcome back to Lisp Listener! Our current choice of Lisp implementations is MacScheme by Semantic Microsystems. Scheme is a modern and elegant dialect of Lisp, and MacScheme is a robust, complete, and elegant implementation. Previously MacScheme did not offer pro-grammers much access to the Macintosh toolbox. In August a new release of a product called MacScheme + Toolsmith, was made which allows the production of event-driven programs. This will be followed shortly by an application builder that will make it possible to create stand-alone applications with MacScheme. The MacScheme editor, which is currently fairly limited, is also in the process of being upgraded. Look for reviews of all these items in future columns.

The only way to get to the toolbox in the previous incar-nation of MacScheme, version 1.11, was through an escape into machine language that looks very complicated (I haven't tried it out). Version 1.11 does, though, have some simple graphics capabilities which we will be using in this month's column. As it stands now, MacScheme is a great way to learn Lisp and explore object oriented programming.

Graphics in MacScheme

In early 1986, MacScheme was enhanced to allow the use of simple graphics operations. MacScheme has one graphics window, which must be opened with a procedure call before graphics can be used. The graphics window can be two sizes, 'full' or 'half'. To open up a small graphics window, the code would be:

 (start-graphics 'half)

Once a graphics window is open, you can get rid of it by saying:

 (end-graphics)

(One thing to be careful of: you aren't allowed to 'start-graphics' if the graphics window is already there, and you aren't allowed to end them if it isn't there. Moreover, there is currently no way for a procedure to test whether the graphics window is open. Hopefully Semantic Microsystems will add this test feature soon, or just allow you to open the window even if it already open, or close it if it is closed.)

Once the graphics window is open, there are just under 30 commands for drawing in it. These are all pretty basic: drawing, erasing, and inverting lines, rectangles, ovals, circles and points. You can also set up a picture that will be refreshed if the graphics window is obscured, draw a string, and clear the window.

For Macintosh programmers, MacScheme graphics take a little readjusting. This is because MacScheme uses the coordinate system that you learned in grade school, instead of the one you learned in Inside Macintosh. That's right, the x coordinate comes first, followed by the y coordinate. The half size graphics window is 470x130 pixels, so the procedure call

 (paint-oval 20 95 50 125)

would paint a circle in the lower left hand corner of the graphics window.

The general form of graphics procedures that work with two points is

(procedure  x1 y1 x2 y2)

Data Abstraction

This brings us to the first programming issue of the column: data abstraction. As you can imagine, it would be awkward working with rectangles and points if you always had to think about them in terms of their individual coordinates. One of the strong points of Lisp is its ability to create complex data objects. So, before I did anything with graphics, I created a set of procedures for working with points and rectangles. The simplest way to work with a rectangle is to set it up as a list of four coordinates. The coordinates can then be passed to a MacScheme graphics procedure by saying

 (apply the-procedure the-list )

In the sample procedures shown here, I use a slightly more complex data structure because it makes the issue of data abstraction stand out more clearly.

As I have defined them, a point is a simple pair, and a rectangle is a list of points. But the particular internal structure of a point or a rectangle is unimportant to most of the procedures I will write. When I want to work with a point or rectangle, I always do so with the selectors and constructors that I have created. I use a constructor to create a rectangle or point, and I use a selector to get information about a rectangle or point. The selectors and constructors are the only parts of the system that need to know what the internals of the data structure look like. Once you have a complete set of selectors and constructors, you can forget about the underlying structures which the selectors and constructors use to work with the data. This technique is called data-abstraction, and is very useful for keeping programs as simple as possible. For example, the procedure adds-points knows nothing about points besides the fact that they have an x and a y coordinate. If I change the way I store points, I need only modify the selectors and constructors; the rest of the program remains the same.

Now that we have a way of storing points and rectangles, we need a way of passing rectangles to Scheme graphics procedures. Because a rectangle is defined by two points (as all Macintosh programmers know), we can use the rectangle data form for any procedure that requires two points (i.e. four coordinates) as arguments. The result is the procedure 2-point-function. This procedure takes two arguments, a graphics procedure and a rectangle, and it calls the graphics procedure, giving it the coordinates from the rectangle as arguments. 2-point-function also illustrates the ease with which procedures can be passed as arguments in Lisp.

An additional feature of Lisp should be clear by now: Lisp programs are not constructed as single units, as are programs in other languages. Rather, procedures are defined, thereby adding to the procedures which come already defined in the language. A Lisp program is little more than the interaction of a number of procedures. The result is an extensible working environment, similar to that found in Forth.

Object oriented Programming

The next feature of Lisp we will discuss is the ease with which procedures can return other procedures. Every procedure in Lisp, when evaluated, returns something. For example, (+ 4 3) returns 7, and (car '(a b c)) returns a. In Lisp it is very easy to have a procedure return another procedure as its result. Here is a simple (though fairly useless) example, a procedure which churns out procedures to add a constant to a number.

(define (make-adder the-constant)
 (lambda (the-input-variable)
 (+the-constant
 the-input-variable)))
 

The procedure make-adder returns a procedure (a lambda expression) which takes a single argument, the-input-variable. If we say,

(set! addfive (make-adder 5))

we have a new procedure, called addfive, which will add 5 to any number it is given as an argument.

One of the most powerful features of Scheme is that it is lexically scoped. This means that variables within a procedure are scoped according to the environment in which the procedure is defined (as opposed to dynamic scoping, in which variables are scoped according to the environment from which the procedure is called ). In the example given above, the procedure addfive works because the variable 'the-constant' is scoped according to the environment in which addfive was defined. When addfive was defined, the-constant was equal to 5. As far as addfive is concerned, the-constant will always be 5, even if we call make-adder again and again, giving it a different number each time, and even if we call addfive from another procedure that has a variable called 'the-constant' with a different value.

When you put together lexical scoping and procedures returning procedures, you get the ability to do object oriented programming. In case you don't know it as more than a buzz-word, here's a brief description of object oriented programming.

In older forms of programming, data and procedures are stored separately. You have a bunch of data, and then you have the procedures that operate on the data. (What would Von Neuman have thought of this!?) In our rectangle example above, we would define a bunch of rectangles, and then we would have procedures that would do something to one or another of the rectangles. In object oriented programming the procedures and data are bundled together. Instead of having a procedure make a rectangle get bigger, you just send a message to the rectangle, telling it to make itself bigger. Or you tell the rectangle to move, or draw itself, or whatever. Because procedures in MacScheme are lexically scoped, they can have internal state. The internal state is the data within the object, and the rest of the procedure knows how to operate on this data. Object oriented programming has advantages that are similar to the advantages of data abstraction. Once you define an object, you can forget about how its insides work. You just treat it as a black box and work with it as a single unit. When you want it to do something, you tell it what to do; when you want to know something about it, you ask it. The creation of objects helps keep programs modular and simple. You work on small, easily understood units which you can then assemble into larger units, and so on.

The first objects we will be working with are ovals. You give the procedure make-oval a rectangle or any combination of points and coordinates, and it returns a procedure which is an object that can draw, erase, invert itself, tell you its bounding rectangle, or receive a new bounding rectangle. Because this object is a procedure, you call it just like you call any other procedure. The argument that you give it is called the 'message' which you send to the object. It is up to the object to decode the message and act accordingly, or signal an error if it doesn't know what to do.

The next stage of object oriented programming involves something called 'inheritance'. Inheritance occurs when one object takes on the characteristics and abilities of other objects, usually adding new abilities of its own. This month we will keep thing simple and just discuss single inheritance, that is, we will define an object that inherits from one other object.

When you call the procedure make-grow-oval, you give it a bounding rectangle as an argument. Make-grow-oval then sends this bounding rectangle to make-oval, and gets back an object, an oval. It then returns a new object, a grow-oval, which contains this recently (and completely locally) defined oval. When you send a message to a grow-oval it first checks to see if it recognizes the message, in which case it does the appropriate processing. If it doesn't recognize the message, it passes it directly to its oval (i.e. it lets it 'fall through' to the internal object). In this way a grow-oval can add new functionality to an oval without losing any of an oval's standard features. One other interesting thing to note: the grow-oval lets the oval take care of bookkeeping the current bounding rectangle. Whenever a grow-oval needs to know the bounding rectangle, it just asks its oval for the information.

Doing It Together

Anyone interested in learning Lisp should read Structure and Interpretation of Computer Programs by Hal Abelson and Gerald Sussman. This is not only a great book on computer programming, but it is all done in Scheme. The reference manual for MacScheme is also very well written, if you just want see what a particular command does. One other book on Scheme that Semantic Microsystems recommends is The Little Lispers, but I haven't seen it myself, and so I can't speak for it.

Graphics Objects in MacScheme 1.11 Program File

Andrew Shalit

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;newgraphicsobjects
;;;a program that demonstrates graphics and
;;;object oriented programming in MacScheme 1.11
;;;copyright 1986, MacTutor Magazine
;;;written by Andrew Shalit
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;constructors for building points and rectangles
;;A point is a simple pair of coordinates : (x . y)
(define (make-point x . y)
 (if  (point? x)
 x
 (cons x (car y))))
;;a rectangle is a list of two points: ((x1 . y1) (x2 . y2))
(define (make-rect first-coord . other-coords)
 (if  (rectangle? first-coord)
 first-coord
 (let ((first-other (car other-coords)))
 (if  (point? first-coord)
 (list  first-coord
 (if  (point? first-other)
 first-other
 (apply make-point other-coords)))
 (apply make-rect
 (cons  (make-point
 first-coord first-other)
 (cdr other-coords)))))))

;selectors for getting coordinates out of points and rectangles
(define (x-coord point)
 (car point))
(define (y-coord point)
 (cdr point))
(define (left-top rectangle)
 (car rectangle))
(define (right-bottom rectangle)
 (cadr rectangle))
(define (left rectangle)
 (x-coord (left-top rectangle)))
(define (top rectangle)
 (y-coord (left-top rectangle)))
(define (right rectangle)
 (x-coord (right-bottom rectangle)))
(define (bottom rectangle)
 (y-coord (right-bottom rectangle)))

;;tests to determine whether something is a point or rectangle
(define (point? object)
 (if  (pair? object)
 (and (number? (car object))
 (number? (cdr object)))
 ()))
(define (rectangle? object)
 (if  (pair? object)
 (and (point? (car object))
 (point? (cadr object)))
 ()))

;functions for adding and subtracting points
(define (add-points point1 point2)
 (cons  (+ (x-coord point1) (x-coord point2))
 (+ (y-coord point1) (y-coord point2))))
(define (subtract-points point1 point2)
 (cons  (- (x-coord point1) (x-coord point2))
 (- (y-coord point1) (y-coord point2))))

;function for passing a rectangle to a graphics function
(define (2-point-function the-function the-rectangle)
 (the-function (left the-rectangle)
 (top the-rectangle)
 (right the-rectangle)
 (bottom the-rectangle)))

;;this is your basic oval that can draw, erase, invert itself,
;;tell its dimensions, and receive new dimensions
(define (make-oval . oval-definition)
 (let ((oval-definition (apply make-rect oval-definition)))
 (lambda (message)
 (if  (rectangle? message)
 (set! oval-definition message)
 (case message
 (DRAW (2-point-function paint-oval oval-definition))
 (ERASE (2-point-function erase-oval oval-definition))
 (INVERT (2-point-function invert-oval oval-definition))
 (DESCRIPTION oval-definition)
 (else (error "make-oval can't handle that definition"
 message)))))))

;;a grow-oval inherits all of the features of an oval, but can
;;also move and change size in more interesting ways
(define (make-grow-oval . oval-def)
 (let ((this-oval (apply make-oval oval-def)))
 (lambda (the-change . the-amount)
 (let ((old-description (this-oval 'description))
   (real-amount
 (if  the-amount
 (apply make-point the-amount))))
 (this-oval
 (case the-change
 (MOVE
 (make-rect
 (add-points
 real-amount
 (left-top old-description))
 (add-points
 real-amount
 (right-bottom old-description))))
 (MOVE-TO
 (make-rect
 real-amount
 (add-points
 real-amount
 (subtract-points
 (right-bottom 
 old-description)
 (left-top 
 old-description)))))
 (EXPAND
 (make-rect
 (subtract-points
 (left-top old-description) 
 real-amount)
 (add-points
 real-amount
 (right-bottom old-description))))
 (else the-change)))))))


;;;this procedure shows off some ovals
(define (oval-sampler)
 (let ( (oval-1 (make-grow-oval 5 5 50 50))
 (oval-2 (make-grow-oval 100 20 130 40))
 (oval-3 (make-grow-oval 30 90 60 120)))
 (clear-graphics)
 (oval-1 'draw)
 (oval-2 'draw)
 (oval-3 'draw)
 (oval-1 'move 5 5)
 (oval-1 'erase)
 (oval-2 'expand 4 4)
 (oval-2 'invert)
 (oval-3 'move-to 40 60 70 90)
 (oval-3 'draw)))