“Alphabet Soup”

By Dave Kelly

“Alphabet Soup”

Welcome to Basic School! This article is dedicated to those of us that enjoy programming in Basic. Programmers of structured languages have put Basic down for several years because it is not considered a structured programming language and many implementations of Basic lack enhancements which give it power to perform advanced functions. Also it has been said many times that it is much harder to follow the program flow in Basic than in other languages like Pascal. Those who complain about the limitations of Basic are sometimes quite justified in their complaints. After all, basic “BASIC” isn’t very powerful and not very flexible at all. Any enhancement at all is an improvement. This has been the caseup until now. Now, the enhancements that we find in Macintosh Basic are approaching the power of the more acceptable high level languages such as Pascal. Exploring Macintosh Basic computing power is what this column is all about.

In the last few months we have seen the evolution of the programming tools needed to program the Mac on the Mac. In the coming issues, we will explore the enhancements included in the new MacBasic and in Microsoft Basic Version 2.0. At the writing of this article Microsoft tells me that they intend to release Microsoft Basic Version 2.0 by the end of October or sometime in November. I’m told that it includes many enhancements which in my opinion should have been included from the very first introduction of Microsoft Basic to the Macintosh world. These enhancements include programmable windows, menus, scrolling, sound and sound effects, compatability with MacWrite, complete mouse control, editing, debugging, access to most if not all of the Mac internal ROM routines, and elimination of the need for line numbers. This is what I call programming made easy. From what I’ve seen so far, there will be quite a competition between MacBasic and Microsoft Basic 2.0 in the coming months.

The Mac Basic listing shows an example of the ease in documenting a program as it is written. I originally wrote the program in Microsoft Basic version 1.0 as an educational tool for my 2 year old to learn his alphabet. The program prints the alphabet and then prompts the user to find each letter one at a time.Then the user points to the letter with the mouse and presses the mouse button. By using variable names that show what is happening and by the use of line labels the program requires little documentation. When I write programs, I rarely have the time to finish up with documentation especially when my 2 year-old can’t wait to start the game. The use of these labels will be familiar to anyone who has used Basic on the Hewlett Packard 9826-36 series computers. The label name is used in each of the gosub statements in place of the line numbers. This makes the use of line numbers unnecessary. The coresponding label name also appears at the beginning of the subroutine followed by a colon. By indenting the text of the program within each subroutine, it is clear where the subroutine starts and ends and the label gives a clue as to what each subroutine does.

Next month we will explore Basic programming on the Mac in more detail.

10 ‘*********************************
20 ‘         Alphabet Soup
30 ‘         By David Kelly
40 ‘         MS Basic Version 1.0
70 ‘*********************************
1000 DIM TOP%(26),BOT%(26),RGT%(26),LFT%(26)
1010 FOR LETTER%=1 TO 26
1020       READ LFT%(LETTER%), TOP%(LETTER%), RGT%(LETTER%), BOT%(LETTER%)
1030 NEXT LETTER%
1040 GOSUB 1090:   ‘ Print_alphabet
1050 FOR LETTER%=ASC(“A”) TO ASC(“Z”)
1060       GOSUB 1200: ‘Ask_for_letter
1070 NEXT LETTER%
1080 CALL TEXTMODE(0):CALL TEXTFACE(0):CALL TEXTFONT(1):CALL TEXTSIZE(12):END

1090 ‘ Print_alphabet to screen
1100 CLS :  ‘Clearwindow
1110 CALL TEXTFONT(2): ‘ Set to New York Font
1120 CALL TEXTSIZE(24): ‘ Set Font size to 24
1130 CALL TEXTMODE(2): ‘Sets screen to XOR
1140 CALL TEXTFACE(0): ‘Sets face to plain style
1150 FOR LETTER% = 1 TO 26
1160  CALL MOVETO(LFT%(LETTER%),BOT%(LETTER%)):PRINT CHR$(ASC(“A”)-1+LETTER%)
1170 NEXT LETTER%
1180 CALL TEXTSIZE(12):  ‘Set font size to 12
1190 RETURN

1200 ‘ Ask_for_letter
1210 CALL MOVETO (125,175):PRINT “Find the letter: “;
1220 CALL TEXTSIZE(24): ‘Set Font size to 24
1230 CALL TEXTMODE(0)
1240 PRINT “ “;CHR$(LETTER%)
1250 CALL TEXTSIZE(12)
1260 CALL PENMODE(10)

1270 IF MOUSE(0)=0 THEN 1270: ‘button wait
1280 X2=MOUSE(1): Y2=MOUSE(2)
1290 CALL MOVETO(238,168):CALL LINETO(X2,Y2)
1300 IF MOUSE(0)<0 THEN 1300
1310 IF (X2<LFT%(LETTER%-64) OR X2>RGT%(LETTER%-64) OR Y2< TOP%(LETTER%-64) 
OR Y2 >BOT%(LETTER%-64)) THEN FLAG%=1 ELSE FLAG%=0

1320 CALL PENMODE(14):PATTERN%(0)=0:CALL PENPAT(VARPTR(PATTERN%(0)))
1330 CALL MOVETO(238,168): CALL LINETO(X2,Y2):CALL PENNORMAL
1340 CALL TEXTMODE(0):IF FLAG% =1 THEN 1210
1350 BEEP:BEEP
1360 RETURN

1370 DATA 36,20,52,74           :’A data
1380 DATA 72,20,84,74           :’B data
1390 DATA 103,20,115,74       :’C data
1400 DATA 133,20,147,74       :’D data
1410 DATA 165,20,176,74       :’E data
1420 DATA 195,20,207,74       :’F data
1430 DATA 225,20,239,74      :’G data
1440 DATA 257,20,272,74       :’H data
1450 DATA 290,20,315,74       :’I data
1460 DATA 330,20,350,74       :’J data
1470 DATA 369,20,383,74       :’K data
1480 DATA 401,20,414,74       :’L data
1490 DATA 434,20,454,74       :’M data
1500 DATA 35,75,51,120         :’N data
1510 DATA 69,75,83,120         :’O data
1520 DATA 101,75,115,120     :’P data
1530 DATA 133,75,147,120     :’Q data
1540 DATA 165,75,179,120     :’R data
1550 DATA 197,75,208,120     :’S data
1560 DATA 227,75,240,120     :’T data
1570 DATA 259,75,275,120     :’U data
1580 DATA 294,75,310,120     :’V data
1590 DATA 329,75,352,120     :’W data
1600 DATA 371,75,385,120     :’X data
1610 DATA 402,75,417,120     :’Y data
1620 DATA 434,75,445,120     :’Z data