"Using the Alternate Screen Buffer"

By Tom Taylor, Software Engineer, Modula-2 Corp., Provo, Ut., MacTutor Contributing Editor

This article discusses the "alternate screen" capabilities of the Macintosh and presents a module that allows easy access to this facility from MacModula-2.

The Alternate Screen

As far as I know, Inside Macintosh only mentions the alternate screen buffer in two places: in the Memory Manager Programmer's Guide and in the Segment Loader Programmer's Guide. The Memory Manager section simply says, "There are alternate screen and sound buffers for special applications. If you use either or both of these, the space available for use by your application is reduced accordingly..." The alternate screen buffer can be used for high-speed flicker free graphics or a slide show program. For example, an application can be drawing in one screen while displaying a different screen. The popular "Tumbling Mac" demo by Mainstay uses the alternate screen buffer to create a high-speed flicker-free animation application. According to figure 1, the alternate screen buffer is allocated 32768 bytes below the main screen buffer.

Figure 1. Partial memory map showing sizes of various buffers.

The Segment Loader section mentions that the Chain and Launch traps configure memory for the sound and screen buffers. Whenever one of these traps is called, a parameter is passed that determines how these buffers are set up. The word (16-bit) parameter has three possible values:

Zero - Only the main sound and screen buffers are allocated. This is the normal situation and gives an application the most possible memory.

Negative - The alternate sound buffer and main screen buffer is allocated.

Positive - Both the alternate sound and screen buffers are allocated.

A Screen Switcher Module

Instead of building a specific program to demonstrate the alternate screen in Modula-2, this article presents a library module that can be used in many different programs in many different types of applications. This article will also present a small program that uses the developed screen switcher module.

A screen switcher module should support at least four functions:

• launch a program with the alternate screen,

• copy the main screen into the alternate screen,

• change the screen back and forth between the main and alternate screens, and

• set the screen buffer to the main screen before a program exits.

Apparently, the Finder always launches a program with the main sound and screen buffers (parameter set to 0). In order for a program to use the alternate screen, the program must be re-launched with the appropriate parameter (-1). The procedure LaunchWithAltScreen re-launches the program with the alternate screen if the alternate screen is not already allocated.

Here are the Definition and Implementation modules for handling the alternate screen:

DEFINITION MODULE ScreenSwitcher;

  EXPORT QUALIFIED
    LaunchWithTwoScreens,
    CopyScreens,
    SwitchScreens,
    SetMainScreen;
  
  PROCEDURE LaunchWithTwoScreens;
    (* This procedure re-launches the
       current program with the alternate
       screen.  If the alternate screen is
       already installed, this procedure 
       does nothing. *)

  PROCEDURE CopyScreens;
    (* CopyScreens copies the main screen
       into the alternate screen. *)
  
  PROCEDURE SwitchScreens;
    (* SwitchScreens alternately switches
       what is being displayed from the
       one screen to the other. *)
  
  PROCEDURE SetMainScreen;
    (* Sets the current screen buffer to
       the main screen so that when the
       program exits to the Finder
       the screen will be the right one. *)
  
END ScreenSwitcher.

IMPLEMENTATION MODULE ScreenSwitcher;

  FROM Launcher IMPORT
          CountAppFiles,
   LaunchRec,
   Launch;

  FROM Terminal IMPORT
          WriteString;

  FROM MacSystemTypes IMPORT
          Str255, LongCard;

  FROM Strings IMPORT
          StrModToMac;

  FROM SYSTEM IMPORT
          ADR, WORD, ADDRESS;

  FROM MacInterface IMPORT
          thePort;

  FROM QuickDraw1 IMPORT
          GrafPtr;

  CONST
    vBufA = 1e00h; (* Buffer A offset from
                                VIA interface chip *)
    vPage2 = 1;    (* This is a bit into
                              vBufA, if 0, select
                              alternate screen *)

  TYPE
    ScreenPtr
        = POINTER TO ARRAY [1..10944] OF
                 WORD;
      (* The Mac screen buffer is 10944
           16-bit words long *)

    FlagsPtr
        = POINTER TO BITSET;

  VAR
    CurPageOption [936h] : INTEGER;
       (* Mac global variable containing
           value of parameter at launch time
           that determines sound and screen
           buffers. *)
    ScrnBase [824h] : ScreenPtr;
       (* Mac global containing address of
           main screen. *)
    AltBase : ScreenPtr;
       (* Our homebrew alternate screen
            pointer. *)
    VIA6522Chip [1d4h] : FlagsPtr;
       (* VIA base address - from MDS's
           SysEqu.txt *)
    BufferA : FlagsPtr;
       (* Our pointer to vBuffer A *)
    originalPort  : GrafPtr;
       (* Save GrafPtr to whole screen *)

  PROCEDURE LaunchWithTwoScreens;
    VAR
      PrintOrWhat, count : INTEGER;
      launchRec : LaunchRec;
      prog : Str255;
  BEGIN
    IF CurPageOption >= 0 THEN
      CountAppFiles(PrintOrWhat,count);
        (* Get the number of Modula-2
            programs launched.  It better
            be one... this one! *)
      IF count # 1 THEN
        WriteString('Double-click the ');
        WriteString('program icon to start');
        WriteString(' the program');
        HALT;
      END;
      StrModToMac(prog,'Modula-2');
      launchRec.Name := ADR(prog);
      launchRec.SoundScreenBuffer := -1;
      Launch(launchRec);
    END;
  END LaunchWithTwoScreens;
  
  PROCEDURE CopyScreens;
  BEGIN
    AltBase^ := ScrnBase^;
  END CopyScreens;
  
  PROCEDURE SwitchScreens;
  BEGIN
    (* According to the MDS SysEqu.Txt
        file, the vPage2 bit in the BufferA
        flags is zero for the alternate
        screen and one for the main screen.
     *)
    WITH originalPort^.portBits DO
      IF baseAddr = ADDRESS(ScrnBase)
      THEN
          (* Graphical operations apply
              to alternate screen while
              displaying main screen. *)
 baseAddr := ADDRESS(AltBase);
 INCL(BufferA^,vPage2);
          (* Turn on bit *)
      ELSE
          (* Graphical operations apply
              to main screen while displaying
              alternate screen. *)
 baseAddr := ADDRESS(ScrnBase);
 EXCL(BufferA^,vPage2);
          (* Turn off  bit *)
      END;
    END;
  END SwitchScreens;
  
  PROCEDURE SetMainScreen;
  BEGIN
    IF NOT(vPage2 IN BufferA^) THEN
      SwitchScreens;
    END;
  END SetMainScreen;

BEGIN
  AltBase := ScrnBase;
   (* Set up pointer to alt screen *)
  DEC(AltBase,32768);
  
  BufferA := VIA6522Chip;
   (* Set up pointer to Buffer A flags *)
  INC(BufferA,vBufA);
  
   (* Save screen GrafPort *)
  originalPort := thePort;
END ScreenSwitcher.

            Here is a program module that actually uses the ScreenSwitcher module.  The 
program simply bounces a picture of a Lisa computer around the screen.  The program draws 
the picture in one screen, switches screens, erases the old picture, moves to a new position, 
draws the picture, and switches to the other screen and applies the same sequence of operations. 
 In order for this program to run properly, it is important to have this program and the 
Modula-2 program on the system disk.  Click the mouse to exit the program.

MODULE Animate;

  FROM QuickDraw1 IMPORT
          QDPtr, StuffHex, HideCursor,
          BitMap, Rect, SetRect,
          srcOr, srcBic, OffsetRect,
          Random;

  FROM QuickDraw2 IMPORT
          CopyBits;
   
  FROM MacSystemTypes IMPORT
          Str255;
   
  FROM Strings IMPORT
          StrModToMac;

  FROM SYSTEM IMPORT
          ADR, WORD;

  FROM MacInterface IMPORT
          thePort, Write;

  FROM EventManager IMPORT
          Button;

  FROM ScreenSwitcher IMPORT
          LaunchWithTwoScreens,
          CopyScreens, SwitchScreens;

  VAR
    icon : ARRAY [0..95] OF WORD;
       (* Storage to hold icon data *)
    x, y : ARRAY [0..1] OF INTEGER;
       (* coordinates of icon for each
           screen *)
    screen : [0..1];
       (* current screen reminder *)
    xDir, yDir : INTEGER;
       (* offset for each icon move *)
 
  PROCEDURE InitIcon;

    PROCEDURE MyStuffHex(ptr: QDPtr;
                         s : ARRAY OF CHAR);
    (* This procedure isolates the body of
       InitIcon from having to convert
       the Modula-style hex strings to
       Pascal format *)
      VAR
 macStr : Str255;
    BEGIN
      StrModToMac(macStr,s);
      StuffHex(ptr,macStr);
    END MyStuffHex;

  BEGIN
    (* Picture of a Lisa hoisted from
        Apple's QDSample program *)
    MyStuffHex(ADR(icon[ 0]),
'000000000000000000000000000000000000001FFFFFFFFC');
    MyStuffHex(ADR(icon[12]),
'00600000000601800000000B0600000000130FFFFFFFFFA3');
  MyStuffHex(ADR(icon[24]),
'18000000004311FFFFF00023120000080F231200000BF923');
    MyStuffHex(ADR(icon[36]),
'120000080F23120000080023120000080023120000080F23');
    MyStuffHex(ADR(icon[48]),
'1200000BF923120000080F2312000008002311FFFFF00023');
    MyStuffHex(ADR(icon[60]),
'08000000004307FFFFFFFFA30100000000260FFFFFFFFE2C');
    MyStuffHex(ADR(icon[72]),
'18000000013832AAAAA8A9F0655555515380C2AAAA82A580');
    MyStuffHex(ADR(icon[84]),
'800000000980FFFFFFFFF300800000001600FFFFFFFFFC00');
  END InitIcon;

  PROCEDURE DrawIcon(h,v: INTEGER;  mode : INTEGER);
    VAR
      srcBits : BitMap;
      srcRect, dstRect : Rect;
  BEGIN
    srcBits.baseAddr := ADR(icon);
    srcBits.rowBytes := 6;
    SetRect(srcBits.bounds,0,0,48,32);
    srcRect := srcBits.bounds;
    dstRect := srcRect;
    OffsetRect(dstRect,h,v);
    CopyBits(srcBits,thePort^.portBits,
                  srcRect,dstRect,mode,NIL);
  END DrawIcon;

  PROCEDURE MoveIcon;
  BEGIN
    (* Erase the old icon *)
    DrawIcon (x[screen],y[screen], srcBic);
    (* Calculate new position *)
    x[screen] := x[1-screen] + xDir;
    (* Don't let icon go off screen *)
    IF (x[screen] < 0) OR (x[screen] > 460) 
    THEN
      xDir := -xDir;
    END;
    y[screen] := y[1-screen] + yDir;
    IF (y[screen] < 0) OR (y[screen] > 310) 
    THEN
      yDir := -yDir;
    END;
    (* Draw the icon *)
    DrawIcon(x[screen],y[screen],srcOr);
    (* Swap our screen reminder *)
    screen := 1 - screen;
  END MoveIcon;
  
BEGIN
  HideCursor;
  (* Re-launch ourself with alt. screen *)
  LaunchWithTwoScreens;
  InitIcon;
  Write(14c); (* Clear Screen *)
  CopyScreens;
  screen := 0;
  x[0] := 100;
  y[0] := 100;
  x[1] := 100;
  y[1] := 100;
  xDir := 1;
  yDir := 1;
  WHILE NOT Button() DO
    MoveIcon;
    SwitchScreens;
  END;
END Animate.