TweetFollow Us on Twitter

Screen Buffer
Volume Number:1
Issue Number:9
Column Tag:Modula 2 Mods

"Using the Alternate Screen Buffer"

By Tom Taylor, Software Engineer, Modula-2 Corp., Provo, Ut., MacTutor Contributing Editor

This article discusses the "alternate screen" capabilities of the Macintosh and presents a module that allows easy access to this facility from MacModula-2.

The Alternate Screen

As far as I know, Inside Macintosh only mentions the alternate screen buffer in two places: in the Memory Manager Programmer's Guide and in the Segment Loader Programmer's Guide. The Memory Manager section simply says, "There are alternate screen and sound buffers for special applications. If you use either or both of these, the space available for use by your application is reduced accordingly..." The alternate screen buffer can be used for high-speed flicker free graphics or a slide show program. For example, an application can be drawing in one screen while displaying a different screen. The popular "Tumbling Mac" demo by Mainstay uses the alternate screen buffer to create a high-speed flicker-free animation application. According to figure 1, the alternate screen buffer is allocated 32768 bytes below the main screen buffer.

Figure 1. Partial memory map showing sizes of various buffers.

The Segment Loader section mentions that the Chain and Launch traps configure memory for the sound and screen buffers. Whenever one of these traps is called, a parameter is passed that determines how these buffers are set up. The word (16-bit) parameter has three possible values:

Zero - Only the main sound and screen buffers are allocated. This is the normal situation and gives an application the most possible memory.

Negative - The alternate sound buffer and main screen buffer is allocated.

Positive - Both the alternate sound and screen buffers are allocated.

A Screen Switcher Module

Instead of building a specific program to demonstrate the alternate screen in Modula-2, this article presents a library module that can be used in many different programs in many different types of applications. This article will also present a small program that uses the developed screen switcher module.

A screen switcher module should support at least four functions:

• launch a program with the alternate screen,

• copy the main screen into the alternate screen,

• change the screen back and forth between the main and alternate screens, and

• set the screen buffer to the main screen before a program exits.

Apparently, the Finder always launches a program with the main sound and screen buffers (parameter set to 0). In order for a program to use the alternate screen, the program must be re-launched with the appropriate parameter (-1). The procedure LaunchWithAltScreen re-launches the program with the alternate screen if the alternate screen is not already allocated.

Here are the Definition and Implementation modules for handling the alternate screen:

DEFINITION MODULE ScreenSwitcher;

  EXPORT QUALIFIED
    LaunchWithTwoScreens,
    CopyScreens,
    SwitchScreens,
    SetMainScreen;
  
  PROCEDURE LaunchWithTwoScreens;
    (* This procedure re-launches the
       current program with the alternate
       screen.  If the alternate screen is
       already installed, this procedure 
       does nothing. *)

  PROCEDURE CopyScreens;
    (* CopyScreens copies the main screen
       into the alternate screen. *)
  
  PROCEDURE SwitchScreens;
    (* SwitchScreens alternately switches
       what is being displayed from the
       one screen to the other. *)
  
  PROCEDURE SetMainScreen;
    (* Sets the current screen buffer to
       the main screen so that when the
       program exits to the Finder
       the screen will be the right one. *)
  
END ScreenSwitcher.

IMPLEMENTATION MODULE ScreenSwitcher;

  FROM Launcher IMPORT
          CountAppFiles,
   LaunchRec,
   Launch;

  FROM Terminal IMPORT
          WriteString;

  FROM MacSystemTypes IMPORT
          Str255, LongCard;

  FROM Strings IMPORT
          StrModToMac;

  FROM SYSTEM IMPORT
          ADR, WORD, ADDRESS;

  FROM MacInterface IMPORT
          thePort;

  FROM QuickDraw1 IMPORT
          GrafPtr;

  CONST
    vBufA = 1e00h; (* Buffer A offset from
                                VIA interface chip *)
    vPage2 = 1;    (* This is a bit into
                              vBufA, if 0, select
                              alternate screen *)

  TYPE
    ScreenPtr
        = POINTER TO ARRAY [1..10944] OF
                 WORD;
      (* The Mac screen buffer is 10944
           16-bit words long *)

    FlagsPtr
        = POINTER TO BITSET;

  VAR
    CurPageOption [936h] : INTEGER;
       (* Mac global variable containing
           value of parameter at launch time
           that determines sound and screen
           buffers. *)
    ScrnBase [824h] : ScreenPtr;
       (* Mac global containing address of
           main screen. *)
    AltBase : ScreenPtr;
       (* Our homebrew alternate screen
            pointer. *)
    VIA6522Chip [1d4h] : FlagsPtr;
       (* VIA base address - from MDS's
           SysEqu.txt *)
    BufferA : FlagsPtr;
       (* Our pointer to vBuffer A *)
    originalPort  : GrafPtr;
       (* Save GrafPtr to whole screen *)

  PROCEDURE LaunchWithTwoScreens;
    VAR
      PrintOrWhat, count : INTEGER;
      launchRec : LaunchRec;
      prog : Str255;
  BEGIN
    IF CurPageOption >= 0 THEN
      CountAppFiles(PrintOrWhat,count);
        (* Get the number of Modula-2
            programs launched.  It better
            be one... this one! *)
      IF count # 1 THEN
        WriteString('Double-click the ');
        WriteString('program icon to start');
        WriteString(' the program');
        HALT;
      END;
      StrModToMac(prog,'Modula-2');
      launchRec.Name := ADR(prog);
      launchRec.SoundScreenBuffer := -1;
      Launch(launchRec);
    END;
  END LaunchWithTwoScreens;
  
  PROCEDURE CopyScreens;
  BEGIN
    AltBase^ := ScrnBase^;
  END CopyScreens;
  
  PROCEDURE SwitchScreens;
  BEGIN
    (* According to the MDS SysEqu.Txt
        file, the vPage2 bit in the BufferA
        flags is zero for the alternate
        screen and one for the main screen.
     *)
    WITH originalPort^.portBits DO
      IF baseAddr = ADDRESS(ScrnBase)
      THEN
          (* Graphical operations apply
              to alternate screen while
              displaying main screen. *)
 baseAddr := ADDRESS(AltBase);
 INCL(BufferA^,vPage2);
          (* Turn on bit *)
      ELSE
          (* Graphical operations apply
              to main screen while displaying
              alternate screen. *)
 baseAddr := ADDRESS(ScrnBase);
 EXCL(BufferA^,vPage2);
          (* Turn off  bit *)
      END;
    END;
  END SwitchScreens;
  
  PROCEDURE SetMainScreen;
  BEGIN
    IF NOT(vPage2 IN BufferA^) THEN
      SwitchScreens;
    END;
  END SetMainScreen;

BEGIN
  AltBase := ScrnBase;
   (* Set up pointer to alt screen *)
  DEC(AltBase,32768);
  
  BufferA := VIA6522Chip;
   (* Set up pointer to Buffer A flags *)
  INC(BufferA,vBufA);
  
   (* Save screen GrafPort *)
  originalPort := thePort;
END ScreenSwitcher.

            Here is a program module that actually uses the ScreenSwitcher module.  The 
program simply bounces a picture of a Lisa computer around the screen.  The program draws 
the picture in one screen, switches screens, erases the old picture, moves to a new position, 
draws the picture, and switches to the other screen and applies the same sequence of operations. 
 In order for this program to run properly, it is important to have this program and the 
Modula-2 program on the system disk.  Click the mouse to exit the program.

MODULE Animate;

  FROM QuickDraw1 IMPORT
          QDPtr, StuffHex, HideCursor,
          BitMap, Rect, SetRect,
          srcOr, srcBic, OffsetRect,
          Random;

  FROM QuickDraw2 IMPORT
          CopyBits;
   
  FROM MacSystemTypes IMPORT
          Str255;
   
  FROM Strings IMPORT
          StrModToMac;

  FROM SYSTEM IMPORT
          ADR, WORD;

  FROM MacInterface IMPORT
          thePort, Write;

  FROM EventManager IMPORT
          Button;

  FROM ScreenSwitcher IMPORT
          LaunchWithTwoScreens,
          CopyScreens, SwitchScreens;

  VAR
    icon : ARRAY [0..95] OF WORD;
       (* Storage to hold icon data *)
    x, y : ARRAY [0..1] OF INTEGER;
       (* coordinates of icon for each
           screen *)
    screen : [0..1];
       (* current screen reminder *)
    xDir, yDir : INTEGER;
       (* offset for each icon move *)
 
  PROCEDURE InitIcon;

    PROCEDURE MyStuffHex(ptr: QDPtr;
                         s : ARRAY OF CHAR);
    (* This procedure isolates the body of
       InitIcon from having to convert
       the Modula-style hex strings to
       Pascal format *)
      VAR
 macStr : Str255;
    BEGIN
      StrModToMac(macStr,s);
      StuffHex(ptr,macStr);
    END MyStuffHex;

  BEGIN
    (* Picture of a Lisa hoisted from
        Apple's QDSample program *)
    MyStuffHex(ADR(icon[ 0]),
'000000000000000000000000000000000000001FFFFFFFFC');
    MyStuffHex(ADR(icon[12]),
'00600000000601800000000B0600000000130FFFFFFFFFA3');
  MyStuffHex(ADR(icon[24]),
'18000000004311FFFFF00023120000080F231200000BF923');
    MyStuffHex(ADR(icon[36]),
'120000080F23120000080023120000080023120000080F23');
    MyStuffHex(ADR(icon[48]),
'1200000BF923120000080F2312000008002311FFFFF00023');
    MyStuffHex(ADR(icon[60]),
'08000000004307FFFFFFFFA30100000000260FFFFFFFFE2C');
    MyStuffHex(ADR(icon[72]),
'18000000013832AAAAA8A9F0655555515380C2AAAA82A580');
    MyStuffHex(ADR(icon[84]),
'800000000980FFFFFFFFF300800000001600FFFFFFFFFC00');
  END InitIcon;

  PROCEDURE DrawIcon(h,v: INTEGER;  mode : INTEGER);
    VAR
      srcBits : BitMap;
      srcRect, dstRect : Rect;
  BEGIN
    srcBits.baseAddr := ADR(icon);
    srcBits.rowBytes := 6;
    SetRect(srcBits.bounds,0,0,48,32);
    srcRect := srcBits.bounds;
    dstRect := srcRect;
    OffsetRect(dstRect,h,v);
    CopyBits(srcBits,thePort^.portBits,
                  srcRect,dstRect,mode,NIL);
  END DrawIcon;

  PROCEDURE MoveIcon;
  BEGIN
    (* Erase the old icon *)
    DrawIcon (x[screen],y[screen], srcBic);
    (* Calculate new position *)
    x[screen] := x[1-screen] + xDir;
    (* Don't let icon go off screen *)
    IF (x[screen] < 0) OR (x[screen] > 460) 
    THEN
      xDir := -xDir;
    END;
    y[screen] := y[1-screen] + yDir;
    IF (y[screen] < 0) OR (y[screen] > 310) 
    THEN
      yDir := -yDir;
    END;
    (* Draw the icon *)
    DrawIcon(x[screen],y[screen],srcOr);
    (* Swap our screen reminder *)
    screen := 1 - screen;
  END MoveIcon;
  
BEGIN
  HideCursor;
  (* Re-launch ourself with alt. screen *)
  LaunchWithTwoScreens;
  InitIcon;
  Write(14c); (* Clear Screen *)
  CopyScreens;
  screen := 0;
  x[0] := 100;
  y[0] := 100;
  x[1] := 100;
  y[1] := 100;
  xDir := 1;
  yDir := 1;
  WHILE NOT Button() DO
    MoveIcon;
    SwitchScreens;
  END;
END Animate.
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Spotify 1.0.53.758. - Stream music, crea...
Spotify is a streaming music service that gives you on-demand access to millions of songs. Whether you like driving rock, silky R&B, or grandiose classical music, Spotify's massive catalogue puts... Read more
beaTunes 4.6.14 - Organize your music co...
beaTunes is a full-featured music player and organizational tool for music collections. How well organized is your music library? Are your artists always spelled the same way? Any R.E.M. vs REM?... Read more
Vienna 3.1.10 :d05d7a5d: - RSS and Atom...
Vienna is a freeware and Open-Source RSS/Atom newsreader with article storage and management via a SQLite database, written in Objective-C and Cocoa, for the OS X operating system. It provides... Read more
Day One 2.1.8 - Maintain a daily journal...
Day One is the easiest and best-looking way to use a journal / diary / text-logging application for the Mac. Day One is well designed and extremely focused to encourage you to write more through... Read more
iDefrag 5.1.8 - Disk defragmentation and...
iDefrag helps defragment and optimize your disk for improved performance. Features include: Supports HFS and HFS+ (Mac OS Extended). Supports case sensitive and journaled filesystems. Supports... Read more
Arq 5.7.9 - Online backup to Google Driv...
Arq is super-easy online backup for Mac and Windows computers. Back up to your own cloud account (Amazon Cloud Drive, Google Drive, Dropbox, OneDrive, Google Cloud Storage, any S3-compatible server... Read more
VirtualBox 5.1.20 - x86 virtualization s...
VirtualBox is a family of powerful x86 virtualization products for enterprise as well as home use. Not only is VirtualBox an extremely feature rich, high performance product for enterprise customers... Read more
beaTunes 4.6.14 - Organize your music co...
beaTunes is a full-featured music player and organizational tool for music collections. How well organized is your music library? Are your artists always spelled the same way? Any R.E.M. vs REM?... Read more
iDefrag 5.1.8 - Disk defragmentation and...
iDefrag helps defragment and optimize your disk for improved performance. Features include: Supports HFS and HFS+ (Mac OS Extended). Supports case sensitive and journaled filesystems. Supports... Read more
Day One 2.1.8 - Maintain a daily journal...
Day One is the easiest and best-looking way to use a journal / diary / text-logging application for the Mac. Day One is well designed and extremely focused to encourage you to write more through... Read more

Latest Forum Discussions

See All

Blizzard is looking to hire a mobile dev...
A new thread on the popular video game rumor forum, NeoGAF, uncovered an interesting job listing over at Blizzard Entertainment. It appears the studio behindStarCraft, World of WarCraft, Hearthstone,andOverwatch is looking to bring on a new hire... | Read more »
Legend of Zelda meets Cooking Mama in ne...
Dungeon Chef is what happens when you mix the RPG elements (and style) of a Legend of Zelda game, with cooking elements. Although, now that The Legend of Zelda: Breath of the Wild also has cookingelements, so maybe the gameplay is not so novel.... | Read more »
ChordFlow (Music)
ChordFlow 1.0.0 Device: iOS Universal Category: Music Price: $6.99, Version: 1.0.0 (iTunes) Description: ChordFlow is a chord sequencer with a unique 4-track polyphonic arpeggiator, extensive chord library, MIDI out and Ableton Link... | Read more »
The Walking Dead: A New Frontier is out...
The newest season of Telltale Games'The Walking Dead is well underway. After the release of the third episode, "Above the Law" about a month ago, episode four, "Thicker Than Water" is hot and ready for more zombies and gut-wrenching emotional... | Read more »
Best games we played this week
Another week, another new wave of mobile games do dive into. We've dug through the list of apps that came out this week to tell you which apps are worth your sweet time. And while there weren't too many games this week, there were some big ones.... | Read more »
Vignettes (Games)
Vignettes 1.0.1 Device: iOS Universal Category: Games Price: $2.99, Version: 1.0.1 (iTunes) Description: Vignettes is a casual but unique exploration game without text or characters, where objects shapeshift as you spin them around... | Read more »
Get Me Outta Here is an 80s retro shoote...
Are you ready to fight some aliens? Because Crescent Moon Games has released the retro shooter Get Me Outta Here on iOS devices today. [Read more] | Read more »
Get a bunch of Apple productivity apps f...
If you're an Apple Mac owner, you're probably aware of the host of Apple productivity apps the company includes in all new Mac purchases. Apps like iMovie, Keynote, and of course, GarageBand. While you used to be able to also buy these apps... | Read more »
Terra Mystica (Games)
Terra Mystica 1.03 Device: iOS Universal Category: Games Price: $9.99, Version: 1.03 (iTunes) Description: Short Summary:≈≈≈≈≈≈≈≈≈≈≈≈≈ | Read more »
Ms. Spell (Games)
Ms. Spell 1.0 Device: iOS Universal Category: Games Price: $.99, Version: 1.0 (iTunes) Description: Cast spells and battle monsters in this turn based game, that has you delving into ever the changing Dreadwood to retrieve the lost... | Read more »

Price Scanner via MacPrices.net

15-inch Touch Bar MacBook Pros, Apple refurbi...
Apple is offering Certified Refurbished 2016 15″ Touch Bar MacBook Pros for $360 to $420 off original MSRP. An Apple one-year warranty is included with each model, and shipping is free: - 15″ 2.6GHz... Read more
13-inch MacBook Airs on sale for up to $150 o...
Overstock.com has 13″ MacBook Airs on sale for up to $150 off MSRP including free shipping: - 13″ 1.6GHz/128GB MacBook Air (sku MMGF2LL/A): $869.99 $130 off MSRP - 13″ 1.6GHz/256GB MacBook Air (sku... Read more
15-inch Touch Bar MacBook Pros on sale for $1...
B&H Photo has the new 2016 15″ Apple Touch Bar MacBook Pros in stock today and on sale for up to $200 off MSRP. Shipping is free, and B&H charges NY sales tax only: - 15″ 2.7GHz Touch Bar... Read more
15-inch 2.7GHz Touch Bar MacBook Pros on sale...
Amazon has 2016 15″ 2.7GHz Apple Touch Bar MacBook Pros in stock today and on sale for $150-$200 off MSRP. Shipping is free: - 15″ 2.7GHz Touch Bar MacBook Pro Space Gray (sku MLH42LL/A): $2599 $200... Read more
Apple now offering Certified Refurbished 13-i...
Apple is now offering Certified Refurbished 2016 13″ Touch Bar MacBook Pros for $270-$300 off original MSRP. An Apple one-year warranty is included with each model, and shipping is free: - 13″ 2.9GHz... Read more
MyGiHealth Digestive Symptom Tracker Version...
My Total Health, Inc. has announced the release of MyGiHealth 2.1, an important update to their digestive symptom tracker developed exclusively for iPhone, iPad and iPod touch devices. MyGiHealth is... Read more
Galaxy S8 Materials Costs Highest by Far Comp...
The new Samsung Galaxy S8 equipped with 64 gigabytes (GB) of NAND flash memory carries a bill of materials (BOM) cost that comes out to US$301.60, much higher than for previous versions of the... Read more
iCarMode 4.0 Car Dashboard App For iOS Integr...
Indie developer Diego Resnik has announced the release of iCarMode 4.0, an update to his productivity app developed for iOS devices. iCarMode has positioned itself as a true car dashboard app,... Read more
How to save $150+ on Apple’s 13-inch 2.0GHz n...
Apple Authorized Reseller B&H Photo has non-Touch Bar 13″ 2.0GHz MacBook Pros on sale for $150 off MSRP for a limited time. Shipping is free, and B&H charges NY sales tax only: - 13″ 2.0GHz... Read more
15-inch 2.2GHz Retina MacBook Pro, Apple refu...
Apple has Certified Refurbished 2015 15″ 2.2GHz Retina MacBook Pros available for $1699. That’s $300 off MSRP, and it’s the lowest price available for a 15″ MacBook Pro. An Apple one-year warranty is... Read more

Jobs Board

*Apple* Mac Computer Technician - GeekHampto...
…complex computer issues over the phone and in person? GeekHampton, Long Island's Apple Premium Service Provider, is looking for you! Come work with our crew Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
Music Marketing Lead, iTunes & *Apple*...
# Music Marketing Lead, iTunes & Apple Music Job Number: 56868140 Culver City, California, United States Posted: Apr. 17, 2017 Weekly Hours: 40.00 **Job Summary** Read more
*Apple* Media Products - Commerce Engineerin...
Apple Media Products - Commerce Engineering Manager Job Number: 57037480 Santa Clara Valley, California, United States Posted: Apr. 18, 2017 Weekly Hours: 40.00 Job Read more
*Apple* Mac Computer Technician - GeekHampto...
…complex computer issues over the phone and in person? GeekHampton, Long Island's Apple Premium Service Provider, is looking for you! Come work with our crew Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.