TweetFollow Us on Twitter

Technical Questions 2.2
Volume Number:2
Issue Number:2
Column Tag:Ask Prof. Mac

Readers Technical Questions

By Steve Brecher, Software Supply, MacTutor Contributing Editor

Prof. Mac depends on your technical questions for inspiration each month. If you have programming problems in your latest project, or are just curious, send your questions to Prof. Mac and let him research your problem.

PICTs from MacDraw

Q. Mike LePage would like to know if a MacDraw PICT file is really a QuickDraw picture; more generally, he asks how to get a MacDraw picture into a PICT resource that his application can use.

A. I really don't know what file format MacDraw uses; its PICT format sure doesn't look like a QuickDraw picture to me, but it may have such pictures buried within it. At any rate, a good way to get a PICT resource from a MacDraw document is to paste the drawing into the Scrapbook; it will be a PICT resource in the Scrapbook file, which can then be moved to your application using Copy/Paste within ResEdit. [Note: ResEdit is available on source code disk #6 for this issue of MacTutor. -Ed.]

Drawing Partial Pictures

Q. Mike LePage also asks, "Suppose I have a giant picture, but want to display only part of it in a window and not have it all scaled down into the window, with the rest able to be scrolled into view. Is there a way of setting the bounds rectangle without creating a bit image of the whole picture first?"

A. What I'd do is pass a bounds rectangle to DrawPicture that was as large as the whole picture. The drawing will be clipped to the window's rectangle, so only the part of the picture that is in the window will actually be drawn, and it will not be scaled down. To scroll, use ScrollRect, and draw the picture again with the boundsrect moved by the size of the scroll.

Simple FilterProc

Q. Mike LePage's third question is, "I have a FilterProc for a modal dialog 'About' box. I don't want any buttons or other controls, so the function will just check for a mousedown and return True on that condition only." Mike wants to know how to code such a FilterProc in assembler.

A. I'd suggest that such a function also return True if Return or Enter is pressed. So, that's the way I've coded it in Figure 1.

Figure 1

;
; Function MyFilter(theDialog: DialogPtr; 
;VAR theEvent: EventRecord; 
;VAR itemHit:  INTEGER): BOOLEAN;
;
; ModalDialog filterProc which returns True if the event is a 
; mousedown or Return or Enter key.
;
 IncludeSysEqu.D
;
;  ASCII codes
CR Equ  13
Enter Equ 3
;
; A6 offsets--
OldA6   Set 0
RtnAddr Set OldA6+4
itemHit Set RtnAddr+4
theEventSet itemHit+4
theDialog Set  theEvent+4
Result  Set theDialog+4
;
MyFilter:
 Link A6,#0 ;set up stack frame
 Move.L theEvent(A6),A0 ;A0 := addr of event record
 Cmp  #MButDwnEvt,(A0)  ;mousedown? 
 ;(note evtCode offset = 0)
; remove following 6 instructions if key events not to be tested
 Beq.S  @0;yes
 Cmp  #KeyDwnEvt,(A0);key down?
 Bne.S  @0;no
 Cmp.B  #CR,evtMessage+3(A0);Return?
 Beq.S  @0;yes
 Cmp.B  #Enter,evtMessage+3(A0) ;Enter?
@0 Seq  Result(A6) ;set result
 Unlk A6
 Move.L (SP)+,A0 ;return address
 Lea  Result-itemHit(SP),SP ;pop arguments
 Jmp  (A0);return

Resources Potpourri

Q. Pascal M. Giordano has a lot of questions about resources, so many that it would take too much space to list them all. So, in this case I'll provide only some answers without the questions!

A. OpenResFile is used to open a resource file and make the resources in it available to your application, typically via GetResource. When your application is launched, its resource fork is automatically opened. So, you only need to use OpenResFile to get at resources in a file other than your application. Some developers like to maintain their non-code resources in a separate resource file while they're working on the program, because code changes are much more frequent than resource changes. Hence, they must use OpenResFile to make those resources available. When the program is ready for release, the resources are included in the application file and the call to OpenResFile is removed. My own approach is to have a separate resource file, but to include the resources in my application file each time I link a test version. This requires a linker which will directly include resources, such as Consulair's Link or Signature Software's McAssembly; MDS Link won't do this (it will only include resources that are in .REL format). That way, I can create or change my resources directly using ResEdit or ReEdit, without a separate resource compiler step.

I very rarely use RMaker. The current version of ResEdit is quite good for creating and editing many kinds of standard resources. I use ReEdit primarily for editing text items in DITLs, since it provides a bigger editing box than ResEdit does for such items. RMaker is a resource compiler that translates textual descriptions of resources into actual resources. In olden days it was the only way to create resources; but as ResEdit matures in its long march to completion it becomes a better and better replacement for RMaker. [Resources can also be coded in assembler and assembled and linked under MDS, as previously mentioned. There is also some new software showing up that allows dialogs and windows to be "designed" on screen with the mouse and then automatically translated into RMaker text file format. A lot more work is needed in this area. -Ed.]

"Signature" is the name for the 4-byte code associated with an application. "Creator" is the name for the analogous code associated with a document. Usually, they are the same code, serving to link the document with it's creating application. Often, "Creator" is used in the sense of "Signature," as when one speaks of "the application's Type and Creator codes."

A BNDL resource is required in any application that is to have a custom icon displayed by the Finder, or in any that creates documents that need to be associated with the application (so that opening the document automatically launches the application).

Building an Editor

Q. Dr. K. Desikachary is developing a multilingual editor to process Indian Languages. He has several questions; again, I'll just imply the questions in my responses.

A. MacWrite file formats are documented in Apple's Technical Notes #11 (MacWrite 2.2) and #12 (MacWrite 4.5). The Technical notes are available by subscription at $20/yr from Apple Computer, 20525 Mariani Ave MS 3-T, Cupertino CA 95014.

I haven't seen any documentation of Microsoft Word file formats.

As far as I know, Apple's Core Edit package is the only text editor building-block available. (Dr. Desikachary would like to find an editing package that he could build on that doesn't have Core Edit's limit of 100 font/style changes in a document.) I haven't seen Core Edit, but I wonder if the limit could be increased by changes to the code. Any reader who can be of help on this may contact Dr. Desikachary at 13 McGregor St., Pinawa, MB ROE 1L0, Canada.

Finding All Files

Q. Bob Perez, author of VMCO (Visual/Vocal MAUG Conferencing program), wants to know how to find a file on an HFS-formatted volume, no matter in what directory the file may be.

A. The FCensus routine in Figure 2 can be used to do this. However, rather than search for a given file, it supplies information about each file, one at a time, to a routine that you supply. If you're looking for a specific file, your routine, when it recognizes a match, can tell FCensus to quit by returning True.

Note, however, that on an HFS volume there can be more than one file having the same name but in different directories. So, searching for a file on an HFS volume and stopping the search when you find the first instance of "the" file is a risky thing to do. Maybe the user really wants you to use another version of the file, with the same name, that's in another directory.

We use the new HFS routine _GetCatInfo, which is like _GetFileInfo except that it returns information for directories as well as files. The parameter block that it returns for files is the same as the GetFileInfo parameter block, except that it's longer -- it has extra information appended to it. (Purists note: GetCatInfo's ioTrap field in the parameter block header is different from GetFileInfo's.)

Figure 2

; 
; FCensus -- HFS/MFS file census routine; provides info on each file
; on a volume, whether MFS or HFS.  If HFS volume, provides info on each 
file
; in each directory.
;
; Procedure FCensus(vRefNum: integer; DirID: longint; Inspector: ProcPtr);
;   
;   vRefNum
;volume reference number (or drive number) of volume.
;   DirID
;ID of directory in which to begin search; pass 2 for root directory. 
 ; The designated directory and all directories below it in the tree 
will 
;be canvassed.  Value passed is immaterial for HFS volumes.
;   Inspector
;The address of a caller-supplied function:
;MyInspector(ParamBlock: ParmBlkPtr; DirID: longint): boolean;
;ParamBlock is the address of a GetFileInfo parameter block for a
;file on the volume.  DirID is the ID of the file's directory (if the
;volume is an MFS volume, DirID is whatever was passed to FCensus).
;If the Inspector function returns True, FCensus will return
;immediately; otherwise FCensus will continue canvassing (continue
;to call MyInspector) until all files have been processed.
;NOTE:  after FCensus returns neither the parameter block, nor the
;the filename string pointed to by its ioFileName parameter, exists.
;
; The census is depth-first, i.e., directories within directory X are
; canvassed before other directories within X's parent directory.  Within 
a
; directory, files are accessed in alphabetic order; then directories 
within
; that directory are accessed in reverse alphabetic order.

 IncludeMacTraps.D
 IncludeSysEqu.D
 IncludeSysErr.Txt
;
; not provided in pre-HFS SysEqu/MacTraps:
;
ioDirID Equ 48
ioHFQElSize Equ  $6C
ioDirFlgEqu 4
FSFCBLenEqu $3F6 ;addr of sys global, positive if HFS running
 .Trap  _HFSDispatch $A260
 Macro  _GetCatInfo =
 MoveQ  #9,D0    ;selector
 _HFSDispatch
 |
; A6 offsets--
OldA6 Set 0
RtnAddr Set OldA6+4
Inspec  Set RtnAddr+4
DirID Set Inspec+4
vRefNum Set DirID+4
ArgsSz  Set vRefNum+2-Inspec
;
ParmBlk Set OldA6-ioHFQElSize ;local parameter block
NameStr Set ParmBlk-256   ;local filename string buffer
Index Set NameStr-2;index in current directory
FCensus:
 Link A6,#Index
 Clr.L  -(SP)    ;sentinel for end of DirID list
NextDir:
 Clr  Index(A6)  ;init index
NextFile:
 Lea  ParmBlk(A6),A0 ;pointer to param block
 Move vRefNum(A6),ioVRefNum(A0)
 Move.L DirID(A6),ioDirID(A0)
 Lea  NameStr(A6),A1
 Move.L A1,ioFileName(A0)
 AddQ #1,Index(A6) ;bump index for _GetCat/FileInfo
 Move Index(A6),ioFDirIndex(A0)
 Tst  FSFCBLen   ;HFS running?
 Bmi.S  @0
 _GetCatInfo;yes
 Bra.S  @1
@0 _GetFileInfo  ;no
@1 Beq.SNodeKind ;no error
 Cmp  #fnfErr,D0 ;end of current directory?
 Bne.S  FCExit   ;no,  an unexpected problem
 Move.L (SP)+,DirID(A6)   ;ID of dir to search next
 Bne.S  NextDir  ;go look at first file/dir in new dir
 Bra.S  FCExit   ;no more directories, all done
NodeKind:
 Btst #ioDirFlg,ioFlAttrib(A0)   ;is this a directory or a file?
 Beq.S  CallInspec ;a file
 Move.L ioDirID(A0),-(SP) ;a directory, push on search list
 Bra.S  NextFile ;and loop back
CallInspec:
 Clr  -(SP) ;space for user function result
 Pea  ParmBlk(A6); param block ptr to user func.
 Move.L DirID(A6),-(SP)   ;pass DirID
 Move.L Inspec(A6),A0;address of user function
 Jsr  (A0);call user function
 Tst.B  (SP)+    ;user wants us to quit now?
 Beq.S  NextFile ;no, keep going
FCExit:
 Unlk A6
 Move.L (SP)+,A0 ;return addr
 Lea  ArgsSz(SP),SP;pop arguments
 Jmp  (A0);return

"SetSound" Code Bumming

Some CompuServe MAUG members were asking for a desk accessory that would let them change the Mac's sound volume with less memory overhead than required by the Control Panel. Sysop Bill Steinberg obliged by whipping out a "SetSound" DA. This was Bill's first DA, so he started with Bill Bond's and Chris Allen's DA Shell from the October, 1985 issue of MacUser magazine, and added the SetSound functional guts. When he'd finished, he asked me if I'd like a copy of his source code (Bill has always been generous about sharing source code with me). I said sure, and, knowing that small size was one of the objects of this exercise, asked him if he'd like me to see if I could further reduce its size. He thought it'd be tough to take much code out of it without changing its functionality -- so much so that he bet me a dinner that I couldn't reduce it by 50 bytes. It was originally a little less than 1K, so that was about 5%.

As I watched the code go by at 1200 baud while I was downloading it, I wasn't confident about winning the bet -- until I saw the 256-byte statically-allocated string buffer at the end. I knew then that just by allocating that dynamically, on the stack, I could win a free dinner. But I thought Bill might object to such a simple maneuver as the sole basis for determining who picked up the dinner tab. After all, moving the buffer from the DRVR resource to the stack didn't really reduce the total memory requirements of using the DA. So I got to work and massaged the code, taking out a word here, a few words there. The end result was 414 bytes smaller than the original. Of course it's a little obscure in places -- the inevitable result of optimizing ("bumming") code as much as possible.

The original version is shown in Figure 3a, and the space-optimized version in Figure 3b. Comparison of the two might provide some useful tips to students of assembly language -- especially in light of the fact that Bill's original version was competently coded, rather than a begining programmer's strawman. Thanks to Bill for being a good sport, for his permission to reprint the code, and for his wide-ranging knowledge of good restaurants.

Figure 3a

;-----------------------------------------------------------------------
; SetSound DA (original version)
; Copyright 1985  William P. Steinberg -- reprinted by permission.
;
; SetSound is a small (<1K) DA that sets default sound volume
;-----------------------------------------------------------------------

 Resource 'DRVR' 31 'SetSound'
 
 IncludeMacTraps.D
 IncludeSysEqu.D
 IncludeQuickEqu.D
 IncludeToolEqu.D
 IncludeSysErr.D

 .TRAP  _CntrLi  $A204    ; _Control,Immed

GoodByeKiss EQU  -1

TRUE  EQU 1
FALSE EQU 0

DAStart:
 DC.W $4400 ; Flags/descriptor
 ; (lock in memory, can
 ;  respond Control calls)
 DC.W 0 ; Tick Count
 DC.W 328 ; Event mask
 ; (will handle: keydown,
 ;  update and activate)
 DC.W 0 ; Menu ID
 DC.W DAOpen   -DAStart ; Offset to open routine
 DC.W DAPrime  -DAStart ; Offset to prime routine
 DC.W DAControl-DAStart ; Offset to control rout.
 DC.W DAStatus -DAStart ; Offset to status rout.
 DC.W DAClose  -DAStart ; Offset to close routine
 DC.B 8 ; Desk Accesory title
 DC.B 'SetSound' ; ( Optional -  helps
 .ALIGN 2 ;   identify  DA in  heap.
 ;   DA appears in Apple
 ;  menu using the 
 ; name of DRVR.)
DAOpen:
 MOVEM.LA0-A6/D0-D7,-(SP) ; Save registers
 MOVE.L A1,A4    ; Put DCE pointer in A4
 PEA  SavePort   ; Save Grafport
 _GetPort
 TST.L  dCtlWindow(A4)  ; Does window exist ?
 BNE.S  GoodOpen ;  yes,  DA already open
 LEA  DAStart,A0 ; Get handle to the DA
 _RecoverHandle
 MOVE.L A0,-(SP) ; Get information on DA
 PEA  DriverID   ; DA id
 PEA  DriverType ; DA type = 'DRVR'
 PEA  DriverName ; DA name
 _GetResInfo
 SUB.L  #4,SP    ; Make room for result
 CLR.L  -(SP)    ; WindowRecord on heap
 PEA  WindowRect ; address of  wind rect
 PEA  DriverName ;  address of  wind title
 MOVE.B #FALSE,-(SP) ; Make it invisibler now
 MOVE.W #noGrowDocProc,-(SP)  ; Push window def id
 MOVE.L #-1,-(SP); Window in front
 MOVE.B #TRUE,-(SP); Give it a goaway box
 CLR.L  -(SP)    ; Window ref value
 _NewWindow ; Create the window
 MOVE.L (SP)+,D0 ; Get the window pointer
 LEA  MyWindow,A0; Save  window pointer
 MOVE.L D0,(A0)  ; Was window created ?
 BEQ.S  BadOpen
 MOVE.L MyWindow,A0; Set windowKind field to
 ;   the DA RefNum
 MOVE.W dCtlRefNum(A4),windowKind(A0) ;Put window
 MOVE.L MyWindow,dCtlWindow(A4)  ; ptr in the DCE
GoodOpen:
 MOVE.L SavePort,-(SP)  ; Restore Grafport
 _SetPort
 MOVEM.L(SP)+,A0-A6/D0-D7 ; Restore registers
 CLR.W  D0; Return code
 RTS
BadOpen:
 MOVE.L SavePort,-(SP)  ; Restore Grafport
 _SetPort
 MOVEM.L(SP)+,A0-A6/D0-D7 ; Restore registers
 MOVE.W #-1,D0   ; Return code
 RTS
 
DAClose:
 MOVEM.LA0-A6/D0-D7,-(SP) ; Save registers
 MOVE.L A1,A4    ; Device Ctrl Entry in A4
 PEA  SavePort   ; Save Grafport
 _GetPort
CloseDA:
 CLR.L  -(SP)    ; Get front window ptr
 _FrontWindow
 MOVE.l (SP)+,D0
DAClose1:
 TST.L  D0;  any more windows ?
 BEQ.S  DAClose3
 CMP.L  MyWindow,D0; Is this our window ?
 BEQ.S  DAClose2
 MOVE.L D0,A0
 MOVE.L nextWindow(A0),D0 ; Get next wind in chain
 BRA.S  DAClose1
DAClose2:
 MOVE.L MyWindow,-(SP)  ; Throw away window
 _DisposWindow
 CLR.L  dCtlWindow(A4)  ; Window gone, tell DCE
DAClose3: 
 MOVE.L SavePort,-(SP)  ; Restore Grafport
 _SetPort
 MOVEM.L(SP)+,A0-A6/D0-D7 ; Restore registers
 CLR.W  D0; Return code
 RTS  
DAControl:
 MOVEM.LA0-A6/D0-D7,-(SP) ; Save registers
 MOVE.L A0,A3    ;  ptr to parm block in A3
 MOVE.L A1,A4    ;  pointer to DCE in A4
 PEA  SavePort   ; Save Grafport
 _GetPort
 MOVE.L MyWindow,-(SP)  ; Make mywindow 
 _SetPort ; the Grafport
 
 ; A3 points to the parameter block which tells us what we
 ; need to do and supplies us with the data to carry it out.

 MOVE csCode(A3),D0
 CMP.W  #GoodByeKiss,D0 ; "GoodByeKiss" msg
 BEQ.S  CloseDA
 CMP.W  #accEvent,D0 ; Event msg, Sys. Evt.
 BNE.S  CTLReturn
CTLEvent:
 MOVE.L csParam(A3),A2
 MOVE.W evtNum(A2),D0
 CMP.W  #keyDwnEvt,D0; Keydown event 
 BEQ.S  EVTkeyDown
 CMP.W  #updatEvt,D0 ; Update event
 BEQ  EVTupdateEvt
 CMP.W  #activateEvt,D0 ; Activate event
 BEQ.S  EVTactivateEvt
CTLReturn:
 MOVE.L SavePort,-(SP)  ; Restore Grafport
 _SetPort
 MOVEM.L(SP)+,A0-A6/D0-D7 ; Restore registers
 CLR.W  D0; Return code
 MOVE.L JIODone,-(SP); Goto IODone
 RTS
EVTactivateEvt:
 MOVE.W EvtMeta(A2),D0
 BTST #activeFlag,D0
 BEQ.S  CTLReturn
 LEA  ActivePend,A0
 ST(A0)
 BRA.S  CTLReturn
EVTkeyDown:
 CLR.L  D2
 MOVE.B evtMessage+3(A2),D2
 CMP.B  #'0',D2
 BLT.S  @2
 CMP.B  #'7',D2
 BGT.S  @2
 SUB.B  #'0',D2
 ANDI.B #7,D2
 ANDI.B #$F8,SpVolCtl
 OR.B D2,SpVolCtl
 MOVEQ  #7,D0
@1 CLR.L-(SP)
 DBRA D0,@1
 MOVE.L SP,A0
 MOVE.W #$FFFC,24(A0)
 MOVE.W #2,26(A0)
 MOVE.W D2,28(A0)
 _CntrLi
 ADD  #32,SP
 LEA  SysParam,A0
 MOVEQ  #-1,D0
 _WriteParam
 MOVE.L MyWindow,-(SP)
 _SetPort
 PEA  NumberRect
 _InValRect
 MOVE.W #3,-(SP) ; Beep on update
 _SysBeep ;at current level
@2 BRA  CTLReturn

EVTupdateEvt:
 MOVE.L MyWindow,-(SP)  ; Update MyWindow
 _SetPort
 MOVE.L MyWindow,-(SP)     ; BeginUpdate(MyWindow)
 _BeginUpdate
 MOVE.L MyWindow,A0
 PEA  portRect(A0)
 _EraseRect
 MOVE.W #' ',-(SP)
 _DrawChar
 MOVEQ  #-1,D0
 MOVE D0,-(SP)
 _SetFontLock
 MOVE.L #20<<16!10,-(SP)
 _MoveTo
 MOVE.W #sysFont,-(SP)
 _TextFont
 MOVE.W #'©',-(SP)
 MOVE.W #applFont,-(SP)
 _TextFont
 PEA  String1
 _DrawString
 MOVE.L #35<<16!19,-(SP)
 _MoveTo
 PEA  String2
 _DrawString
 MOVE.L #50<<16!27,-(SP)
 _MoveTo
 PEA  String3
 _DrawString
 CLR.W  D0
 MOVE.B SpVolCtl,D0
 AND.B  #%00000111,D0; Mask all but low 3 bits
 ADD.B  #'0',D0  ; Convert to ASCII
 MOVE.W D0,-(SP)
 _DrawChar
 MOVE.L #65<<16!37,-(SP)
 _MoveTo
 PEA  String4
 _DrawString
 MOVE.L MyWindow,-(SP)  ; EndUpdate(MyWindow)
 _EndUpdate
 CLR  -(SP)
 _SetFontLock
 LEA  ActivePend,A0
 TST.B  (A0)
 BEQ.S  @1
 MOVE.W #3,-(SP)
 _SysBeep
 LEA  ActivePend,A0
 CLR.B  (A0)
@1 BRA  CTLReturn
 
 ; Prime and Status are not used by Desk Accesories.
 ; These are included "just in case".
DAPrime:
DAStatus:
 CLR.W  D0; Return code
 RTS

SavePort: DC.L 0 ; Application's Grafport
MyWindow: DC.L 0 ; DA window pointer
DriverID: DC.W 0 ; DA resource id
DriverType: DC.L 0 ; DA resource type
DriverName: DCB.B256,0  ; DA resource name
WindowRect: DC.W 40,2,115,213  ; DA window rectangle
NumberRect: DC.W 38,175,50,190 ; DA number rect.
 ;for invalrect
ActivePend: DC.B 0
String1:DC.B28,'1985 by William P. Steinberg'
String2:DC.B28,'Vers 1.0 - Free Distribution'
String3:DC.B23,'Current Volume Level = '
String4:DC.B21,'Enter New Level (0-7)'

 END

Product Briefs from Ms. Elaine E.

My trusty (if somewhat disorganized) assistant, Ms. Elaine E., has returned from a trip outside the cave with reports on some products of interest to developers...

MacExpress

MacExpress is a "generic application" which provides many powerful facilities for handling events, windows, and the desktop. Conceptually, it's a core application program that you customize. It handles all the chores of event processing, menu selections, window manipulation, etc. that are not specific to your application; you provide the code that's application-specific. It's supplied as a set of library routines for a variety of development systems (MDS, Mac C, TML Pascal, etc.) Note that these are not merely utility routines that you call for occasional services; an applicatiion built using MacExpress would, by virtue of that fact, necessarily invoke many of its fundamental event- and window-handling routines. Logically (but not physically) speaking, it's as if you begin your work with the MacExpress code already constituting the core of your application. Physically, your code consists of calls to MacExpress routines that are brought in at link time (plus, of course, your application-specific code).

For example, MacExpress automatically handles window movement, resizing, scrolling, splitting into panes; you have to worry only about what gets drawn in the windows. Similarly with menus: MacExpress handles command selection and desk accessories; you worry only about the code that implements the application-specific menu commands.

MacExpress also provides automatic facilities for handling icons on the desktop (Finder-style). You can associate icons with, e.g., windows (documents) and/or desk accessories. MacExpress will take care of handling the icons graphically (dragging them, "shadowing" them, rearranging them with a clean-up command); you specify what happens when a user opens an icon or sets it aside.

I haven't actually developed an application using MacExpress, but I've spent some time examining the documentation, demos, and sample source files that come with it. I'd seriously consider using it for a window-oriented application. (Lately, my nose has been buried in device drivers and such.) MacExpress author Al Whipple appears to have a sincere commitment to supporting the product.

ALSoft, Inc.

P.O. Box 927

Spring, TX 77383-0927 (713) 353-4090

$495 (demo version, $50, applicable to purchase)

$100/yr per application you distribute (unlimited copies)

McAssembly

McAssembly is a new assembly-language development system for the Macintosh. It consists of a two-pass assembler and linker (integrated into one application file), and a separate debugger (Macsbug-style, i.e., TTY line-oriented).

The assembler has some nice features: dummy data sections to facilitate record offset definitions; based variables, so that explicit register references need not be coded; alphanumeric local labels; decent listings (ever looked at an MDS Asm listing? --yuk) with optional cross-reference; built-in resource compiler -- the assembler knows about the formats of the commonly-used resources. Conversion of MDS Asm source files to McAssembly format is pretty straightforward.

The linker can directly include resource files (created, e.g., with ResEdit). McAssembly's .Rel file format is not compatible with anything else, but a utility is provided to convert its .Rel files to MDS format.

Equivalents for the Software Supplement equate and trap definition files are provided, as are .Rel files (in McAssembly format) corresponding to the Supplement Appletalk, Printer, etc., object files.

On paper, I like it better than MDS Asm (I've never been a fan of MDS Asm). Next time I start a new assembly project, I plan to give it a real tryout. It's been used to assemble itself and the TMON User Area (which uses every trick in the book), so I figure it's reasonably well-tested. Author Dave McWherter is responsive to enhancement suggestions.

Signature Software

2151 Brown Ave.

Bensalem, PA 19020 (215) 639-8764

$89.95

QUED

QUED is a programmer's text editor. After I bought it, I stopped using MDS Edit (and arranged to have Software Supply, i.e., me, become a dealer for QUED -- note, therefore, my financial interest in telling you about QUED).

QUED is memory-based -- the file(s) you edit must fit into memory. It will open as many files (windows) as will fit; I've had more than 30 windows open at once. Windows can be automatically arranged in a tile fashion (neat rows and columns) or stacked in the more usual manner. Each window can be horizontally and/or vertically split into independently-scrollable panes. The top two windows can be scrolled synchronously (scroll bar of either one controls both).

QUED can be told to automatically save your work every N keystrokes, and/or to save to two different disks (called the "RAMdisk" option). It will display unclosed parentheses as you're entering code, where "parentheses" are user-defined program structure elements (begin end, { }, etc.) or string or comment delimeters; or it will check the whole file for unbalanced parentheses. It has a user-editable Transfer menu. You can move the cursor and/or delete by characters, words, and lines without using the mouse. Double-click a window's title bar to enlarge it to full-screen; double-click again to restore it to its former size. QUED will print in background (spooled) mode. You can append to as well as replace the contents of the Clipboard, and exchange selected text with the Clipboard. Search/replacement can apply to multiple files, and Undo really undoes. It's compatible with MDS Edit file font, font size and tab-setting resources, and works with MDS Exec.

I like it. I use it. I sell it. The publisher is a good guy and is committed to support and enhancements.

Paragon Courseware

4954 Sun Valley Road

Del Mar, CA 92014 (619) 481-1477

$65 (+CA tax) + $2 shipping, credit cards accepted

or

Software Supply

4618 E. Sixth St.

Long Beach, CA 90814 (213) 434-3723

$65 (+CA tax), no shipping charge, checks only

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Kodi 17.1. - Powerful media center tool...
Kodi (was XBMC) is an award-winning free and open-source (GPL) software media player and entertainment hub that can be installed on Linux, OS X, Windows, iOS, and Android, featuring a 10-foot user... Read more
Bookends 12.8 - Reference management and...
Bookends is a full-featured bibliography/reference and information-management system for students and professionals. Bookends uses the cloud to sync reference libraries on all the Macs you use.... Read more
Apple iTunes 12.6 - Play Apple Music and...
Apple iTunes lets you organize and stream Apple Music, download and watch video and listen to Podcasts. It can automatically download new music, app, and book purchases across all your devices and... Read more
Default Folder X 5.1.4 - Enhances Open a...
Default Folder X attaches a toolbar to the right side of the Open and Save dialogs in any OS X-native application. The toolbar gives you fast access to various folders and commands. You just click on... Read more
Amazon Chime 4.1.5587 - Amazon-based com...
Amazon Chime is a communications service that transforms online meetings with a secure, easy-to-use application that you can trust. Amazon Chime works seamlessly across your devices so that you can... Read more
CrossOver 16.2 - Run Windows apps on you...
CrossOver can get your Windows productivity applications and PC games up and running on your Mac quickly and easily. CrossOver runs the Windows software that you need on Mac at home, in the office,... Read more
Adobe Creative Cloud 4.0.0.185 - Access...
Adobe Creative Cloud costs $19.99/month for a single app, or $49.99/month for the entire suite. Introducing Adobe Creative Cloud desktop applications, including Adobe Photoshop CC and Illustrator CC... Read more
MegaSeg 6.0.2 - Professional DJ and radi...
MegaSeg is a complete solution for pro audio/video DJ mixing, radio automation, and music scheduling with rock-solid performance and an easy-to-use design. Mix with visual waveforms and Magic... Read more
Bookends 12.8 - Reference management and...
Bookends is a full-featured bibliography/reference and information-management system for students and professionals. Bookends uses the cloud to sync reference libraries on all the Macs you use.... Read more
Adobe Creative Cloud 4.0.0.185 - Access...
Adobe Creative Cloud costs $19.99/month for a single app, or $49.99/month for the entire suite. Introducing Adobe Creative Cloud desktop applications, including Adobe Photoshop CC and Illustrator CC... Read more

The best deals on the App Store this wee...
Deals, deals, deals. We're all about a good bargain here on 148Apps, and luckily this was another fine week in App Store discounts. There's a big board game sale happening right now, and a few fine indies are still discounted through the weekend.... | Read more »
The best new games we played this week
It's been quite the week, but now that all of that business is out of the way, it's time to hunker down with some of the excellent games that were released over the past few days. There's a fair few to help you relax in your down time or if you're... | Read more »
Orphan Black: The Game (Games)
Orphan Black: The Game 1.0 Device: iOS Universal Category: Games Price: $4.99, Version: 1.0 (iTunes) Description: Dive into a dark and twisted puzzle-adventure that retells the pivotal events of Orphan Black. | Read more »
The Elder Scrolls: Legends is now availa...
| Read more »
Ticket to Earth beginner's guide: H...
Robot Circus launched Ticket to Earth as part of the App Store's indie games event last week. If you're not quite digging the space operatics Mass Effect: Andromeda is serving up, you'll be pleased to know that there's a surprising alternative on... | Read more »
Leap to victory in Nexx Studios new plat...
You’re always a hop, skip, and a jump away from a fiery death in Temple Jump, a new platformer-cum-endless runner from Nexx Studio. It’s out now on both iOS and Android if you’re an adventurer seeking treasure in a crumbling, pixel-laden temple. | Read more »
Failbetter Games details changes coming...
Sunless Sea, Failbetter Games' dark and gloomy sea explorer, sets sail for the iPad tomorrow. Ahead of the game's launch, Failbetter took to Twitter to discuss what will be different in the mobile version of the game. Many of the changes make... | Read more »
Splish, splash! The Pokémon GO Water Fes...
Niantic is back with a new festival for dedicated Pokémon GO collectors. The Water Festival officially kicks off today at 1 P.M. PDT and runs through March 29. Magikarp, Squirtle, Totodile, and their assorted evolved forms will be appearing at... | Read more »
Death Road to Canada (Games)
Death Road to Canada 1.0 Device: iOS Universal Category: Games Price: $7.99, Version: 1.0 (iTunes) Description: Get it now at the low launch price! Price will go up a dollar every major update. Update news at the bottom of this... | Read more »
Bean's Quest Beginner's Guide:...
Bean's Quest is a new take on both the classic platformer and the endless runner, and it's free on the App Store for the time being. Instead of running constantly, you can't stop jumping. That adds a surprising new level of challenge to the game... | Read more »

Price Scanner via MacPrices.net

Updated iPad Price Trackers
Scan our Apple iPad (and iPod touch) Price Trackers for the latest information on sales, bundles, and availability on systems from Apple’s authorized internet/catalog resellers. We update the... Read more
12-inch 32GB Space Gray iPad Pro on sale for...
B&H Photo has 12″ Space Gray 32GB WiFi Apple iPad Pros on sale for $50 off MSRP including free shipping. B&H charges sales tax in NY only: - 12″ Space Gray 32GB WiFi iPad Pro: $749 $50 off... Read more
2.6GHz Mac mini on sale for $559, $140 off MS...
Guitar Center has the 2.6GHz Mac mini (MGEN2LL/A) on sale for $559 including free shipping. Their price is $140 off MSRP, and it’s the lowest price available for this model. Read more
SSD Speeder RAM Disk SSD Life Extender App Fo...
Fehraltorf, Switzerland based B-Eng has announced they are making their SSD Speeder app for macOS publicly available for purchase on their website. SSD Speeder is a RAM disk utility that prevents... Read more
iPhone Scores Highest Overall in Smartphone D...
Customer satisfaction is much higher among smartphone owners who use their device to operate other connected home services such as smart thermostats and smart appliances, according to the J.D. Power... Read more
Swipe CRM Free Photo-Centric CRM Sales DEal C...
Swipe CRM LLC has introduced Swipe CRM: Visual Sales 1.0 for iPad, an app for creating, managing, and sharing visually stunning sales deals. Swipe CRM is targeted to small-and-medium creative... Read more
13-inch 2.0GHz Apple MacBook Pros on sale for...
B&H has the non-Touch Bar 13″ 2.0GHz MacBook Pros in stock today and on sale for $150 off MSRP. Shipping is free, and B&H charges NY sales tax only: - 13″ 2.0GHz MacBook Pro Space Gray (... Read more
15-inch Touch Bar MacBook Pros on sale for up...
B&H Photo has the new 2016 15″ Apple Touch Bar MacBook Pros in stock today and on sale for up to $150 off MSRP. Shipping is free, and B&H charges NY sales tax only: - 15″ 2.7GHz Touch Bar... Read more
Apple’s iPhone 6s Tops Best-Selling Smartphon...
In terms of shipments, the iPhone 6s from Apple bested all competitors for sales in 2016, according to new analysis from IHS Markit, a world leader in critical information, analytics and solutions.... Read more
Logitech Rugged Combo Protective iPad Case an...
Logitech has announced its Logitech Rugged Combo, Logitech Rugged Case, and Logitech Add-on Keyboard for Rugged Case for Apple’s new, more affordable $329 9.7-inch iPad, a complete solution designed... Read more

Jobs Board

*Apple* Mobile Master - Best Buy (United Sta...
**492562BR** **Job Title:** Apple Mobile Master **Location Number:** 000853-Jackson-Store **Job Description:** **What does a Best Buy Apple Mobile Master do?** Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Fulltime aan de slag als shopmanager in een h...
Ben jij helemaal gek van Apple -producten en vind je het helemaal super om fulltime shopmanager te zijn in een jonge en hippe elektronicazaak? Wil jij werken in Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Fulltime aan de slag als shopmanager in een h...
Ben jij helemaal gek van Apple -producten en vind je het helemaal super om fulltime shopmanager te zijn in een jonge en hippe elektronicazaak? Wil jij werken in Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.