TweetFollow Us on Twitter

January 90 - BRAVING OFFSCREEN WORLDS

BRAVING OFFSCREEN WORLDS

GUILLERMO ORTIZ

No one disputes the benefits of using offscreen environments to prepare and keep the contents of windows. The only problem is that creating such environments--from a simple pixMap to a more complicated GDevice--can be rather difficult. 32-Bit QuickDraw includes a set of calls that allows an application to create offscreen worlds easily and effectively. This article describes those calls and provides details on how to use them.

Until now, creating and maintaining offscreen devices or ports has been complicated and confusing at best. As part of 32-Bit QuickDraw, Apple's engineering team has included a set of calls that makes creating and maintaining offscreen devices and ports a real breeze. Using the offscreen graphics environment, QuickDraw can maintain the data alignment necessary to improve the performance of CopyBits when you use it to display onscreen the contents of the offscreen buffer.

Also, applications using the offscreen world support from QuickDraw are more likely to benefit from future enhancements to QuickDraw than programs doing their own offscreen management. This can save you a lot of time down the road.

The offscreen world offers a few more benefits:

  • The system takes care of all the messy details involved in creating the offscreen GDevice. You don't need to bother asking "What flags should I set?" or "What is the refNum for an offscreen device?"
  • You can tailor the offscreen port according to your specifications rather than being restricted to screenBits.bounds. Because the visRgn comes set to the right dimensions, you won't need to change anything.
  • The pixMap associated with the offscreen world comes back from the call complete and ready to use. You won't have to lose sleep wondering if you set the correct value for rowBytes or if your baseAddress pointer has less memory than it should because the compiler didn't do the multiplication using Longs.

Think of the GWorld structure as an extension to the CGrafPort structure, containing the port information along with the device data and some extra state information. In most cases, a GWorldPtr can be used interchangeably with a CGrafPtr, which makes converting applications quite easy. At this point, however, Apple is keeping the structure of an offscreen graphics world private to allow for further expansion.

For instance, in the following section of Developer Technical Support's sample program FracApp, the new calls were implemented without changing the document's data structure at all. This example illustrates the difference the new set of calls can make when creating offscreen environments.

A LOOK AT THE NEW CALLS

Let's use a section of the sample program FracApp to illustrate the difference this new set of calls can make when creating offscreen environments. The procedure TFracAppDocument.BuildOffWorld creates a new device and its accompanying structures for each document. Here is the original code, with comments shortened, followed by the equivalent code using the new calls:
PROCEDURE  TFracAppDocument.BuildOffWorld (sizeOfDoc: Rect);
VAR oldPerm:    Boolean;
        dummy:  Boolean;
        docW, docH: LongInt;
        fi:     FailInfo;
        currDevice: GDHandle;
        currPort:   GrafPtr;
        Erry:   OSErr;
    
    PROCEDURE DeathBuildOff (error: OSErr; message: LONGINT);
    {Error handler}

    BEGIN
        oldPerm := PermAllocation (oldPerm);    
        { Set memory back to previous. }
        
        SetGDevice (currDevice);    
        { Set device back to main, just in case. }
        SetPort (currPort);
    END;

BEGIN
    currDevice := GetGDevice;   { save current for error handling. }
    GetPort(currPort);
    
    oldPerm := PermAllocation (TRUE);

    CatchFailures(fi, DeathBuildOff);   { any failures, must be }
                                        { cleaned up. }

    { Let's set up the size of the rectangle we are using for the }
    { document. }
    docW := sizeOfDoc.right - sizeOfDoc.left;
    docH := sizeOfDoc.bottom - sizeOfDoc.top;


    { Now try to set up the offscreen bitMap (color). }
    fBigBuff := NewPtr (docW * docH);
    FailMemError;       { couldn't get it we die. }


    { OK, now we get wacko.  We need to create our own gDevice, }
            
    fDrawingDevice := NewGDevice (0, -1);  { -1 means unphysical }
                                           { device.  }
    FailNIL (fDrawingDevice);       { If we failed, error out. }
    
    { Now init all the fields in the gDevice Record, since it comes }
    { uninitialized. }
    HLock ( Handle(fDrawingDevice) );
    WITH  fDrawingDevice^^  DO  BEGIN
        gdId := 0;  { no ID for search & complement procs }
        gdType := clutType;     { color table type fer sure. }
        
        DisposCTable (gdPMap^^.pmTable);  { kill the stub that is }
                                          { there. }
        gdPMap^^.pmTable := gOurColors;   { make a copy of our }
                                          { global color table. }
        Erry := HandToHand (Handle(gdPMap^^.pmTable));
        FailOSErr (Erry);   { if not possible, blow out. }
        
        { build a new iTable for this device }
        MakeITable (gdPMap^^.pmTable, gdITable, 3);
        FailOSErr (QDError);{ no memory, we can leave here. }
        
        gdResPref := 3;{ preferred resolution in table. }
        gdSearchProc := NIL; { no search proc. }
        gdCompProc := NIL;  { no complement proc. }
        { Set the gdFlags }
        gdFlags := 2**0 + 2**10 + 2**14 + 2**15;  { set each bit we }
                                                  { need. }
        
        { Now set up the fields in the offscreen PixMap }
        gdPMap^^.baseAddr := fBigBuff;  { The base address is our }
                                        { buffer. }
        gdPMap^^.bounds := sizeOfDoc;   { bounding rectangle to our }
                                        { device. }

        gdPMap^^.rowBytes := docW + $8000;
        gdPMap^^.pixelSize := 8;
        gdPMap^^.cmpCount := 1;
        gdPMap^^.cmpSize := 8;
        
        gdRect := sizeOfDoc;  { the bounding rectangle for gDevice, }
                              { too. }
    END;        { With fDrawingDevice }
        
    HUnLock ( Handle(fDrawingDevice) );

    { Yow, that was rough.}
    SetGDevice (fDrawingDevice);
    

    fDrawingPort := CGrafPtr( NewPtr (SizeOf (CGrafPort)) );
                                               { addr CPort record. }
    FailNil (fDrawingPort); { didn't get it, means we die. }
    
    { Now the world is created }
    dummy := PermAllocation (FALSE);

    OpenCPort (fDrawingPort);   { make a new port offscreen. }
    FailNoReserve;      { Make reserve, die if we can't }
        
    { QuickDraw is most obnoxious about making a port that is bigger
    than the screen, so we need to modify the visRgn to make it as
    big as our full page document }
    RectRgn(fDrawingPort^.visRgn, sizeOfDoc);

    fDrawingPort^.portRect := sizeOfDoc;

    { OK, we have a nice new color port that is offscreen. }
    Success (fi);

    oldPerm := PermAllocation (oldPerm);

    { Now we have the offscreen PixMap, we need to initialize it to
    white. }
    SetPort (GrafPtr(fDrawingPort));
    EraseRect (sizeOfDoc);      { clear the bits. }

    SetGDevice (currDevice);
    SetPort (currPort);
END;    { BuildOffWorld }

Now let's see what the equivalent code looks like when we use the calls provided by 32-Bit QuickDraw and its offscreen support:

PROCEDURE TFracAppDocument.BuildOffWorld(sizeOfDoc:RECT); 
VAR oldPerm :Boolean;
        fi  :FailInfo;
        currDev :GDHandle;
        currPort    :CGrafPtr;
        erry    :QDErr;
        
    PROCEDURE DeathBuildOff (error: OSErr; message:LONGINT);
    
    BEGIN
        oldPerm := PermAllocation(oldPerm);
        SetGWorld (currPort,  currDev); 
    END;
    
BEGIN  (*myBuildOffWorld*)
    GetGWorld(currPort,  currDev);
    CatchFailures(fi, DeathDocument);
    Erry := NewGWorld(fDrawingPort, 8, sizeOfDoc, gOurColors, NIL,
        GWorldFlags(0));
    FailOSErr(Erry);
    
    SetGWorld (fDrawingPort,  NIL); 
    
    IF ( NOT LockPixels(fDrawingPort^.portPixMap) ) THEN
    FailOSErr(QDError);
    
        EraseRect(FDrawingPort^.portRect);
    
    UnlockPixels (fDrawingPort^.portPixMap); 
    
    SetGWorld (currPort,  currDev); 
END {myBuildOffWorld};

CALLS YOU CAN'T DO WITHOUT

The new routines simplify the code and help prevent the typical errors you make having to initialize all those special fields. It only makes sense to make your work easier if you can. Here are the calls in the order they appear in the sample code:
PROCEDURE GetGWorld(VAR port:CGrafPtr; VAR gdh:GDHandle)

This call takes the place of two standard calls, GetPort and GetGDevice. It saves the current settings for later restoration and works for offscreen worlds as well as old-style ports.

  • port is set to the current port, which can be a GrafPtr, a CGrafPtr, or a GWorldPtr.
  • gdh returns the current device.
FUNCTION NewGWorld(VAR offscreenWorld: GWorldPtr; pixelDepth:
        INTEGER; boundsRect: Rect; cTable:CTabHandle;
        aGDevice: GDHandle; flags: GWorldFlags): QDErr;

This is the call that does the work. If the function returns noErr, then offscreenWorld contains a pointer to the newly created offscreen environment. If the function does not return noErr, then something didn't work. Most likely the Memory Manager couldn't allocate enough memory for all the structures. In that case, your program has to decide what to do next, such as draw to the window's port, sacrificing speed, features, or both.

Possible error returns other than noErr are cDepthErr (no such depth is possible), paramErr (illegal parameter), plus any Memory Manager or QuickDraw errors.

  • pixelDepth must be 1, 2, 4, 8, 16, or 32 bits per pixel. With one exception, other values will make the call return cDepthErr. pixelDepth can be 0, as described later in this article.
  • boundsRect is used to calculate the offscreen pixMap's size and coordinate system. It is also used to set portRect, pixMap bounds, gdRect, and the port's visRgn.
  • When it is provided, cTable is copied and the copy is used for the offscreen pixMap. If cTable is nil, then the system uses the default table for the desired depth.
  • When aGDevice is not nil and the noNewDevice flag is set, no new offscreen device is created. This is the case when you want to create an offscreen port but do not need the offscreen device. In our example, aGDevice is always nil because we want to keep a separate environment for each document being drawn, which requires a unique color table and inverse table, implying the need for individual devices.

    This is useful when, for example, an application has several offscreen worlds with similar characteristics, such as depth or color table. It is possible to allocate only one GWorld with an offscreen device and to use that offscreen device as a GDevice for all the other GWorlds. Be sure to avoid using one of the screen devices as a GDevice. If the user changes the characteristics of a screen device via the Control Panel, your offscreen world will become invalid.

    Note that aGDevice is used to create the offscreen graphics world only when noNewDevice is set and its pixelDepth is not 0. In any other instance, aGDevice should be set to nil.

    If pixelDepth is 0, boundsRect is used to find the deepest device that intersects the rectangle. Taken in global screen coordinates, the depth, color table, and inverse table of this device are used to set up the offscreen environment.

  • The flags parameter gives some control to the application for the creation of the new offscreen graphics environment. Currently the possible values are a combination of pixPurge and noNewDevice.

    If pixPurge is set, the offscreen buffer is created as a purgeable block. The effects of noNewDevice are the same, as discussed earlier.

FUNCTION GetGWorldDevice(offscreenWorld: GWorldPtr):GDHandle;

This call returns the GDevice associated with offscreenWorld, normally the offscreen device created with NewGWorld. If noNewDevice was used, however, the device returned will be the device passed to NewGWorld or UpdateGWorld.

PROCEDURE SetGWorld (port: CGrafPtr; gdh: GDHandle);

This call replaces SetPort and SetGDevice. If port is a GrafPtr or a CGrafPtr, then the current port is set to port and the current device is set to gdh. If port is a GWorldPtr, then the current port is set to port and the current device is set to the device attached to the offscreen graphics world.

As a rule of thumb, when you use the offscreen support provided with 32-Bit QuickDraw, you should use GetGWorld instead of GetPort and GetGDevice, and SetGWorld instead of SetPort and SetGDevice. Both calls are safe to use within the old-style environment and ensure proper behavior in the new.

If pixelDepth is 1,2,4,8,16, or 32 optimize for offscreen data depth boundsRect is a rectangle in local coordinates if cTable is nil NewGWorld uses default color table for given pixelDepth else NewGWorld attaches a copy of your cTable to your new GWorld if NoNewDevice flag is passed (see flags) aGDevice is used to create your new GWorld (aGDevice should not be a screen device) else aGDevice is ignored J.Z.

WHERE IS THE CATCH?

When using the offscreen world environment, you have to make sure that the pixMap is actually available and locked when you draw to or from an offscreen graphics world. This is why you must bracket any drawing action with LockPixels and UnlockPixels.

In our example, to anchor the offscreen pixMap, we need to call LockPixels just before calling EraseRect. When we are done, a call to UnlockPixels releases the buffer. These two calls are the only extra work offscreen support in 32-Bit QuickDraw demands.

FUNCTION LockPixels (pm: PixMapHandle):Boolean; 

Call this function prior to any drawing operation to or from the offscreen environment. A false value returned means the offscreen pixMap has been purged. A LockPixels result of false tells the application to either recreate the offscreen pixMap, using UpdateGWorld in the process, or draw directly to the target window.

PROCEDURE UnlockPixels (pm: PixMapHandle); 

When you finish drawing, you should call UnlockPixels. Just remember that all that is locked should be unlocked. Otherwise, strange things may happen. one more call you'll need

FUNCTION UpdateGWorld (VAR offscreenGWorld: GWorldPtr; pixelDepth:
    INTEGER; boundsRect: Rect; cTable: CTabHandle;
    aGDevice: GDHandle; flags: GWorldFlags): GWorldFlags;

This call reconstructs the offscreen environment according to the new boundsRect, cTable, and pixelDepth. These parameters work in large part the same way they do in NewGWorld.

When pixelDepth is 0, the device list is parsed again to find the deepest device intersecting boundsRect taken in global coordinates. If aGDevice is not nil, then pixelDepth and cTable are ignored and the fields from aGDevice are used offscreen. If the offscreen buffer has been purged, UpdateGWorld allocates a new one.

When necessary, the application can simply call UpdateGWorld to change the offscreen environment without having to recreate the offscreen image from scratch. This is the case, for example, when the user selects a different depth or the color table is modified somehow.

Keeping the offscreen world parallel to the conditions used to display the images to the user guarantees that when CopyBits is called to update a window, the operation will be performed at the highest speed. The controlling parameter flags can take the following values:

  • [] I know what I am doing--don't update the pixels for me.
  • [clipPix] If boundsRect is smaller than the current boundsRect, the bottom and right edges pixels are clipped out. If boundsRect is larger, the bottom and right edges are filled with the background color.
  • [stretchPix] If boundsRect is smaller, the image is reduced to the new size. If the rectangle is larger, the offscreen image is enlarged to fit the new area.
  • [clipPix, ditherPix] and [stretchPix, ditherPix] These provide error diffusion when necessary in addition to clipping or stretching.

Now if boundsRect is new but the same size, UpdateGWorld realigns the pixMap for best performance. With a new pixelDepth, the pixels are scaled to the new depth. If cTable is new as well, the pixels are mapped to the new colors.

Even for our engineers, some miracles are just too difficult. If the pixMap has been purged, it is reallocated, but the old contents are lost.

When UpdateGWorld returns, check its result, which will be of the GWorldflags variety. If gwFlagErr is set, that means the call was unsuccessful. The offscreen world has not changed, and some correcting action is required. The errors might be cDepthErr (no such depth is possible), paramErr (illegal parameters), and any Memory Manager or QuickDraw errors.

If the call was successful, the rest of the flags can be interpreted as follows:

mapPixColor mapping was necessary.
newDepthDepth is new.
alignPixPixels were realigned for best results.
newRowBytesRowBytes changed.
reallocPixpixMap was reallocated.
clipPixClipping was used.
stretchPixStretching was used.
ditherPixDithering was used.

SOME BONUS CALLS

PROCEDURE DisposeGWorld (offscreenGWorld: GWorldPtr);

Make this call only when you are one hundred percent sure you don't need offscreenGWorld any more, and you want to release the memory it uses.

PROCEDURE AllowPurgePixels (pm: PixMapHandle);

This call makes the given pixMap purgeable.

PROCEDURE NoPurgePixels (pm: PixMapHandle);

This one makes the pixMap nonpurgeable.

FUNCTION GetPixelsState (pm: PixMapHandle): GWorldflags;

Make this call to find out the condition of the flags pixelsPurgeable and pixelsLocked. When you want to make temporary changes, you can use this call in conjunction with SetPixelsState to save and later restore the state of the flags.

PROCEDURE SetPixelsState (pm: PixMapHandle; state: GWorldFlags);

This call sets the state of the pixelsPurgeable and pixelsLocked flags.

FUNCTION GetPixBaseAddr (pm: PixMapHandle): Ptr;

Since the offscreen world is yours, you will probably feel the urge to mess with it directly. GetPixBaseAddr is the call you need. It returns the 32-bit address of the start of the offscreen buffer associated with the given pixMap. The address is valid until any call that moves memory around is made. If you make such a call, you must call GetPixBaseAddr again. If the offscreen pixMap has been purged, the call returns nil.

FUNCTION NewScreenBuffer (globalRect: Rect; purgeable: BOOLEAN;
        VAR gdh: GDHandle; VAR offscreenPixMap: PixMapHandle): QDErr;

This call creates a pixMap using the color table and depth of the deepest device intersected by globalRect. It is useful when the offscreen buffer is used to keep a copy of a portion of a window. Normally, applications don't need to make this call.

If the call is successful, gdh is a handle to the deepest device and offscreen pixMap points to the new pixMap. Note that if the screen device returned in gdh is changed by the user in monitors, the offscreen pixMap becomes invalid.

Errors are noErr (everything is okay), cNoMemErr (couldn't get all the memory needed), paramErr (illegal parameters), and any Memory Manager or QD errors.

PROCEDURE DisposeScreenBuffer (offscreenPixMap: PixMapHandle);

You made it, so call this procedure to dispose of it.

CALLS TO AVOID DISASTER

Even though all the books, Technical Notes, and documents that describe how to program the Macintosh talk about the things you shouldn't do and the data fields you are not supposed to mess with, not everyone can resist temptation. That's why 32-Bit QuickDraw includes a set of calls that allows you to tell the system you have modified some forbidden structure, and it should try to accommodate to your designs. The calls are:

PROCEDURE CTabChanged (ctab: CTabHandle);

This call says "Yes, I know I shouldn't mess with a color table directly, but I did it and I want to come clean." Use SetEntries, or even better let the Palette Manager maintain the color table for you.

PROCEDURE PixPatChanged (ppat: PixPatHandle);

Use this call to say "I admit I modified the fields of a PixPat directly. Please fix the resulting mess for me." When the modifications include changing the contents of the color table pointed to by PixPat.patMap^^.pmTable, you should also call CTabChanged. PenPixPat and BackPixPat are a better way to install new patterns.

PROCEDURE PortChanged (port: GrafPtr);

You should not modify any of the port structures directly. But if you cannot control yourself, use this call to let QuickDraw know what you've done. If you modify either the pixPat or the color table associated with the port, you need to call PixPatChanged and CTabChanged.

PROCEDURE GDeviceChanged (gdh: GDHandle);

The best practice is to stay away from the fields of any GDevice. But if you do change something, make this call so the system can rectify any problems. If you change the data of the color table in the device's pixMap, you must also call CTabChanged.

NEWGWORLD

NewGWorld(offscreenGWorld, pixelDepth, boundsRect, cTable, aGDevice, flags);

On entry offscreenGWorld should point to nothing
On exit offscreenGWorld is your new GWorldthe pointer may not be the same
Flags can be one of ...
0pixels not purgeable, create a new device
pixPurgepixels are purgeable, check LockPixel's return value
NoNewDevicepixelDepth and cTable are from aGDevice
pixPurge and NoNewDevice
if pixelDepth is 0optimize for CopyBits Speed
boundsRect holds a global rectanglecorresponding to a window
cTable is ignoreduses cTable from boundsRect's deepest screen
aGDevice is ignored
If pixelDepth is 1,2,4,8,16, or 32optimize for offscreen data depth
boundsRect is a rectangle in local coordinates
if cTable is nil
NewGWorld uses default color table for given pixelDepth
else
NewGWorld attaches a copy of your cTable to your new GWorld
if NoNewDevice flag is passed (see flags)
aGDevice is used to create your new GWorld (aGDevice should not be a screen device)
else
aGDevice is ignored

UPDATEGWORLD

UpdateGWorld(offscreenGWorld, pixelDepth, boundsRect,cTable, aGDevice, flags);

On entry offscreenGWorld is your old GWorld
On exit offscreenGWorld is your new GWorldthe pointer may or may not be the same
Flags can be one of ...
0pixels not updated
clipPixpreserves pixels it can, puts background in new areas
stretchPixstretches pixels to fit from old to new pixmap
clipPix and ditherPixplus the pixels are dithered if necessary
stretchPix and ditherPix
If aGDevice is not nil then the pixelDepth and cTable you supply are overridden by the pixelDepth and cTable of aGDevice.
If pixelDepth is 0
boundsRect is a global rectangle
typically corresponds to the associated window
cTable is ignored
uses cTable from boundsRect's deepest screen device
aGDevice is nilwatch out for side effects if not nil!
If pixelDepth is 1,2,4,8,16, or 32
boundsRect is a rectangle in local coordinates if different from old boundsRect then pixmap, etc are updated appropriately
if cTable is nil
uses default color table for given pixelDepth and updates pixmap if different
else
new color table used to update your pixmap
aGDevice is nil or the device to determine your cTable and pixel depth J.Z.

Guillermo Ortiz graduated from college with a BSEE, but this event took place so long ago and so far away that he gave up trying to remember when and where. He is truly the Apple veteran among the bunch of authors in this issue, having successfully emerged as a pretty nice guy from six years at Apple--four as an Apple II Pascal "expert" and two working on Color QuickDraw, the Palette Manager, and the like. He attributes surviving the 32-bit QuickDraw project to being in good shape from running and playing tennis with good friends. His curriculum vitae is entitled, "My Life As An Elvis Impersonator." Although he profusely denies ever having written that line, there's a trail of sequins leading to his office. 'Fess up, Guillermo. *

All Apple developers (Associates and Partners) received FracApp with their monthly mailings. It is also available on develop, the CD, and through APDA on the DTS sample code disks.*

 
AAPL
$118.80
Apple Inc.
+1.20
MSFT
$47.48
Microsoft Corpora
+0.01
GOOG
$539.34
Google Inc.
-1.74

MacTech Search:
Community Search:

Software Updates via MacUpdate

RapidWeaver 6.0.3 - Create template-base...
RapidWeaver is a next-generation Web design application to help you easily create professional-looking Web sites in minutes. No knowledge of complex code is required, RapidWeaver will take care of... Read more
iPhoto Library Manager 4.1.10 - Manage m...
iPhoto Library Manager lets you organize your photos into multiple iPhoto libraries. Separate your high school and college photos from your latest summer vacation pictures. Or keep some photo... Read more
iExplorer 3.5.1.9 - View and transfer al...
iExplorer is an iPhone browser for Mac lets you view the files on your iOS device. By using a drag and drop interface, you can quickly copy files and folders between your Mac and your iPhone or... Read more
MacUpdate Desktop 6.0.3 - Discover and i...
MacUpdate Desktop 6 brings seamless 1-click installs and version updates to your Mac. With a free MacUpdate account and MacUpdate Desktop 6, Mac users can now install almost any Mac app on macupdate.... Read more
SteerMouse 4.2.2 - Powerful third-party...
SteerMouse is an advanced driver for USB and Bluetooth mice. It also supports Apple Mighty Mouse very well. SteerMouse can assign various functions to buttons that Apple's software does not allow,... Read more
iMazing 1.1 - Complete iOS device manage...
iMazing (was DiskAid) is the ultimate iOS device manager with capabilities far beyond what iTunes offers. With iMazing and your iOS device (iPhone, iPad, or iPod), you can: Copy music to and from... Read more
PopChar X 7.0 - Floating window shows av...
PopChar X helps you get the most out of your font collection. With its crystal-clear interface, PopChar X provides a frustration-free way to access any font's special characters. Expanded... Read more
Carbon Copy Cloner 4.0.3 - Easy-to-use b...
Carbon Copy Cloner backups are better than ordinary backups. Suppose the unthinkable happens while you're under deadline to finish a project: your Mac is unresponsive and all you hear is an ominous,... Read more
ForeverSave 2.1.3 - Universal auto-save...
ForeverSave auto-saves all documents you're working on while simultaneously doing backup versioning in the background. Lost data can be quickly restored at any time. Losing data, caused by... Read more
Voila 3.8.1 - Capture, annotate, organiz...
Voila is a screen-capture, recording, and annotation tool that is a full-featured replacement for Mac's screen-capture and screen-recording capabilities. It has a large and robust set of editing,... Read more

Latest Forum Discussions

See All

Sunburn! Review
Sunburn! Review By Campbell Bird on November 26th, 2014 Our Rating: :: DON'T DIE ALONEUniversal App - Designed for iPhone and iPad Platform through the depths of space to make sure your entire crew dies together in this satisfying... | Read more »
Black Friday has Started Early – Lots an...
It’s almost turkey time! Which means lots and lots of food but also lots and lots of sales. Some sales have even started a few days early, which is why we’ve put together a list of iOS games that are currently discounted (sometimes by a lot).... | Read more »
Loose Leaf Review
Loose Leaf Review By Jennifer Allen on November 26th, 2014 Our Rating: :: SIMPLE SKETCHINGiPad Only App - Designed for the iPad Sketch out ideas with simple drawing tools, courtesy of Loose Leaf.   | Read more »
Screeny (Utilities)
Screeny 1.0 Device: iOS iPhone Category: Utilities Price: $.99, Version: 1.0 (iTunes) Description: Screeny is an utility app that helps you save space consumed by screenshots. It screens your camera roll and helps you to filter and... | Read more »
Tilt to Live Bundle Set to Arrive This T...
Tilt to Live Bundle Set to Arrive This Thanksgiving Posted by Ellis Spice on November 25th, 2014 [ permalink ] One Man Left has unveiled an upcoming Tilt to Live bundle, allowing players to get the series for a di | Read more »
BattleLore: Command (Entertainment)
BattleLore: Command 1.0 Device: iOS Universal Category: Entertainment Price: $9.99, Version: 1.0 (iTunes) Description: ***NOTE: Compatible with iPad 2/iPad mini, iPod touch 5 and up and iPhone 4S and up – WILL NOT RUN ON EARLIER... | Read more »
Weather Or Not Review
Weather Or Not Review By Jennifer Allen on November 25th, 2014 Our Rating: :: STYLISH WEATHER REPORTINGiPhone App - Designed for the iPhone, compatible with the iPad Check the weather quickly and conveniently with Weather or Not... | Read more »
The All-New Football Manager Handheld 20...
The All-New Football Manager Handheld 2015 is Available Now Posted by Jessica Fisher on November 25th, 2014 [ permalink ] Universal App - Designed for iPhone and iPad | Read more »
Six iOS Games to Get You Ready for Thank...
Image Source: Friends Wiki At this point in the month, you or at least a few people you know are probably getting ready to scramble around (or are already scrambling around) for Thanksgiving Dinner. It’s a hectic day of precise oven utilization, but... | Read more »
Call of Duty: Heroes: Tips, Tricks, and...
Hello Heroes: What’d we think of Call of Duty‘s take on Clash of Clans? Check out our Call of Duty: Heroes review to find out! Just downloaded Call of Duty: Heroes and need some handy tips and tricks on how to get ahead of the rest? As we often do,... | Read more »

Price Scanner via MacPrices.net

Early Black Friday Mac Pro sale, 6-Core 3.5GH...
 B&H Photo has the 6-Core 3.5GHz Mac Pro on sale today for $3499 including free shipping plus NY sales tax. Their price is $500 off MSRP, and it’s the lowest price available for this model from... Read more
Early Black Friday sale price: 15-inch 2.2GHz...
 B&H Photo has the 2014 15″ 2.2GHz Retina MacBook Pro on sale today for $1699.99. Shipping is free, and B&H charges NY sales tax only. Their price is $300 off MSRP, equalling Best Buy’s price... Read more
13-inch 2.5GHz MacBook Pro (refurbished) avai...
The Apple Store has Apple Certified Refurbished 13″ 2.5GHz MacBook Pros available for $170 off the cost of new models. Apple’s one-year warranty is standard, and shipping is free: - 13″ 2.5GHz... Read more
Early Black Friday iPad mini 3 sale: $75 off...
 Best Buy has iPad mini 3s on sale for $75 off MSRP on their online store for a limited time. Choose free shipping or free local store pickup (if available). Sale prices available for online orders... Read more
Early Black Friday MacBook Pro sale: 15-inch...
 Best Buy has posted early Black Friday prices on 15″ Retina MacBook Pros, with models on sale for $300 off MSRP on their online store for a limited time. Choose free local store pickup (if available... Read more
A9 Chips Already?
It’s barely more than a couple of months since Apple got the first A8 systems-on-chip into consumer hands, but rumor and news focus is already turning to the next-generation A9 SoC. Apple Daily... Read more
NewerTech Announces NuGuard KXs Impact X-Orbi...
NewerTech has announced updates to its family of Impact X-Orbing Screen Armor bringing military grade, triple layer protection to Apple’s new iPhone 6 and 6 Plus. Like all models in the NuGuard KXs... Read more
13-inch 1.4GHz MacBook Air on sale for $889,...
 B&H Photo has the 13″ 1.4GHz/128GB MacBook Air on sale for $889 including free shipping plus NY tax only. Their price is $110 off MSRP. B&H will also include free copies of Parallels Desktop... Read more
Save up to $300 on Macs and iPads with your A...
Purchase a new Mac or iPad at The Apple Store for Education and take up to $300 off MSRP. All teachers, students, and staff of any educational institution qualify for the discount. Shipping is free,... Read more
Apple refurbished Mac Pros available for up t...
The Apple Store is offering Apple Certified Refurbished Mac Pros for up to $600 off the cost of new models. An Apple one-year warranty is included with each Mac Pro, and shipping is free. The... Read more

Jobs Board

*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
Senior Event Manager, *Apple* Retail Market...
…This senior level position is responsible for leading and imagining the Apple Retail Team's global event strategy. Delivering an overarching brand story; in-store, Read more
*Apple* Retail - Multiple Positions (US) - A...
Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, you're also the Read more
*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
*Apple* Solutions Consultant (ASC) - Apple (...
**Job Summary** The ASC is an Apple employee who serves as an Apple brand ambassador and influencer in a Reseller's store. The ASC's role is to grow Apple Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.